home *** CD-ROM | disk | FTP | other *** search
/ Collection of Tools & Utilities / Collection of Tools and Utilities.iso / keyb / alias450.zip / ALIAS.ASM next >
Assembly Source File  |  1990-02-04  |  236KB  |  6,113 lines
  1.  
  2. Title   ALIAS.COM   Command line editor/abbreviator for MS-DOS
  3. comment |           ; start of comment block
  4.  
  5.                                                                        
  6.           A       L           I I I I I         A          S S S
  7.         A   A     L               I           A   A      S       S
  8.       A       A   L               I         A       A    S
  9.       A       A   L               I         A       A      S S S
  10.       A A A A A   L               I         A A A A A            S
  11.       A       A   L               I         A       A    S       S
  12.       A       A   L L L L L   I I I I I     A       A      S S S
  13.  
  14.  
  15.  -----------------------------------------------------------------------
  16.                             F U N C T I O N
  17.  -----------------------------------------------------------------------
  18.  
  19. This program adds a number of resident commands to DOS to implement a
  20. form of the Alias command as found on other computers.  See the variables
  21. area under 'help_text' for a list of the facilities provided, or install
  22. it by typing ALIAS at the DOS prompt, and then view the help screen by
  23. typing ALIAS ? at the prompt.
  24.  
  25. Like aliases, DOS commands typed at the prompt can be split with
  26. the & character, as long as aliases are turned on (type ALIAS ? at the
  27. prompt, for help).
  28.  
  29. ALIAS also incorporates a DOSEDIT-like facility, so ALIAS is a full
  30. superset of DOSEDIT, CED and the like.
  31.  
  32. Also, command completion is offered.  Type the first few characters of a
  33. command and press the prf_trigger key.  If a matching command is found, it
  34. will be put on screen to complete the part-typed command.  See the code
  35. for the definition of the prf_trigger key.  Why prf?  Well, during development
  36. it was known as parameter recall facility.
  37.  
  38. This file (ALIAS.ASM) comprises the entire source code.  No other files
  39. are needed to create ALIAS.COM.  The help text is a plain ASCII file called
  40. ALIAS.HLP.
  41.  
  42. Note that this resident program uses the default MS-DOS stack and does not
  43. create its own.  This has not caused any known problems.  (The DOSEDIT code
  44. sets up its own stack, but the rest of ALIAS does not use it, yet).
  45.  
  46.  
  47.   -----------------------------------------------------------------------
  48.                       I M P O R T A N T    N O T E S
  49.   -----------------------------------------------------------------------
  50.  
  51. 1.  This source code is made available for personal use only.  You can
  52.     learn from it, steal my routines, and make your own custom 
  53.     versions of the program.
  54.  
  55.     YOU MUST NOT make your own customised or enhanced versions generally
  56.     available on any BBS or by any other means.
  57.  
  58.     The only way to incorporate your enhancements into the distribution
  59.     version of ALIAS is to send ideas or code fragments (not whole new copies
  60.     of this file, please!) to the author.
  61.  
  62. 2.  If you start changing the code in here, some things may not work properly.
  63.     Just because the table size is defined as an equate, this does not mean
  64.     that you can necessarily enlarge the table by simply changing the equate.
  65.     If you change the code, and your machine crashes, that's not my fault.
  66.  
  67. 3.  There are two conditional assembly instructions in the code.  If DEBUG is
  68.     set, a number of debug procedures wil be assembled but not called. They
  69.     can be called by inserting CALL commands as required.  If ONLINE_HELP is
  70.     set, the online help will be available, as documented, with the ALIAS ?
  71.     command.  If ONLINE_HELP is not set, the online help is not assembled, and
  72.     is replaced with a short message to this effect.  This saves around 2K of
  73.     RAM when ALIAS is loaded, but means that users will have to read the
  74.     ALIAS.HLP documentation file to get help.
  75.  
  76.   -----------------------------------------------------------------------
  77.    B U G   F I X E S   A N D   A M E N D M E N T S   T O   B E   D O N E
  78.   -----------------------------------------------------------------------
  79.  
  80. Add DOS compatibility with function keys for Psion.  To do by mid Jan 1990.
  81.  
  82. Should PgUp and PgDn redraw the display line?
  83.  
  84. Trap func 29h, which the batch file interpreter uses to parse strings.  Copy
  85. commands retrieved from batch files, into the ALIAS history buffer.
  86.  
  87. Add an ALIAS E command to edit an alias, or do separate ALIAS2WP and WP2ALIAS
  88. file conversion programs.  If programs, make one prog.  Use Basic 7?
  89.  
  90. ALIAS D has the colour bug if used on the bottom line.
  91.  
  92. Add an extended keyboard buffer to 128 bytes.  This may be difficult, as DOS 4
  93. is too large to keep the buffer within segment 40h.
  94.  
  95. Add executable filenames?  eg  ALIAS A *.ASM PE *.ASM, ie the asterisk
  96. stands for the primary filename in both sides of the alias definition.
  97. The code for ALIAS A already permits this, so it's just the expander that
  98. needs expanding!
  99.  
  100. Ignore separator characters unless surrounded by spaces, else the user can't
  101. have filenames with ampersands in.
  102.  
  103. The colour bug is still in ALIAS S.
  104.  
  105.  There's a problem when PC-Tools is loaded resident.
  106.  
  107.  There's a problem with Borland's Sprint.  See message on Cix for more.
  108.  
  109.  Multiple-command lines can't have nested aliases.  Eg, if you
  110.  have ALIAS A CD CHDIR then CD FRED & DIR will use CD and not CHDIR
  111.  to change directories.  Demon@Cix found this bug, so mail him when
  112.  it's fixed.  Reported in exe/files #250 on Cix.
  113.  
  114.  There are problems with Sidekick Plus.  See message on Cix.
  115.  
  116.  If SHOW mode is on and user types 11&22, the 22 gets echoed twice.  It seems
  117.  that echo proc is being called from both 'call echo' statements.
  118.  
  119.   -----------------------------------------------------------------------
  120.              D E V E L O P M E N T   E N V I R O N M E N T
  121.   -----------------------------------------------------------------------
  122.  
  123.                 Machine:  CompuAdd 386/20 & other PC clones
  124.        Operating System:  MS-DOS 4.01.  Will run under DOS 2, 3 or 4 or 10.
  125.                Language:  8086 assembly language
  126.               Assembler:  SLR Systems OPTASM version 1.5.
  127.                  Linker:  Microsoft Linker version 5.01.20
  128.          Program Format:  Must be run as a .COM file, not .EXE
  129.  Editor for source file:  Word Perfect Program Editor version 4.21.
  130.  
  131.   -----------------------------------------------------------------------
  132.              C R E A T I N G   E X E C U T A B L E   F I L E
  133.   -----------------------------------------------------------------------
  134.  
  135. ALIAS is designed to run as a .COM file and MUST do so.  Strange things will
  136. happen if you make this into an .EXE file, because ALIAS.COM uses parts of
  137. its PSP as buffer space, and does other things which make assumptions about
  138. segments and their position in memory.
  139.  
  140. To create ALIAS.COM:
  141.  
  142. 1.  MASM ALIAS; <---- note the semi colon
  143. 2.  LINK ALIAS; <---- and this one, too
  144. 3.  EXE2BIN ALIAS
  145. 4.  RENAME ALIAS.BIN ALIAS.COM
  146. 5.  DELETE ALIAS.EXE
  147. 6.  DELETE ALIAS.OBJ
  148.  
  149.   -----------------------------------------------------------------------
  150.                  S T R U C T U R E   O F   D A T A
  151.   -----------------------------------------------------------------------
  152.  
  153. The alias table consists of a contiguous block of bytes, each initialized
  154. to zero. Each entry in the table consists of a left hand side and a right
  155. hand side.  The length of the left hand side and right hand side, as well as
  156. the number of entries, are fixed by the equates LHS_LEN, RHS_LEN and TBL_LEN
  157. respectively.  These can be changed prior to reassembling this program,
  158. resulting in an ALIAS.COM of any desired length.  The table is a fixed-length
  159. structure, which is probably not the best way to have written it.
  160.  
  161. After the right hand side part of a table entry comes a zero to signify the
  162. end of an entry.  This extra byte is not included in the count of characters
  163. defined in the equates.
  164.  
  165. If a table entry is empty, the first byte is 0.  If the entry is full, the
  166. first byte is non-zero, there is a string on the right and left side, and ALL
  167. unused bytes in the entry are 0.
  168.  
  169. There are 5 bytes before the actual table data.  These are saved along with
  170. the data, but are not flushed by the ALIAS F command.  These 5 bytes are:
  171.  
  172.           1:         - ins_mode. 0 = overwrite, 1 = insert.
  173.           2:         - status. 0 = abbrevs turned off, 1 = on
  174.           3:         - expand_from.  If 1, global, 0 = DOS prompt only
  175.           4:         - screen colour.  
  176.           5:         - echo_status. Shows whether Show or Hide mode set.
  177.  
  178. There is no identifying string to show that the file is an ALIAS file, or
  179. to specify the lhs and rhs lengths.
  180.  
  181. These flags will need bitmapping if any more data is required to be saved.
  182.  
  183. -------------------------------------------------------------------------
  184.             H I S T O R Y   O F   T H I S   V E R S I O N
  185. -------------------------------------------------------------------------
  186.  
  187. 4.50  Started adding touches of DOS compatibility to the line editor.
  188.       INS and Del work vaguely like DOS!
  189.  
  190. 4.30  Changed function keys around.  Command completion now F8.
  191.       'It' and 'Also' are F9 and F10 respectively.  This leaves F1 to F5
  192.       free, to add full DOS function key compatibility at a later stage.
  193.  
  194. 4.27  Removed help_flag (originally added in v4.12) and added function key
  195.       line to help text.
  196.  
  197.       Changed literal arrow characters in help text to decimal numbers, cos
  198.       the Ctrl-X was screwing up printer listings of the source code.
  199.  
  200. 4.26  Increased length of command completion buffer from 1000 to 1500 chars.
  201.       This value is held in CmdLen.
  202.  
  203. 4.25  ZAP_MSG shortened to save memory. Also, error_msg and disk_msg, and
  204.       version.
  205.  
  206.       Added an online_help conditional assembly switch.  When true, the help
  207.       text is assembled.  Otherwise, no online help is assembled, saving RAM.
  208.  
  209.       UK registration price increased from £20 to £25.
  210.  
  211.       Made parameter recall (the F4 key) case-insensitive, by forcing chars
  212.       to lower case before comparing them in prf_compare.
  213.  
  214.       Made putc routine use DOS rather than the BIOS version that was in NDE.
  215.  
  216.       Rewrote the sign-on text.
  217.  
  218.       Amended some calls to bios_video, so they preserve more registers in
  219.       order to conform to what the IBM tech ref says about int 10h's use
  220.       and corruption of registers.  Should always preserve ax,bp,si and di.
  221.  
  222. 4.24  Greeting message is now printed by a DOS call, rather than using our
  223.       home-made bios version.  The whole greet message can consequently be
  224.       redirected to NUL if it is not required.
  225.  
  226.       Dialcom reference removed from greeting, cos I'm not on Dialcom any more.
  227.  
  228. 4.23  Fixed printregs cos it used to corrupt bp and si.
  229.  
  230. 4.22  Added check to see if user just types a single ampersand as a string.
  231.       If so, kill the string, or ALIAS goes into a loop.
  232.  
  233.       Removed all traces of par_flag.  This was a flag that used to be set
  234.       if the string typed at the prompt was found in the alias table.  If it
  235.       was set, then replace_params (no longer used) would put back the params
  236.       typed after the first word.  Also, echo proc used par_flag, to only echo
  237.       in certain cases.  Now, if show mode is on, we always echo, whether the
  238.       string came from DOS prompt, was part of a multiple line etc.
  239.  
  240. 4.21  Re-implemented filter proc, to filter out LF characters.  Sometimes,
  241.       strings end with CRLF, and bufkey stops with CR so there will be stray
  242.       LF characters around.
  243.  
  244.       Expanded sign-on message.
  245.  
  246.       Uploaded as ALIAS421.COM and .HLP to Bix, 30/4/89.
  247.  
  248. 4.20  Started adding support for % replacable parameters.  After calling
  249.       SUBST, call expand_percents to substitue the percent parameters into
  250.       the ds:dx bufer.
  251.  
  252.       BIOS_BLIP, which makes a beep by using hardware programming and no
  253.       bios calls, renamed to hw_blip.
  254.  
  255.       Released on Cix 3am, 23/4/89.
  256.  
  257. 4.18  Removed no_dollar flag.  Display routines now stop on ascii zero,
  258.       and never on a dollar sign.  This allows aliases to contain dollar
  259.       signs and to be listed properly.
  260.  
  261.       Added F1proc, that does nothing when F1 is pressed. There is no
  262.       need for an F1 key when you have the editing facilities of ALIAS.
  263.  
  264. 4.17  Finally fixed the multiple-size cursor for CGA, EGA, VGA etc.
  265.       Works OK now.
  266.  
  267. 4.16  Experimental bug-fix for cursor size on non-CGA machines.  Need to
  268.       set bit 0 of 0:487?
  269.  
  270. 4.15  Cursor size now indicates insert/overwrite mode.
  271.  
  272. 4.14  Moved insert mode status byte so it gets saved in the data file.
  273.  
  274.       Disabled the filter proc, which prevented control characters being
  275.       typed.  Added F6 key recognition to getc, to make it Ctrl-Z.
  276.  
  277.       If user doesn't type a space before pressing the IT key, a space
  278.       is automatically added to user's string.
  279.  
  280.       Added ESC key to help text.
  281.  
  282.       Added PgUp/Dn commands, and included them in the help text.
  283.  
  284.       Bufkey routine now preserves si, which Norton's version doesn't do.
  285.       ALIAS (and NDE) now work properly with MASM.
  286.  
  287.       ALIAS414.COM released on Cix, 11 Feb 1989.
  288.  
  289. 4.12  Removed token parsing from disp_str_colour, cos the help text was
  290.       getting very confusing.  It is now printed literally.
  291.       Rewrote help text to include more information.  There are no features
  292.       that do not now appear in the help text.
  293.  
  294.       Added help_flag.  It is set before the help text is displayed, and
  295.       cleared again afterwards.  Disp_str_colour puts a white space in column
  296.       1 when the flag is set.  The help text is shifted right by 1 char.
  297.       This means that we can use all 25 lines, without getting the colour
  298.       problem, but only 79 of the 80 columns can be used.  Oh well.
  299.  
  300.       Added line to de-install message to say that user's command buffer
  301.       has been cleared.
  302.  
  303.       Added f3proc, which is called when F3 is pressed.  This is a non-
  304.       destructive version of cursup, which won't overwrite chars to the
  305.       left of the cursor.  This is the way that DOS works normally, compared
  306.       to the destructive cursup proc that used to be called when F3 pressed.
  307.       There is unused code that used to handle F3 before prf and DOSEDIT was
  308.       added.  This has not yet been removed.
  309.  
  310.       Added shareware message, requesting money, to signon screen.
  311.  
  312.       Added F8 key, which is like F4 but doesn't check to make sure that
  313.       the parameters match.  It just retrieves all but the first word of
  314.       the previous command and takes it on to the word that you have typed.
  315.       F8 is known as the IT key, cos you can TYPE a file and then DEL IT,
  316.       rather than specifying its name again.
  317.  
  318.       Added no_dollar flag.  Normally set to 1, which means that
  319.       disp_str_colour will terminate on a dollar sign.  Temporarily set
  320.       to 0 before displaying the greet message, so that we can have a dollar
  321.       character in the sign-on text.
  322.  
  323.       Rewrote help text yet again!  disp_str_proc still puts a white space
  324.       at the start of each line of the help text, so that the text could
  325.       fill the whole screen without corrupting colours.  At present, though,
  326.       the help text only fills about 18 lines.
  327.  
  328.       Removed ALIAS X and ALIAS Y commands, which used to turn prf on and
  329.       off.  No longer needed, now prf trigger is not the space bar.  People
  330.       have suggested that cursor-up should work like the prf key if one or
  331.       more characters have been typed.  Decided against this, because it
  332.       will confuse.  After all, why shouldn't it work like F3, instead?
  333.  
  334.       Added the 'also' key, which works in a similar way to the 'it' key.
  335.       Eg, TYPE FRED, <ALSO> JIM, thus <ALSO> repeats the TYPE command.
  336.       Currently using the F10 key for 'also'.  See also_proc.
  337.  
  338.       Added line to ALIAS I info to give number of aliases currently
  339.       defined, and the total number of places in the table.
  340.  
  341.       Pressing ESCape allows exit from recursive aliases.  This was easier
  342.       and safer than adding Ctrl-C checking.
  343.  
  344.       Released on cix in exe/alias 20.1.89.
  345.  
  346. 4.11  Fixed 2 places in ab_add proc, so that aliases of 7 characters or
  347.       more get truncated properly and added to the table in the right way.
  348.       Previously, the proc was not stepping over any unwanted lhs characters
  349.       that were over the lhs length limit.
  350.  
  351.       Also fixed routine at do_again: to put the correct number of characters
  352.       into the comparison buffer. 6-character aliases are now accepted, listed
  353.       and executed properly.
  354.  
  355.       Changed dates from 1988 to 1989.
  356.  
  357.       Environment block does not get freed if debug flag is set.  This lets
  358.       SMAP find the name of the loaded program.
  359.  
  360.       Sprinkled a few cld instructions around, to ensure that repeated
  361.       mov and sto instructions go in the right direction.
  362.  
  363.       Released on Cix as ALIAS411.ARC on 2 Jan 1989.
  364.  
  365. 4.10  Changed alias i text to talk about command completion and not parameter
  366.       recall.
  367.  
  368.       Released on Cix 30.12.88 as ALIAS410.ARC, containing just ALIAS.COM.
  369.  
  370. 4.03  Removed the extra lines in tinyedt that checked for the prf_trigger
  371.       key, and replaced them with an entry in cmndtbl.  This is the proper
  372.       way to do things, and it saves about 150 bytes.
  373.  
  374.       Made prf match with whatever the user has currently typed, rather than
  375.       waiting for a whole word to be typed.
  376.  
  377.       Fixed bug from earlier incarnations of the prf procedure that prevented
  378.       matches from being found in certain circumstances, by replacing the
  379.       charcount routine, that kept track of how many characters the user had
  380.       typed, with calls to bublcnt when required.  Simply incrementing a
  381.       counter after all calls to getc was not good enough, because it didn't
  382.       take into account things like presses of the del key.
  383.  
  384.       Changed help text entry for parameter recall to Command Completion,
  385.       which is more accurate.  Added ALIAS B command to help text, after
  386.       its previous, yet temporary, demotion to an undocumented command.
  387.  
  388.       Changed 2 INC SI commands in ab_buffer to calls to cmdinc.  This should
  389.       fix the problems that were happening with the alias b command.
  390.  
  391.       Added check for multiple presses of the prf trigger key, to bring
  392.       back repeated matches if there are any.  Multiple presses of the
  393.       key now cycle through all matches, then back to the first match
  394.       again.
  395.  
  396.       Added printregs proc.  Gets assembled only if DEBUG is defined as
  397.       non-zero.  Calling printregs prints the values of all the registers,
  398.       in ascii hex, on LPT1.
  399.  
  400. 4.02  Changed to_lower proc so that, instead of forcing all aliases to
  401.       lower case, we now force only the short forms.  The long forms,
  402.       ie the second string in an ALIAS A command, are now case sensitive.
  403.       The short forms are still forced to lower case, so you can not create
  404.       an alias called DA if there is an alias called da.
  405.  
  406. 4.01  Added overwrite mode facility to editor, cos all input was in
  407.       insert mode.  Added entry to cmndtbl, plus extra code to putin.
  408.       Also added ins_mode byte in data area, and inskey proc to toggle
  409.       the byte when the insert key is pressed.
  410.  
  411.       Changed hard-coded prf trigger key (SPACE character) to one defined
  412.       with an equate, so it can easily be changed.  Currently set to F4.
  413.  
  414. 4.00  Added PRF, Parameter Recall Facility.
  415.       Added code to dosedit routine to watch for first space char in
  416.       string, and call do_prf when it's found.  Doesn't allow the space
  417.       to be the first char.
  418.       Amended help text to include ALIAS X and ALIAS Y commands.
  419.       Lengthened command table to accept ALIAS X and ALIAS Y.
  420.       Added procs to process ALIAS X and ALIAS Y.
  421.       Added proc to AB_INFO to display current state of PRF.
  422.       Added do_prf proc to handle the display updating and command matching.
  423.       Do_prf checks for match and, if found, prf_disp updates display.
  424.  
  425.       Replaced the 01Ah byte, stored at the front of an alias table file,
  426.       with the value of prf_flag, so this flag now gets saved in the file.
  427.       To update an old data file, from a version of ALIAS less than
  428.       4.00, type ALIAS X or ALIAS Y to set prf preference, and re-save the
  429.       file with ALIAS W.
  430.  
  431.       Added display-a-white-space routine after ab_buffer to prevent
  432.       corruption of display.
  433.  
  434.       Removed ALIAS ? from the help screen, as a shorter help screen cures
  435.       the last ocurrence of the display colour bug.
  436.  
  437.       Fixed bug in code that constructed default data file name.  If file
  438.       was in root, an extra backslash was added.  Now works properly.
  439.  
  440.       Added DEBUG flag in equates.  If set, BIOS_BLIP gets assembled.
  441.  
  442.       Rewrote do_prf so that the command stack is searched in the correct
  443.       order, ie most current commands first.  Also takes account of commands
  444.       that may wrap around between top and bottom of the command stack.
  445.  
  446.       Added move_crsr proc to prf code so that cursor is placed in correct
  447.       position after prf facility is used.
  448.  
  449. 3.04  Changed alias.dat to upper case, so that it looks better when
  450.       printed by the alias i command.
  451.  
  452.       Removed DOSEDIT equate, that allowed a version of ALIAS to be 
  453.       assembled without the DOSEDIT module.  This is to prepare for the
  454.       parameter recall facility, which will only work when DOSEDIT is loaded,
  455.       as we need control over individual keys pressed.
  456.  
  457.       Removed the 'Command Line Editor Available' message from alias i
  458.       info, cos it's always available now.
  459.  
  460. 3.03  Rewrote help screen to be task-oriented rather than keystroke
  461.       oriented.  Token values changed to apply to new help screen.
  462.  
  463.       Removed a call to crlf, to stop leaving 2 blank lines after ALIAS W.
  464.  
  465.       If the default file is loaded at install time, a record of the current
  466.       directory is kept.  If an ALIAS W command is given, and no file is
  467.       specified, the default file written will be placed in the same directory
  468.       as the original file was loaded from.  If a filename IS given, it will
  469.       go in the current directory, or the one specified in the pathname on
  470.       the ALIAS W command.
  471.  
  472.       ALIAS R commands work the same.  If just ALIAS R is typed, and a
  473.       default file was loaded at install time, the ALIAS R command will read
  474.       from that same default file, with the same path.
  475.  
  476.       The ALIAS I command shows the full pathname of the current default
  477.       file.  Note that this default filename cannot be changed.
  478.  
  479.       Added small routine in INSTALL procedure to free the program's
  480.       copy of the environment strings.  This saves a few bytes of RAM
  481.       once the program is installed, though it does mean that programs such
  482.       as SMAP and RMAP will not be able to report the name of the program,
  483.       as the name is stored at the end of the environment string data.
  484.  
  485.       ALIAS303.ARC, containing just a COM file, released on Cix 18/11/88.
  486.       Will not give source code away from now on.
  487.  
  488. 3.02  Changed from Microsoft MASM 5.1 to OPTASM 1.5.  No changes at all
  489.       required for source code.  Assembles faster, and produces a .COM
  490.       file around 35 bytes smaller, by optimizing jump instructions.
  491.  
  492.       No OPTASM special features are used, in order to maintain MASM 5
  493.       compatibility.  This means that pushm and popm are not used, for
  494.       example.  OPTASM takes care of jumps being out of range, so there
  495.       may be a couple of these that need correcting if MASM is used.
  496.  
  497.       Fixed ab_buffer proc so that listings pause after each screen. Added
  498.       line to list_pause proc, to clear the counter when the list_proc
  499.       routine is called.
  500.  
  501.       Added disclaimer, and removed (c) symbol from help text.
  502.  
  503.       Replaced generic 'There is an error' message with a set of more
  504.       specific ones.  Procs added are invalid_letter, syntax_error,
  505.       exist_err and not_found.
  506.  
  507. 3.01  Fixed bugs caused by block-conversion of the NDE code to lower
  508.       case.  A few capital letters in quotes got changed to l/case, which
  509.       affected CMP instructions.
  510.  
  511.       Removed redundant message that used to be produced after the SORT
  512.       command had done its job.
  513.  
  514.       Changed ShrtStr from 2 to 0, so all strings are saved in DOSEDIT
  515.       buffer, even if they are only 1 char long.  This means that ALIAS B
  516.       gives you a true history of what you've typed recently.  There should
  517.       be an option of saving the history to file, but there isn't yet.
  518.  
  519.       Re-wrote ab_buffer proc so that strings get displayed in the
  520.       current colour, and not white.
  521.  
  522.       ALIAS301.ARC RELEASED SEPTEMBER 1988.
  523.       ARC FILE INCLUDES ALIAS.ASM AND ALIAS.COM.
  524.       DOC FILE FROM v1.31 NOT INCLUDED.  SEE THIS HISTORY SECTION INSTEAD.
  525.  
  526. 3.00  Added DOSEDIT-like facility.  This is now a standard feature of having
  527.       ALIAS loaded, and thus makes it ALIAS a superset of DOSEDIT.  Current
  528.       DOSEDIT users can be encouraged to replace DOSEDIT with ALIAS v3.00.
  529.  
  530.       At present the DOSEDIT code is based strongly on NDE, a Norton
  531.       DOSEDIT clone released as shareware on CompuServe a couple of years
  532.       ago.  This code will be modified and improved, though.
  533.  
  534.       The parameter recall facility as found in CED is not yet available
  535.       with ALIAS.  This will come in version 4 of ALIAS, hopefully.
  536.  
  537.       DOSEDIT flag added.  If false, program will assemble with old
  538.       get-string code, and will not include the DOS editor.  Saves around
  539.       3K of RAM in the file and the resident code.
  540.  
  541.       Changed int 10h calls in editor code to use bios_video macro.
  542.  
  543.       Added check at install time to permit loading under DOS version 4.x.
  544.  
  545.       Added ALIAS B command.  Only assembles if DOSEDIT is true.
  546.  
  547. 2.13  Added message at load time to say we're loading alias.dat.
  548.  
  549. 2.12  Fixed to_lower proc to only convert characters in the range A to Z.
  550.       (Note the capitals).  If ALL characters are converted, strange things
  551.       happen, eg a backslash becomes a pipe character.
  552.  
  553.       Entries in multiple commands can't have overrides.  
  554.       Eg, ALIAS A ZZ CD\FRED & ~TC stuffs CD\FRED into the buffer, and then
  555.       stuffs ~TC (ie, the override char gets stuffed as well.)  Also, ~A & B
  556.       results in A getting executed but not B.  These 'bugs' cured by
  557.       officially documenting the fact that overrides are only designed to
  558.       override a whole line, and that their use in any other place than the
  559.       1st char in a line, or the use of more than 1 override char in a line
  560.       will cause unpredictable results.
  561.  
  562. 2.11  Added some tokenising in the HELP text, so that phrases appearing
  563.       many times are included in the code only once. Size of .COM file was
  564.       reduced by 457 bytes, despite the additional code to process the tokens.
  565.  
  566.       Added crlf to start of list4 label, to prevent corruption of DOS
  567.       prompt if ALIAS L xxx failed to find specified entry in table.
  568.  
  569. 2.10  Added checking in replace_params and subst procs, to ensure that
  570.       we don't stuff too many characters into the ds:dx buffer.  The size
  571.       of the buffer is in ds:dx, placed before the function call.
  572.  
  573.       Fixed bug in list routine to handle 40h:84h being 0, in which case
  574.       screen length gets set to 25.
  575.  
  576.       Force the parameters of an ALIAS A command to lower case, to prevent
  577.       case-sensitive aliases being added to the table.
  578.  
  579.       Added routine after faking a get-string call, to iret if the user
  580.       simply presses RETURN.  In such a case, no more processing by ALIAS
  581.       is necessary.
  582.  
  583. 2.01  Added nesting facility.  You can have ALIAS A FA F A:*.*, where the
  584.       expanded alias is an alias command in its own right.
  585.  
  586.       Fixed bug in AB_ADD routine that checks whether an alias exists before
  587.       allowing one to be added to the table.  The check routine checked one
  588.       too few entries, so you could add an alias that had the same name as
  589.       the last one in the table.
  590.  
  591.       Changed list_pause routine to only pause if screen is really full
  592.       (ie, support EGA 43 lines).  Also, Press Any Key message is removed
  593.       from screeen when key pressed.
  594.  
  595.       Added get_vpage proc, so we now write to the current video page and
  596.       don't simply assume page 0.  Should really force video page to 0 if
  597.       we are in graphics mode, but who has a DOS prompt in graphics mode?!
  598.  
  599. 2.00  Added parameter facility. If F is abbreviated to DIR, then typing
  600.       F A: will be expanded to DIR A: and not just DIR.
  601.       This is done as follows.  When the user's string is first typed,
  602.       only the first word (up to a space) is used for deciding if an alias
  603.       exists.  The rest is just saved away in a buffer.  Once the alias
  604.       has been substituted, REPLACE_PARAMS is called to put those buffered
  605.       characters back where they belong and to update the length pointer
  606.       in ds:[dx+1].  In theory, the routine should ensure that the length
  607.       of the new string doesn't exceed that specified in [dx] and, if
  608.       it does, the string should be truncated.  This does not happen in
  609.       version 2.00.
  610.  
  611.       Note that replace_params only does something if the search for an
  612.       alias succeeds.  If the first word that a user types does not appear
  613.       in the table, replace_params does nothing.
  614.       Note that, in multi-statement lines, any parameters get appended to
  615.       THE LAST OF THE STATEMENTS ONLY.  So, if you have CLS & DIR, the
  616.       parameters would go on to the DIR but not the CLS.
  617.  
  618.       Added AB_ORDER proc to sort the alias table in RAM. This was originally
  619.       called by the ALIAS O command but I've changed things so that it gets
  620.       called automatically whenever the table changes.  This way, the table is
  621.       always kept alphabetical for the benefit of the user.  Because of this,
  622.       it would be better (and faster) if the ADD procedure looked for
  623.       spare table entries by starting from the bottom, but doing this is not
  624.       really important.
  625.  
  626.       Fixed colour bug.  Before, if an ALIAS command causing screen output
  627.       made the screen scroll, the DOS default attribute changed to ALIAS's
  628.       colour setting.  So, an ALIAS L that filled the screen with yellow text
  629.       would cause all subsequent DOS output to be in yellow until a CLS.
  630.       The cause of this is BIOS video function 0Eh (write TTY).  When it
  631.       scrolls the screen up, it gets the attributes for the new line from the
  632.       line above, which was the coloured text displayed by ALIAS.  Fixed by
  633.       adding a routine to put a white space at the start of a line, for
  634.       function 0Eh to find and copy.  This problem doesn't seem to occur if
  635.       ANSI.SYS is loaded - perhaps it handles scrolling in a better way.
  636.  
  637.       Expanded the LIST command to stop if screen is full and ask user to
  638.       press any key.  Essential if you have more than 24 aliases in table.
  639.  
  640.       Install routine now permits loading under DOS major version 2,3 or 10.
  641.       Version 10.0 is the DOS box of OS/2.
  642.  
  643.       Replaced int 10h calls with a macro that also preserves bp, cos of bug
  644.       in early IBM bios, that trashes bp during an int 10h call.
  645.  
  646. 1.31  Expand_from and ab_status flag bytes moved into the table area, so
  647.       they now get saved to disk with the table.
  648.       Disk_error_msg proc added.  DOS version check now looks for ver 2 or 3,
  649.       and not just >1. Prevents prog being used under DOS 4 or OS/2.
  650.  
  651.       ALIAS131.ARC (first ever release of ALIAS) RELEASED DECEMBER 1987.
  652.       ARC FILE CONTAINS JUST ALIAS.COM AND DOCUMENTATION.
  653.  
  654. 1.30  Added bp to list of registers in push_all and pop_all macros.
  655.       Added shift_left proc, so that leading spaces in user's input are now
  656.       handled as they would be if ALIAS were not installed,
  657.  
  658. 1.29  Changed method for checking whether ALIAS is resident.  Versions up to
  659.       1.28 used a signature.  The checking process involved searching all of
  660.       RAM for the signature.  This was slow, and also meant that, if a copy
  661.       of ALIAS.COM was kept on a ram disk, the signature would appear in
  662.       memory even if ALIAS was not loaded.
  663.       Version 1.29 intercepts int 21h function 35h (get interrupt vector).
  664.       Before passing control to the real function 35h routine, the fifth byte
  665.       of the inter-application communication area at 0040:00F4h is 
  666.       incremented.  Thus, a program simply needs to do a dummy call to func
  667.       35h and monitor the ICA byte, to see whether ALIAS is loaded or not.
  668.       The side-effect of this is that calls to function 35h will corrupt 
  669.       the ICA.  If this causes problems it can be fixed, though the very few
  670.       programs that actually use the ICA should be responsible enough to
  671.       keep a check on its integrity now and again!
  672.  
  673. 1.28  Display error message if invalid ALIAS command typed
  674.  
  675. 1.27  If only 1 parameter is specified in A command, error msg displayed.  If
  676.       the single parameter followed by a space, abbreviation is set up to
  677.       a null string and can be deleted with D.
  678.       Error message (no action taken) expanded to give help.
  679.  
  680. 1.26  Check with ALIAS L that user leaves a space between arg and ALIAS L
  681.       else machine hangs. Same goes for D and A command.
  682.  
  683. 1.25  Y or N typed to Are You Sure message gets echoed in correct colour
  684.  
  685. 1.24  Only Y,y,N,n allowed in response to 'Are you sure...' msg.
  686.       Alrdy_in message expanded.
  687.  
  688. 1.23  Fixed bug so that args specified in D and L command works in u/case too
  689.  
  690. 1.22  List command can now optionally take an argument. Zap_msg tidied up.
  691.       Confirmation required on f,r,w,z options.
  692.       Added disp_ch CR in echo proc, after echoing ']'.  Needed for Infocom
  693.       games.
  694.  
  695. 1.21  Echo_status saved with data files. 
  696.  
  697. 1.20  Alias commands can now be recalled with F3, just like any DOS command.
  698.       The ALIAS Z command can't, though, as the routine that puts the chars
  699.       back into the buffer for F3 to find doesn't get called because alias
  700.       has been de-installed.  Oh well, can't have everything I s'pose.
  701.  
  702. 1.11  Current colour gets saved with the table.
  703.  
  704. 1.10  Fixed colour bugs in ALIAS L and in show mode, where some parts
  705.       always displayed in white.
  706.  
  707. 1.00  First version of Alias.  Previously called ABR.  Commands changed from
  708.       AB to ALIAS.  Default filename changed from DEFAULT.ABR to ALIAS.DAT
  709.  
  710.         |                             ; end of comment
  711.  
  712. ; -----------------------------------------------------------------------
  713. ;                           M A C R O S
  714. ; -----------------------------------------------------------------------
  715. ;  
  716. ;
  717. show    macro     string                    ; Display a string using
  718.         push      ax                        ; a DOS call.
  719.         push      dx
  720.         push      ds
  721.  
  722.         push      cs
  723.         pop       ds
  724.         mov       ah,9
  725.         mov       dx,offset cs:string
  726.         int       21h
  727.  
  728.         pop       ds
  729.         pop       dx
  730.         pop       ax
  731. endm
  732. ;
  733. push_m  macro arglist
  734.               irp      register,<arglist>
  735.               push     register
  736.               endm
  737.         endm
  738. ;
  739. pop_m   macro arglist
  740.               irp      register,<arglist>
  741.               pop      register
  742.               endm
  743.         endm
  744. ;
  745. disp_ch macro char
  746.         push_m <ax,dx>
  747.         mov   dl,char
  748.         mov   ah,2
  749.         int   21h
  750.         pop_m <dx,ax>
  751.         endm
  752. ;
  753. push_all      macro
  754.               push_m <ax,bx,cx,dx,di,si,es,ds,bp>
  755.               endm
  756. ;
  757. pop_all macro
  758.         pop_m <bp,ds,es,si,di,dx,cx,bx,ax>
  759.         endm
  760. ;
  761. bios_video    macro
  762.         push  bp
  763.         int   10h
  764.         pop   bp
  765.         endm
  766. ;
  767. ; -----------------------------------------------------------------------
  768. ;                          E Q U A T E S
  769. ; -----------------------------------------------------------------------
  770. ; 
  771. VERS        equ   '4.50'              ; Current version number.
  772.                                       ; Note that this is the only place
  773.                                       ; where the version number is quoted
  774.                                       ; literally.
  775.  
  776. DEBUG       equ   0                   ; Assemble debug procs if <> 0
  777.                                       ; Also, don't free environment block
  778. ONLINE_HELP equ   1                   ; Only assemble help text if set
  779.  
  780. RSIZE     equ   (init-start)/16+17      ; number of resident paragraphs
  781. CR        equ   0Dh                     ; carriage return character
  782. LF        equ   0Ah                     ; line feed character
  783. EOM       equ   0                       ; message terminator for internal
  784.                                         ; display routines.
  785. DOS_EOM   equ   '$'                     ; message terminator for strings
  786.                                         ; displayed by DOS functions.
  787. BS        equ   08                      ; backspace
  788. LETTER    equ   byte ptr cs:command_letter 
  789. SPACE     equ   20h
  790. WHITE     equ   7                       ; attribute value
  791.  
  792. ; The following 3 values define the size of the alias table
  793.  
  794. LHS_LEN equ   06                      ; length of lhs in table entry
  795. RHS_LEN equ   70                      ; length of rhs
  796. TBL_LEN equ   30                      ; no of entries in table
  797. ;
  798. OVERRIDE      equ '~'                 ; override character for commands
  799. SEPARATOR     equ '&'                 ; char between cmds on multi-cmd lines
  800.  
  801.  
  802. ; Extra DOSEDIT equates
  803.  
  804. PRF_TRIGGER   equ    0142h            ; F8 key
  805. IT_KEY        equ    0143h            ; F9 key
  806. ALSO_KEY      equ    0144h            ; F10 key
  807. MaxSWdt       equ    134              ;max screen width
  808. MaxLin        equ    140              ;max line length to edit
  809. CmdLen        equ    1500             ;number of char for previous commands
  810. ShrtStr       equ    0                ;length of strings too short to save
  811. TAB           equ    09H              ;ASCII tab
  812. ESCAPE        equ    1BH              ;ASCII escape
  813. HomeKey       equ    0147H            ;home key
  814. UpArrw        equ    0148H            ;up arrow key
  815. LtArrw        equ    014BH            ;left arrow key
  816. RtArrw        equ    014DH            ;right arrow key
  817. EndKey        equ    014FH            ;end key
  818. DnArrw        equ    0150H            ;down arrow key
  819. DelKey        equ    0153H            ;delete key
  820. CntLf         equ    0173H            ;control left arrow key
  821. CntRt         equ    0174H            ;control right arrow key
  822. AltW          equ    0111H            ;ALT W key
  823. AltL          equ    0126H            ;ALT L key
  824. AltK          equ    0125H            ;ALT K key
  825. AltU          equ    0116H            ;ALT U key
  826. F1Key         equ    013BH            ; F1 Key.
  827. F3Key         equ    013DH            ;F3 function key
  828. F6Key         equ    0140H            ; F6 key.
  829. PGUPKEY       equ    0149H            ; PgUp Key
  830. PGDNKEY       equ    0151H            ; PgDn Key
  831. CNTL          equ    40H              ;difference between alpha and control
  832. Insert        equ    0152h            ;Insert key
  833.  
  834. ; end of dosedit equates
  835.  
  836. ; -----------------------------------------------------------------------
  837. ;                   S T A R T   O F   M A I N   C O D E
  838. ; -----------------------------------------------------------------------
  839. code    segment
  840.         assume     cs:code,ds:code,es:nothing
  841.         org   100h
  842.         ;
  843. start:  jmp   init                    ; init code at end of res section
  844.         ;
  845. private db  CR
  846.         db  'ALIAS v',VERS,' - (c) Robert Schifreen.',1ah
  847.         ;
  848. intent:                               ; DOS function 0Ah comes here now
  849.         ;
  850.  
  851.         push  ax                      ; first, save the flags reg
  852.         pushf                         ; save flags on stack...
  853.         pop   ax                      ; ...and retrieve into ax
  854.         mov   cs:save_flags,ax
  855.         pop   ax
  856.  
  857.         cmp   ah,0ah                  ; is this a 'get string' instruction?
  858.         je    go_on                   ; continue if it is
  859.  
  860.         cmp   ah,35h                  ; intercept get-int-vector to check for
  861.                                       ; alias being resident.
  862.         je    func35
  863.         jmp   exec                    ; else jump far to abort
  864.         ;
  865.  
  866.  
  867. func35:                               ; we have found a call to function 35h.
  868.                                       ; Increment byte 0040:00F4h as a sign
  869.                                       ; that ALIAS is resident.
  870.         push  ds
  871.         push  ax
  872.         mov   ax,40h
  873.         mov   ds,ax                   ; ds points to ICA segment
  874.         inc   byte ptr ds:0f4h        ; increment 5th byte of ICA
  875.         pop   ax
  876.         pop   ds
  877.         jmp   exec                    ; and go to real int 21h routine with
  878.                                       ; everything intact.
  879.  
  880. go_on:
  881.         ; 
  882.         cmp   cs:do_kb_str,0          ; do we want to restore kbd buffer?
  883.         je    no_restore_kbd          ; if not, then don't
  884.         call  restore_buffer          ; put back chars so F3 can find them
  885.         mov   cs:do_kb_str,0          ; clear the flag now it's dealt with
  886.  
  887. no_restore_kbd:
  888.  
  889.         push  bp                      ; The first time that the new int 21h 
  890.         push  ax                      ; handler is called, this routine saves
  891.         mov   ax,cs:command_cs        ; CS and IP values that called it. This
  892.         cmp   ax,0                    ; will be the location in COMMAND.COM
  893.         jne   csip_saved              ; that called it.When other strings are
  894.         mov   bp,sp                   ; processed we can get CS and IP values
  895.         mov   ax,ss:[bp+6]            ; from stack (pushed by INT) & cmp
  896.         mov   cs:command_cs,ax        ; them with the stored ones.  If they
  897.         mov   ax,ss:[bp+4]            ; match,string being looked at was
  898.         mov   cs:command_ip,ax        ; entered from DOS prompt. If not, str 
  899.         ;
  900. csip_saved:                           ; must have come from another prog.
  901.         ;
  902.         pop   ax
  903.         pop   bp
  904.         ;
  905.         push  ax                      ; was string typed at the DOS prompt?
  906.         push  bx                      ; (See above for how to find out.)
  907.         push  bp
  908.         mov   bp,sp
  909.         mov   ax,ss:[bp+8]            ; get CS value that called us.
  910.         mov   bx,cs:command_cs        ; get saved CS value
  911.         cmp   ax,bx                   ; are they the same?
  912.         jne   wrong_csip              ; abort if not
  913.         ;
  914.         mov   ax,ss:[bp+6]            ; get IP value that called us
  915.         mov   bx,cs:command_ip        ; get saved IP value
  916.         cmp   ax,bx                   ; same?
  917.         jne   wrong_csip              ; abort if not equal
  918.         jmp   csip_valid              ; continue processing if OK
  919.         ;
  920. wrong_csip:                           ; We were not called from COMMAND.COM
  921.                                       ; so just get string and return
  922.         ;
  923.         pop   bp
  924.         pop   bx
  925.         pop   ax
  926.         ;
  927.                                       ; although the string was not 
  928.                                       ; typed at the DOS prompt, if
  929.                                       ; expand_from = 1 then global 
  930.                                       ; expansion is required so jmp to
  931.                                       ; csip_valid anyway
  932.         cmp   cs:expand_from,1
  933.         je    csip_valid2
  934.         ;
  935.         cmp   cs:multi_line_outstanding,0
  936.         je    no_need   
  937.         jmp   do_multi_line
  938.         ;
  939. no_need:
  940.         ;         
  941.         call  get_string_from_kbd     ; else fake a real 'get string' call
  942.         call  restore_flags           ; replace flags saved on entry
  943.         iret                          ; and return to caller of INT 21h
  944.  
  945. csip_valid:                           ; CS and IP values correct. Look for ~
  946.         pop   bp                      ; tidy up the stack
  947.         pop   bx
  948.         pop   ax      
  949.                                       ; Is there part of a multi-statement
  950.                                       ; line that has not been passed to DOS?
  951.                                       ; If so, don't read keyboard but go    
  952.                                       ; straight to correct routine.
  953.  
  954. csip_valid2:                          ; come here if global.
  955.         ;
  956.         cmp   cs:multi_line_outstanding,0 
  957.         je    no_multi_line           ; if 0, no multi-line in process
  958.         jmp   do_multi_line
  959.         ;
  960. no_multi_line:
  961.         ;
  962.         call  get_string_from_kbd     ; fake a real 'get string' call
  963.  
  964.         push_m <bp,ax>
  965.         mov    bp,dx
  966.         mov    ah,byte ptr ds:[bp+1]  ; get length of string entered
  967.         cmp    ah,0                   ; do nothing if user just pressed RETURN
  968.         jne    not_zerolen2
  969.         jmp    short zero3
  970.  
  971. not_zerolen2:
  972.  
  973.         cmp    ah,1                   ; is string only 1 char long?
  974.         jne    not_zerolen
  975.         mov    ah,byte ptr ds:[bp+2]
  976.         cmp    ah,SEPARATOR           ; and is that 1 char an ampersand?
  977.         jne    not_zerolen            ; forget it if so
  978.         mov    byte ptr ds:[bp+1],0
  979.         mov    byte ptr ds:[bp+2],CR  ; else clear the ampersand
  980. zero3:
  981.         pop_m  <ax,bp>
  982.         call   restore_flags
  983.         iret                          ; There's nowt for us to do
  984.  
  985. not_zerolen:
  986.  
  987.         pop_m <ax,bp>
  988.         push  ax
  989.         push  bp
  990.         mov   bp,dx
  991.         mov   ah,ds:[bp+2]            ; get 1st char in string
  992.         cmp   ah,override             ; is it the override character?
  993.         jne   find_ab                 ; if not, proceed 
  994.         mov   byte ptr ds:[bp+2],' '  ; else, replace ~ with space
  995.         pop   bp
  996.         pop   ax
  997.         ;
  998.         call  restore_flags
  999.         iret                          ; and return to caller
  1000.         ;
  1001. find_ab:
  1002.         ;
  1003.         pop   bp
  1004.         pop   ax
  1005.  
  1006. find_ab2:                             ; Come here after expanding an alias,
  1007.                                       ; thus allowing nesting.
  1008.  
  1009.  
  1010.         push   ax                     ; Allow ESC to abort recursive aliases
  1011.         push   dx
  1012.  
  1013. special_key:
  1014.  
  1015.         mov    ah,6                   ; is there a char waiting?
  1016.         mov    dl,0FFh
  1017.         int    21h
  1018.         jz     no_break               ; no key is waiting
  1019.         cmp    al,0
  1020.         je     special_key
  1021.         cmp    al,ESCAPE              ; is key ESCAPE?
  1022.         jne    no_break
  1023.         pop    dx
  1024.         pop    ax
  1025.         call   restore_flags          ; ESC pressed.  Tidy up.
  1026.         push   bp
  1027.         mov    bp,dx
  1028.         mov    byte ptr ds:[bp+1],0   ; Clear the buffer, so passing DOS
  1029.         mov    byte ptr ds:[bp+3],CR  ; an empty command string.
  1030.         pop    bp
  1031.         iret
  1032.  
  1033. no_break:
  1034.  
  1035.         pop    dx
  1036.         pop    ax
  1037.  
  1038.                                       ; Before operating on user's string,
  1039.                                       ; remove any leading spaces.
  1040.         call  shift_left
  1041.  
  1042.                                       ; If the first 6 characters in the
  1043.                                       ; string are 'ALIAS 'then do requested
  1044.                                       ; command. If not, search table and
  1045.                                       ; replace string if required.
  1046.                                       ; 1st string at ds:si
  1047.         push_m <si,ds,es,di,cx,ax>
  1048.         mov   si,dx
  1049.         add   si,2
  1050.         mov   ax,cs
  1051.         mov   es,ax
  1052.         mov   ax,offset cs:match
  1053.         mov   di,ax                   ; 2nd string at es:di
  1054.         mov   cx,6                    ; compare 6 bytes
  1055.         cld
  1056.         repe  cmpsb
  1057.         je    ab_found
  1058.         ;
  1059.         mov   si,dx                   ; if not found, try looking for upper
  1060.         add   si,2                    ; case version too
  1061.         mov   di,offset cs:match_u_case
  1062.         mov   cx,6
  1063.         repe  cmpsb
  1064.         je    ab_found
  1065.         ;
  1066.         jmp   not_ab                  ; jump if alias command not typed
  1067.         ;
  1068. ab_found:
  1069.         ;
  1070.         pop_m <ax,cx,di,es,ds,si>
  1071.  
  1072.                                       ; an alias command was typed, so find 
  1073.                                       ; out what one it is, and act on it
  1074.         push  ax
  1075.         push  bp
  1076.         mov   bp,dx
  1077.         mov   ah,byte ptr ds:[bp+1]   ; string must be 7 chars long 
  1078.         cmp   ah,7
  1079.         pop   bp
  1080.         pop   ax
  1081.         jnb   length_correct
  1082.         jmp   bye
  1083.         ;
  1084. length_correct:
  1085.         ;
  1086.         push  ax
  1087.         push  bp
  1088.         mov   bp,dx
  1089.         mov   ah,byte ptr ds:[bp+8]   ; get 8th char of string
  1090.         or    ah,00100000b            ; force to lower case
  1091.         mov   cs:command_letter,ah    ; save it
  1092.         pop   bp
  1093.         pop   ax
  1094.         ;
  1095.                                       ; the following list of CMP's may well
  1096.                                       ; be bad programming practice, but it
  1097.                                       ; is easier to follow than a jump
  1098.                                       ; table, and is shorter too!
  1099.  
  1100.  
  1101.         cmp   letter,'?'
  1102.         jne   x1
  1103.         call  ab_help
  1104.         jmp bye
  1105. x1:     cmp   letter,'a'
  1106.         jne   x2
  1107.         call  ab_add
  1108.         call  ab_order
  1109.         jmp bye
  1110. x2:     cmp   letter,'d'
  1111.         jne   x3
  1112.         call  ab_delete
  1113.         call  ab_order
  1114.         jmp bye
  1115. x3:     cmp   letter,'l'
  1116.         jne   x4
  1117.         call  ab_order
  1118.         call  ab_list
  1119.         jmp bye
  1120. x4:     cmp   letter,'w'
  1121.         jne   x5
  1122.         call  ab_order
  1123.         call  ab_write
  1124.         jmp bye
  1125. x5:     cmp   letter,'r'
  1126.         jne   x6
  1127.         call  ab_read
  1128.         jmp bye
  1129. x6:     cmp   letter,'c'
  1130.         jne   x7
  1131.         call  ab_colour
  1132.         jmp bye
  1133. x7:     cmp   letter,'n'
  1134.         jne   x8
  1135.         call  ab_none
  1136.         jmp bye
  1137. x8:     cmp   letter,'i'
  1138.         jne   x9
  1139.         call  ab_info
  1140.         jmp bye
  1141. x9:     cmp   letter,'f'
  1142.         jne   xa
  1143.         call  ab_flush
  1144.         jmp bye
  1145. xa:     cmp   letter,'p'
  1146.         jne   xb
  1147.         call  ab_prompt
  1148.         jmp bye
  1149. xb:     cmp   letter,'g'
  1150.         jne   xc
  1151.         call  ab_global
  1152.         jmp bye
  1153. xc:     cmp   letter,'s'
  1154.         jne   xd
  1155.         call  ab_show
  1156.         jmp bye
  1157. xd:     cmp   letter,'b'
  1158.         jne   xe
  1159.         call  ab_buffer
  1160.         jmp   bye
  1161. xe:     cmp   letter,'h'                  
  1162.         jne   xf
  1163.         call  ab_hide
  1164.         jmp bye
  1165. xf:     cmp   letter,'h'                  ; unused dummy. SPARE.
  1166.         jne   xg
  1167.         call  ab_hide
  1168.         jmp bye
  1169. xg:     cmp   letter,'h'                  ; unused dummy. SPARE
  1170.         jne   xh
  1171.         call  ab_hide
  1172.         jmp bye
  1173. xh:     cmp   letter,'z' 
  1174.         jne   xi
  1175.         jmp   ab_zap
  1176. xi:     call  invalid_letter
  1177.  
  1178.  
  1179. bye:                                  ; come back here if user says "No"
  1180.                                       ; when asked if sure about Zap
  1181.  
  1182.         push  bp
  1183.         mov   bp,dx
  1184.  
  1185.         push  ax                      ; save details before overwriting str,
  1186.                                       ; so they can be retrieved when this
  1187.                                       ; int handler is called again. Allows
  1188.                                       ; alias cmds to be recalled with F3.
  1189.         mov   al,ds:[bp+1]        
  1190.         mov   byte ptr cs:kb_str_len,al ; save length of string
  1191.         mov   al,ds:[bp+2]
  1192.         mov   byte ptr cs:kb_str_ch1,al ; save 1st char 
  1193.         pop   ax
  1194.  
  1195.         mov   byte ptr cs:do_kb_str,1 ; flag to say put back values
  1196.         mov   byte ptr ds:[bp+1],0    ; set length to 0 to stop ALIAS cmd
  1197.                                       ; being executed by DOS
  1198.         mov   byte ptr ds:[bp+2],CR   ; put c/r terminator in buffer too
  1199.         pop   bp
  1200.         ;
  1201.         call  restore_flags
  1202.         iret
  1203.         ;
  1204. not_ab:
  1205.         ;
  1206.  
  1207.         pop_m <ax,cx,di,es,ds,si>
  1208.  
  1209.                                       ; No ALIAS command typed. Search
  1210.                                       ; table and substitute if necessary
  1211.  
  1212.         cmp   cs:[ab_status],0        ; don't substitute if aliases off
  1213.         je    back_to_dos
  1214.         jmp   turned_on
  1215.  
  1216. back_to_dos:
  1217.  
  1218.         call  restore_flags
  1219.         iret
  1220.  
  1221. turned_on:                            ; aliases are not off so continue
  1222.  
  1223.         ;
  1224.         mov   byte ptr cs:nest_flag,0 ; set if expansion takes place
  1225.         push  bp
  1226.         mov   bp,dx
  1227.         cmp   byte ptr ds:[bp+1],0    ; get length of user's string
  1228.                                       ; if it's zero, abort.
  1229.         ;
  1230.         pop   bp
  1231.         je    too_long                ; abort if it is
  1232.         jmp   length_ok               ; otherwise OK to continue
  1233.  
  1234. too_long:
  1235.  
  1236.         call  copy_to_psp
  1237.         jmp   ok_to_cont2
  1238.  
  1239.  
  1240. length_ok:                            ; fill buffer with 0's
  1241.  
  1242.         push_m <ax,es,di,cx>
  1243.         cld
  1244.         mov   ax,cs       
  1245.         mov   es,ax
  1246.         mov   al,0h
  1247.         mov   di,offset cs:buffer
  1248.         mov   cx,LHS_LEN
  1249.         rep   stosb
  1250.         pop_m <cx,di,es,ax>
  1251.                                       ; Now put the string at ds:dx 
  1252.                                       ; into the buffer,
  1253.                                       ; up to (but not including) the 1st
  1254.                                       ; space char
  1255.         push_m <ax,bp,si,es,cx>
  1256.         mov   bp,0                    ; set count to 0
  1257.         mov   si,dx
  1258.  
  1259. do_again:
  1260.  
  1261.         mov   ah,ds:[si+bp+2]         ; get count'th char from user's string
  1262.         cmp   ah,SPACE                ; is it a space
  1263.         je    buffer_filled           ; jump if it is
  1264.         cmp   ah,CR                   ; is it CR (= end of string)
  1265.         je    buffer_filled           ; jump as though space was found
  1266.         or    ah,00100000b            ; force char to lower case as in table
  1267.         mov   cs:[buffer+bp],ah       ; put string in buffer
  1268.         inc   bp                      ; increment counter
  1269.         cmp   bp,LHS_LEN              ; all done?
  1270.         jne   do_again                ; loop if not
  1271.         ;
  1272. buffer_filled:
  1273.         ;
  1274.                                       ; We've taken the first word in the
  1275.                                       ; string.  Now take the remainder of the
  1276.                                       ; string and put it in the parameter
  1277.                                       ; buffer, for adding on to the replaced
  1278.                                       ; string after the alias has been
  1279.                                       ; substituted.
  1280.  
  1281.         push_m <di,ax,si,bp>
  1282.         mov    di,offset cs:param_buff  ; adr of buffer
  1283.  
  1284. param1:
  1285.  
  1286.         mov   ah,byte ptr ds:[si+bp+2]  ; get next char from user
  1287.         mov   byte ptr cs:[di],ah       ; put char in buffer and leave
  1288.                                         ; CR at end as terminator
  1289.         cmp   ah,CR
  1290.         je    param_done
  1291.         inc   di
  1292.         inc   si
  1293.         jmp   short param1
  1294.  
  1295. param_done:
  1296.  
  1297.         pop_m  <bp,si,ax,di>
  1298.  
  1299.         pop_m <cx,es,si,bp,ax>
  1300.  
  1301.                                       ; user's string, padded with 0's, is in
  1302.                                       ; buffer, ready to compare to
  1303.                                       ; table entries.      
  1304.  
  1305.         push_m <ax,bx,ds,si,es,di,cx>
  1306.         mov   bh,1                    ; count 30 comparisons
  1307.         mov   di,offset cs:ab_table   ; es:di is the ab_table
  1308.   
  1309. find_match:
  1310.  
  1311.         mov   ax,cs                   ; ds:si is buffer
  1312.         mov   ds,ax
  1313.         mov   si,offset cs:buffer
  1314.         mov   ax,cs
  1315.         mov   es,ax
  1316.         ;
  1317.         mov   cx,LHS_LEN              ; compare for 6 characters
  1318.         repe  cmpsb
  1319.         jne   oops
  1320.         jmp   match_found
  1321.  
  1322. oops:
  1323.  
  1324.         inc   bh                      ; no match found so loop again
  1325.         cmp   bh,TBL_LEN + 1
  1326.         je    no_luck
  1327.         add   di,RHS_LEN + 1          ; jump to next entry
  1328.         add   di,cx                   ; and skip over unchecked characters
  1329.         jmp   find_match              ; from previous pass through loop
  1330.  
  1331. no_luck:
  1332.  
  1333.         pop_m <cx,di,es,si,ds,bx,ax>
  1334.  
  1335.         call  copy_to_psp
  1336.         jmp   ok_to_cont2
  1337.  
  1338. match_found:
  1339.         
  1340.         mov   byte ptr cs:nest_flag,1 ; an expansion took place
  1341.         mov   cs:match_pos,di
  1342.         pop_m <cx,di,es,si,ds,bx,ax>
  1343.                                       ; the position in ab_table at which
  1344.                                       ; the matching string starts, is now
  1345.                                       ; in match_pos.
  1346.                                       ; The string at cs:match_pos 
  1347.                                       ; must be copied
  1348.                                       ; to ds:dx+2. must put match_len
  1349.                                       ; in ds:dx+1.
  1350.         push  ax                         
  1351.         mov   ax,cs:match_pos
  1352.         mov   cs:multi_start,ax       ; set start address to match_pos
  1353.         pop   ax
  1354.  
  1355. do_multi_line:  
  1356.  
  1357.                                       ; Although we have come here, if 
  1358.                                       ; global commands are not set and
  1359.                                       ; the call was not from the DOS
  1360.                                       ; prompt, return to read keybd
  1361.                                       ; instead.  This will make commands
  1362.                                       ; like DEBUG & DIR work properly,
  1363.                                       ; so that it will enter debug, pass
  1364.                                       ; control to the keyboard and then
  1365.                                       ; do a DIR after exiting debug. This
  1366.                                       ; assumes that global expansion is
  1367.                                       ; not set.  If it is, the DIR gets
  1368.                                       ; passed to debug.
  1369.         push_m <ax,bx,bp>
  1370.         mov   bp,sp 
  1371.         mov   ax,ss:[bp+8]  
  1372.         mov   bx,cs:command_cs 
  1373.         cmp   ax,bx 
  1374.         jne   not_from_prompt 
  1375.         mov   ax,ss:[bp+6]  
  1376.         mov   bx,cs:command_ip 
  1377.         cmp   ax,bx     
  1378.         jne   not_from_prompt 
  1379.         jmp   ok_to_continue 
  1380.  
  1381. not_from_prompt:
  1382.  
  1383.         pop_m <bp,bx,ax>
  1384.         cmp   byte ptr cs:expand_from,1
  1385.         je    ok_to_cont2
  1386.         jmp   no_multi_line
  1387.  
  1388. ok_to_continue:
  1389.  
  1390.         pop_m <bp,bx,ax>
  1391.         
  1392. ok_to_cont2:
  1393.  
  1394.         mov   cs:multi_len,0          ; length of string = 0
  1395.         push_all
  1396.         cld
  1397.         push  cs
  1398.         pop   ds
  1399.         mov   si,cs:multi_start       ; lodsb works with ds:si
  1400.  
  1401. multi1:
  1402.  
  1403.         lodsb                         ; get char from string
  1404.         cmp   al,0                    ; end of string reached?
  1405.         je    null_found
  1406.         cmp   al,SEPARATOR            ; multiple command separator?
  1407.         je    ampersand_found
  1408.         mov   bh,cs:multi_len         ; inc length of string & get next char
  1409.         inc   bh
  1410.         mov   cs:multi_len,bh
  1411.         jmp   multi1
  1412.  
  1413. null_found:                           ; end of string found so put into ds:dx
  1414.  
  1415.         pop_all
  1416.         push  ax
  1417.         mov   ax,cs:multi_start
  1418.         mov   cs:match_pos,ax
  1419.         mov   ah,cs:multi_len
  1420.         mov   cs:match_len,ah
  1421.         pop   ax
  1422.         mov   byte ptr cs:multi_line_outstanding,0
  1423.         call  subst                   ; put string from alias table into ds:dx
  1424.         call  expand_percents         ; If we put any % signs into ds:dx
  1425.                                       ; buffer then replace with parameters.
  1426.         call  restore_flags
  1427.         call  echo
  1428.  
  1429.                                       ; We are done.  However, instead of just
  1430.                                       ; IRETing, check to see if an expansion
  1431.                                       ; took place.  If it did, go round and
  1432.                                       ; check again, to allow nesting.
  1433.  
  1434.         cmp    byte ptr cs:nest_flag,1
  1435.         jne    no_nest
  1436.         jmp    find_ab2
  1437.  
  1438. no_nest:                              ; If no expansion took place, don't need
  1439.                                       ; to go round again.
  1440.  
  1441.         iret
  1442.  
  1443. ampersand_found: 
  1444.  
  1445.                                       ; A multiple-command-line separator 
  1446.                                       ; found.  Set starting position to
  1447.                                       ; 1st char after the ampersand, 
  1448.                                       ; so we know where to start from next
  1449.                                       ; time.  Then set the flag so that
  1450.                                       ; we come straight here next time
  1451.                                       ; that the 'get string' interrupt
  1452.                                       ; gets called, to put the next part
  1453.                                       ; of the multi-command line into the
  1454.                                       ; kbd buffer.
  1455.  
  1456.         pop_all
  1457.         push  ax 
  1458.         mov   ax,cs:multi_start 
  1459.         mov   cs:match_pos,ax 
  1460.         mov   ah,cs:multi_len 
  1461.         mov   cs:match_len,ah 
  1462.         pop   ax              
  1463.         mov   byte ptr cs:multi_line_outstanding,1
  1464.         call  subst                   ; Put string from alias table into ds:dx
  1465.         call  expand_percents         ; Expand any percent characters that
  1466.                                       ; were copied from alias table by SUBST.
  1467.         push  ax
  1468.         mov   ah,0
  1469.         mov   al,cs:multi_len
  1470.         add   ax,cs:multi_start
  1471.         inc   ax 
  1472.         mov   cs:multi_start,ax
  1473.         pop   ax
  1474.  
  1475.         call  echo
  1476.         call  restore_flags
  1477.         iret
  1478. ; -----------------------------------------------------------------------
  1479. ;                        P R O C E D U R E S
  1480. ; -----------------------------------------------------------------------
  1481. restore_flags proc                    ; restore flags register before iret
  1482.         push   ax   
  1483.         mov    ax,cs:save_flags
  1484.         push   ax
  1485.         popf
  1486.         pop    ax
  1487.         ret
  1488. restore_flags endp
  1489. ;
  1490. get_vpage proc                        ; get current video page into bh, so
  1491.                                       ; that we use the current video page
  1492.                                       ; for screen I/O.
  1493.         push ax
  1494.         push bx
  1495.         push cx
  1496.         push dx
  1497.         push si
  1498.         push di
  1499.         mov   ah,0fh
  1500.         BIOS_VIDEO                    ; page is in bh
  1501.         pop  di
  1502.         pop  si
  1503.         pop  dx
  1504.         pop  cx
  1505.         pop  ax                       ; gets old BX without destroying new bh
  1506.         mov  bl,al                    ; restore old bl
  1507.         pop  ax                       ; restore old ax
  1508.         ret
  1509.  
  1510. get_vpage  endp
  1511. ;
  1512. crlf    proc                          ; display carriage return and linefeed
  1513.         disp_ch CR 
  1514.         disp_ch LF
  1515.         ret
  1516. crlf    endp
  1517. ;
  1518. are_you_sure      proc                ; asks user "Are you sure you want to?"
  1519.                                       ; Sets confirm to 1 if user hits Y or y,
  1520.                                       ; or sets to 0 otherwsie.  All 
  1521.         push_all                      ; registers preserved.
  1522.         mov   bl,byte ptr cs:colour 
  1523.         mov   si,offset cs:sure_msg
  1524.         call  disp_str_colour         ; display message in current colour
  1525.  
  1526. sure1:
  1527.  
  1528.         mov   ah,8                    ; get key (without echo) into al.
  1529.         int   21h
  1530.         cmp   al,0                    ; if it's a 2-byte code,
  1531.         je    sure1                   ; then go round again.
  1532.         or    al,00100000b            ; make character lower case
  1533.  
  1534.         push_m <ax,bx,cx,si,di>
  1535.         mov   bl,cs:colour            ; get current colour
  1536.         call  get_vpage               ; current page into bh
  1537.         mov   cx,1                    ; do it once
  1538.         mov   ah,9
  1539.         BIOS_VIDEO                    ; echo Y or N to console in correct
  1540.                                       ; colour
  1541.         pop_m <di,si,cx,bx,ax>
  1542.  
  1543.         cmp   al,'y'                  ; Y or y pressed?
  1544.         jne   not_y
  1545.         mov   byte ptr cs:confirm,1   ; set flag to show Y or y typed
  1546.         jmp   short sure_done
  1547. not_y:  cmp   al,'n'
  1548.         jne   sure1                   ; get key again if not y or n
  1549.         mov   byte ptr cs:confirm,0   ; set flag to show Y or y not typed
  1550.  
  1551. sure_done:
  1552.         pop_all
  1553.         call  crlf
  1554.  
  1555.         push_m  <si,di,cx,bx,ax>
  1556.         mov     ah,9
  1557.         mov     al,SPACE
  1558.         mov     bl,WHITE               ; attrib
  1559.         call    get_vpage              ; get vpage into bh
  1560.         mov     cx,1
  1561.         BIOS_VIDEO
  1562.         pop_m   <ax,bx,cx,di,si>
  1563.  
  1564.         ret
  1565. are_you_sure      endp
  1566. ;
  1567. shift_left        proc                ; Remove any leading spaces in the
  1568.                                       ; string at ds:dx+2.  Adjust length of
  1569.                                       ; string in byte at ds:dx+1, to reflect
  1570.                                       ; the number of spaces removed.
  1571.  
  1572.          push_all
  1573.          mov      ah,0                ; we only use al.
  1574.          mov      bp,dx               ; start of func 0Ah's buffer
  1575.          add      bp,2                ; skip to 1st char of user's input
  1576.          mov      si,0                ; user si as a counter
  1577.  
  1578. shift1:
  1579.  
  1580.          mov      al,ds:[bp]          ; get a char from user's string
  1581.          cmp      al,SPACE
  1582.          jne      not_a_space
  1583.          inc      si                  ; inc counter for no. of spaces found
  1584.          inc      bp                  ; point to next char in string
  1585.          jmp      short shift1        ; and round we go again
  1586.  
  1587. not_a_space:                          ; ah holds no. of leading spaces found
  1588.  
  1589.          cmp     si,0                 ; any spaces found?
  1590.          je      shift_done           ; we're finished if none found
  1591.          mov     bp,dx                ; point to start of string again
  1592.          add     bp,2
  1593.          add     bp,si                ; jump over spaces to 1st non-space char
  1594.  
  1595. shift2:
  1596.  
  1597.          mov     al,ds:[bp]           ; get char
  1598.          sub     bp,si                ; adjust bp
  1599.          mov     byte ptr ds:[bp],al  ; move char back, Can't have [bp-si],
  1600.                                       ; hence the above subtraction
  1601.          add     bp,si                ; adjust bp back again
  1602.          inc     bp
  1603.          cmp     al,CR                ; have we just shifted a CR?
  1604.          jne     shift2               ; no, so round again
  1605.  
  1606.          mov     bp,dx                ; CR shifted, so we're done.
  1607.          inc     bp                   ; point to length counter
  1608.          mov     al,ds:[bp]           ; get it
  1609.          sub     ax,si                ; subtract no. of leading spaces. ah is
  1610.                                       ; zero, so ax is really al.
  1611.          mov     byte ptr ds:[bp],al  ; and replace new byte
  1612.  
  1613. shift_done:
  1614.  
  1615.         pop_all
  1616.         ret
  1617. shift_left        endp
  1618. ;
  1619. restore_buffer    proc 
  1620.         push  bp                      ; restore the buffer from the previous
  1621.         push  ax                      ; use of this function, so that alias
  1622.         mov   bp,dx                   ; commands can be recalled with F3.
  1623.         mov   al,cs:kb_str_len
  1624.         mov   byte ptr ds:[bp+1],al
  1625.         mov   al,cs:kb_str_ch1
  1626.         mov   byte ptr ds:[bp+2],al
  1627.         pop   ax
  1628.         pop   bp
  1629.         ret
  1630. restore_buffer    endp
  1631. ;
  1632. copy_to_psp   proc 
  1633.                                       ; although the command is not an alias
  1634.                                       ; command, don't just iret. Instead,
  1635.                                       ; copy the string to a spare part of
  1636.                                       ; memory, and pretend that that area
  1637.                                       ; of memory contains a valid alias.
  1638.                                       ; That way, the DOS command can have
  1639.                                       ; ampersands in it, which will be 
  1640.                                       ; treated properly.
  1641.                                       ;
  1642.                                       ; The spare part of memory used is the
  1643.                                       ; PSP that remains after installation,
  1644.                                       ; at address CS:5Ch.
  1645.  
  1646.         push_m <es,di,si,bp,cx>
  1647.         cld
  1648.         mov   si,dx
  1649.         add   si,2                    ; from ds:si = ds:dx+2
  1650.         push  cs
  1651.         pop   es
  1652.         mov   di,5ch                  ; to es:di = cs:5ch
  1653.         mov   bp,dx
  1654.         mov   cl,byte ptr ds:[bp+1] 
  1655.         mov   ch,0                    ; copy correct number of bytes
  1656.         rep   movsb
  1657.         mov   byte ptr es:[di],0      ; put null at end
  1658.         pop_m <cx,bp,si,di,es>
  1659.         ;
  1660.         mov   cs:match_pos,5ch
  1661.         mov   cs:multi_start,5ch
  1662.         mov   byte ptr cs:multi_line_outstanding,0
  1663.         ret
  1664. copy_to_psp   endp
  1665. ;
  1666. ab_buffer       proc                    ;Display the DOSEDIT buffer.
  1667.  
  1668.         push_all
  1669.         mov    byte ptr cs:list_count,0 ; count no of lines displayed
  1670.         call   get_lines
  1671.         mov    si,word ptr cs:cmdold    ; get adr of 1st byte of oldest cmd
  1672.         mov    bp,word ptr cs:cmdpnt    ; get adr of 1st byte of current cmd
  1673.         dec    bp                       ; prevent double crlf after listing
  1674.  
  1675. buf_top:
  1676.  
  1677.         mov    bl,byte ptr cs:colour    ; get current ALIAS colour
  1678.         call   crlf
  1679.  
  1680.         inc    byte ptr cs:list_count
  1681.         push   ax
  1682.         mov    ah,byte ptr cs:page_len
  1683.         cmp    byte ptr cs:list_count,ah
  1684.         pop    ax
  1685.         jne    scr_not_full
  1686.         call   list_pause             ; Press Any Key to Continue
  1687.  
  1688. scr_not_full:
  1689.  
  1690.         push_all
  1691.         call   disp_str_colour          ; show string on screen
  1692.         pop_all
  1693.  
  1694. get_again:
  1695.  
  1696.         mov    ah,byte ptr cs:[si]      ; get 1st char of command again
  1697.         cmp    ah,0                     ; end of command?
  1698.         je     new_command              ; yes...
  1699.         call   cmdinc                   ; no, so inc pointer
  1700.         jmp    short get_again          ; and keep looking
  1701.  
  1702. new_command:
  1703.  
  1704.         cmp    si,bp                    ; are all commands printed?
  1705.         je     buf_done
  1706.         call   cmdinc                   ; point to start of next command
  1707.         jmp    short buf_top            ; and start all over again
  1708.  
  1709. buf_done:
  1710.  
  1711.         pop_all
  1712.  
  1713.         disp_ch LF
  1714.         push_m  <di,si,cx,bx,ax>             ; Display a white space.
  1715.         mov     ah,9
  1716.         mov     al,SPACE
  1717.         mov     bl,WHITE               ; attrib
  1718.         call    get_vpage              ; video page into bh
  1719.         mov     cx,1
  1720.         bios_video
  1721.         pop_m   <ax,bx,cx,si,di>
  1722.  
  1723.         ret
  1724. ab_buffer       endp
  1725. ;
  1726. subst   proc
  1727.                                       ; This procedure gets a string which 
  1728.                                       ; starts at cs:match_pos with length
  1729.                                       ; cs:match_len, and puts it in the 
  1730.                                       ; buffer which is set up for a string
  1731.                                       ; by a routine that calls DOS 
  1732.                                       ; function 0Ah.  The string will be 
  1733.                                       ; placed in ram starting at ds:dx+2.
  1734.                                       ; Its length will get put in ds:dx+1
  1735.                                       ; and a carriage return gets put at 
  1736.                                       ; the end of the string, though this 
  1737.                                       ; is not included in the char count.
  1738.  
  1739.  
  1740.         push_all
  1741.         push   cs
  1742.         pop    es                     ; source segment
  1743.         mov    bp,dx                  ; destination segment
  1744.         mov    bl,byte ptr ds:[bp]    ; get length of buffer
  1745.         mov    bh,0                   ; counter
  1746.         add    bp,2                   ; destination offset
  1747.         mov    si,cs:match_pos        ; start of string
  1748.         mov    cl,cs:match_len        ; length
  1749.         cmp    cl,0                   ; is string empty (ie user just pressed
  1750.                                       ; RETURN)
  1751.         jne    keep_on
  1752.         mov    byte ptr ds:[bp],CR    ; put CR at end(!) of empty string
  1753.         jmp    short subst_done
  1754.  
  1755. keep_on:
  1756.  
  1757.         mov    al,es:[si]             ; get char from string
  1758.         mov    byte ptr ds:[bp],al    ; and put it in place
  1759.         dec    cl                     ; count down till whole string copied
  1760.         inc    si                     ; inc source pointer
  1761.         inc    bp                     ; inc dest pointer
  1762.         inc    bh
  1763.         cmp    cl,0                   ; are we done?
  1764.         je     stuffed
  1765.         cmp    bh,bl                  ; or is buffer full?
  1766.         je     stuffed
  1767.         jmp    short keep_on
  1768.  
  1769. stuffed:
  1770.  
  1771.         mov    byte ptr ds:[bp],CR    ; put CR at end
  1772.  
  1773.         push   bp                     ; set length
  1774.         push   ax
  1775.         mov    ah,cs:match_len
  1776.         mov    bp,dx
  1777.         add    bp,1
  1778.         mov    ds:[bp],ah         
  1779.         pop    ax
  1780.         pop    bp
  1781.         pop_all
  1782.  
  1783. subst_done:
  1784.  
  1785.         ret
  1786. subst   endp
  1787. ;
  1788. expand_percents proc
  1789.  
  1790.                                       ; This proc takes the contents of the
  1791.                                       ; buffer at ds:dx, which SUBST has
  1792.                                       ; copied an alias into, and expands any
  1793.                                       ; %n characters into the correct strings
  1794.                                       ; taken from param_buff.
  1795.  
  1796.                                       ; Percent params are handled by Alias in
  1797.                                       ; the same way as DOS batch files,except
  1798.                                       ; that there is no %0 implementation,and
  1799.                                       ; there is a %*, which is the whole
  1800.                                       ; parameter buffer.
  1801.  
  1802.         push_all
  1803.  
  1804. expand_vtop:
  1805.  
  1806.         mov    si,dx                  ; point to start of ds:dx buffer
  1807.         inc    si
  1808.  
  1809. expand_top:
  1810.  
  1811.         inc    si
  1812.         mov    al,byte ptr ds:[si]    ; get char from buffer
  1813.         cmp    al,CR                  ; are we at the end of the buffer?
  1814.         jne    ok
  1815.         jmp    expand_done
  1816. ok:
  1817.         cmp    al,'%'                 ; is the char a percent?
  1818.         je     percent_found          ; jump if so
  1819.         jmp    short expand_top
  1820.  
  1821. percent_found:
  1822.  
  1823.         mov    byte ptr cs:star_flag,0
  1824.  
  1825.                                       ; a percent was found in ds:dx buffer.
  1826.                                       ; It's only valid and expandable if
  1827.                                       ; followed by a digit.
  1828.  
  1829.                                       ; Check si+1, which must be a digit
  1830.                                       ; If we find %*, change it to %1, but
  1831.                                       ; set an internal flag.
  1832.  
  1833.         cmp    byte ptr ds:[si+1],'*'
  1834.         jne    expand12
  1835.         mov    byte ptr ds:[si+1],'1'
  1836.         mov    byte ptr cs:star_flag,1
  1837.  
  1838. expand12:
  1839.  
  1840.         cmp    byte ptr ds:[si+1],'1'
  1841.         jb     expand_top
  1842.         cmp    byte ptr ds:[si+1],'9'
  1843.         ja     expand_top
  1844.  
  1845.  
  1846.                                       ; SI is pointing to a percent char,
  1847.                                       ; which is the start of a valid
  1848.                                       ; parameter sequence.
  1849.  
  1850.         mov    cl,byte ptr ds:[si+1]  ; get the parameter
  1851.         sub    cl,'0'                 ; convert to binary digit
  1852.  
  1853.                                       ; Before we copy parameter in, check
  1854.                                       ; that a) it exists, and b) that it will
  1855.                                       ; fit into the buffer.
  1856.  
  1857.                                       ; Count the number of parameters, to see
  1858.                                       ; if cl exists.
  1859.  
  1860.         push   bp
  1861.         push   bx
  1862.         mov    bp,offset cs:param_buff
  1863.         mov    bh,0
  1864.  
  1865. counter_top:
  1866.  
  1867.         mov    bl,byte ptr cs:[bp]
  1868.         cmp    bl,CR
  1869.         je     counter_done
  1870.         cmp    bl,SPACE
  1871.         je     param_found
  1872.         inc    bp
  1873.         jmp    short counter_top
  1874.  
  1875. param_found:
  1876.  
  1877.         inc    bh
  1878.         inc    bp
  1879.         jmp    short counter_top
  1880.  
  1881. counter_done:
  1882.  
  1883.         cmp    bh,cl                  ; did we find enough parameters?
  1884.         pop    bx
  1885.         pop    bp
  1886.  
  1887.         jae    enough_params
  1888.  
  1889.                                       ; There are not enough params to expand
  1890.                                       ; the % sign currently pointed to by si.
  1891.                                       ; Delete % and the digit.  This is the
  1892.                                       ; way that DOS handles this situation.
  1893.  
  1894.         push   bp
  1895.         mov    bp,si
  1896.         call   close_up_buffer        ; Delete char at bp, and amend length
  1897.         call   close_up_buffer
  1898.         pop    bp
  1899.         dec    si                     ; compensate for expand_top's inc si
  1900.         jmp    short expand_top
  1901.  
  1902.  
  1903. enough_params:
  1904.  
  1905.                                       ; parameter cl exists.  If it will fit,
  1906.                                       ; it can be copied in, but we don't
  1907.                                       ; yet know if it will fit...
  1908.  
  1909.                                       ; find out if parameter cl will fit.
  1910.                                       ; dx = length of buffer, dx+1 holds
  1911.                                       ; current number of chars in buffer.
  1912.                                       ; If length of parameter
  1913.                                       ; <= ([dx]-[dx+1]-1) then all is well.
  1914.  
  1915.                                       ; First, get length of parameter
  1916.         mov    bp,offset cs:param_buff
  1917.         mov    bh,0
  1918.  
  1919. expand5:
  1920.  
  1921.         mov    bl,byte ptr cs:[bp]    ; get char from param_buff
  1922.         cmp    bl,SPACE
  1923.         je     expand4
  1924.         inc    bp
  1925.         jmp    short expand5
  1926.  
  1927. expand4:
  1928.  
  1929.         inc    bp
  1930.         inc    bh
  1931.         cmp    bh,cl
  1932.         jne    expand5
  1933.  
  1934.                                       ; bp contains start of parameter.
  1935.                                       ; Count till next space, or CR, found.
  1936.  
  1937.         mov    bh,0
  1938.         mov    ax,bp                  ; preserve start of parameter
  1939.  
  1940. expand7:
  1941.  
  1942.         mov    bl, byte ptr cs:[bp]
  1943.  
  1944.         cmp    byte ptr cs:star_flag,1
  1945.         je     expand14               ; don't stop at spaces if %*
  1946.  
  1947.         cmp    bl,SPACE
  1948.         je     expand6
  1949.  
  1950. expand14:
  1951.  
  1952.         cmp    bl,CR
  1953.         je     expand6
  1954.         inc    bp
  1955.         inc    bh
  1956.         jmp    short expand7
  1957.  
  1958. expand6:
  1959.  
  1960.                                       ; bh contains length of parameter cl
  1961.  
  1962.         mov    di,dx
  1963.         mov    ch,byte ptr ds:[di]    ; ch = length of buffer,
  1964.         mov    cl,byte ptr ds:[di+1]  ; cl = chars in buffer
  1965.                                       ; Note: This is not the same as
  1966.                                       ; mov cx,word ptr ds:[di], as that would
  1967.                                       ; leave ch and cl transposed.
  1968.  
  1969.         sub    ch,cl
  1970.         dec    ch                     ; ch now contains space left in buffer
  1971.         cmp    bh,ch
  1972.  
  1973.         jna    expand_fits            ; jump if not above.
  1974.                                       ; Can't use jle, cos that's for
  1975.                                       ; signed numbers.
  1976.  
  1977.         call   no_fit                 ; warn user that it doesn't fit.
  1978.         jmp    expand_done            ; parameter will not fit, so quit.
  1979.  
  1980. expand_fits:                          ; parameter will fit so copy it
  1981.  
  1982.  
  1983.                                       ; copy parameter starting at ds:[ax] and
  1984.                                       ; finishing with SPACE or CR into
  1985.                                       ; ds:dx buffer.  Delete the % and the
  1986.                                       ; following 2 chars.  Amend length.
  1987.  
  1988.         mov    di,si
  1989.         mov    si,ax                  ; source is now si, dest is di
  1990.  
  1991.                                       ; First, close up the gap.
  1992.                                       ; Delete char at di, di+1 and di+2,
  1993.                                       ; and amend length.
  1994.  
  1995.         push   bp
  1996.         mov    bp,di
  1997.         call   close_up_buffer        ; delete the %
  1998.         call   close_up_buffer        ; delete the digit
  1999.         pop    bp
  2000.  
  2001.  
  2002.                                       ; now copy in the string
  2003.  
  2004. expand9:
  2005.  
  2006.         mov    al,byte ptr cs:[si]    ; get char
  2007.  
  2008.         cmp    byte ptr cs:star_flag,1
  2009.         je     expand15               ; don't stop at spaces if %*
  2010.  
  2011.         cmp    al,SPACE
  2012.         je     expand11
  2013.  
  2014. expand15:
  2015.  
  2016.         cmp    al,CR
  2017.         je     expand11
  2018.         call   put_in_dsdx            ; insert al into ds:dx buffer at [di].
  2019.                                       ; di returns pointing at new char.
  2020.  
  2021.         inc    si
  2022.         jmp    short expand9
  2023.  
  2024. expand11:
  2025.  
  2026.         jmp    expand_vtop            ; Every time, we start parsing from
  2027.                                       ; dx+2, rather than from where we left
  2028.                                       ; off last time.  This is not the most
  2029.                                       ; efficient coding!
  2030.  
  2031. expand_done:
  2032.  
  2033.         pop_all                       ; Finished proc.  Params substituted.
  2034.  
  2035.         ret
  2036. expand_percents endp
  2037. ;
  2038. close_up_buffer    proc
  2039.  
  2040.  
  2041.                                       ; delete the char at [bp] in a buffer,
  2042.                                       ; whose length is at dx+1. Amend length.
  2043.  
  2044.         push   bp
  2045.         push   ax
  2046.  
  2047.         inc    bp                     ; point past the char to delete
  2048.  
  2049. close1:
  2050.  
  2051.         mov    al,ds:[bp]             ; get a char
  2052.         mov    byte ptr ds:[bp-1], al ; shift the char left
  2053.         cmp    al,CR                  ; are we done
  2054.         je     closed
  2055.         inc    bp
  2056.         jmp    short close1
  2057.  
  2058. closed:
  2059.  
  2060.                                       ; char is deleted.  Amend length.
  2061.  
  2062.         mov    bp,dx
  2063.         inc    bp                     ; point to length
  2064.         mov    al,byte ptr ds:[bp]    ; get length
  2065.         dec    al                     ; decrement it
  2066.         mov    byte ptr ds:[bp],al    ; and write new value back
  2067.         pop    ax
  2068.         pop    bp
  2069.         ret
  2070. close_up_buffer endp
  2071. ;
  2072. put_in_dsdx proc                      ; insert al into ds:dx buffer at ds:[di]
  2073.                                       ; di returns pointing at new char
  2074.                                       ; Update length at dx+1
  2075.         push   si
  2076.         push   ax
  2077.         push   bx
  2078.  
  2079.         mov    si,dx                  ; point to start of buffer
  2080.         inc    si                     ; point to length
  2081.         mov    bl,byte ptr ds:[si]    ; get length
  2082.  
  2083.         inc    bl
  2084.         mov    byte ptr ds:[si],bl    ; update length while we're here
  2085.         dec    bl
  2086.  
  2087.         mov    bh,0
  2088.         add    si,bx                  ; point to terminating CR
  2089.         inc    si
  2090.         inc    si
  2091.  
  2092. put_in:
  2093.  
  2094.         dec    si
  2095.         mov    ah,byte ptr ds:[si]    ; get char from string
  2096.         mov    byte ptr ds:[si+1],ah  ; shift it right
  2097.         cmp    si,di                  ; are we done?
  2098.         jne    put_in
  2099.         mov    byte ptr ds:[di],al    ; insert char in newly created space
  2100.         inc    di
  2101.  
  2102.         pop    bx
  2103.         pop    ax
  2104.         pop    si
  2105.  
  2106.         ret
  2107.  
  2108. put_in_dsdx endp
  2109. ;
  2110. no_fit  proc                          ; The string can't be expanded, cos it
  2111.                                       ; will end up longer than the ds:dx
  2112.                                       ; buffer provided for it.  Clear the
  2113.                                       ; buffer and display a warning message.
  2114.         mov    bp,dx
  2115.         mov    byte ptr ds:[bp+1],0   ; set length to 0
  2116.         mov    byte ptr ds:[bp+2],CR  ; add a CR on end
  2117.         mov    bl,cs:colour
  2118.         mov    si,offset cs:no_fit_msg
  2119.         call   disp_str_colour
  2120.         ret
  2121. no_fit  endp
  2122. ;
  2123. echo    proc
  2124.                                       ; This routine is called once the
  2125.                                       ; aliased string has been assembled
  2126.                                       ; at ds:dx+2, and immediately before
  2127.                                       ; the IRET.  If echo is turned on,
  2128.                                       ; we echo the string at ds:dx+2 to the
  2129.                                       ; console, in the current colour, and
  2130.                                       ; enclosed in square brackets.
  2131.                                       ; This echo only occurs if the string
  2132.                                       ; was placed at ds:dx+2 because an alias
  2133.                                       ; was found in the table.  If no 
  2134.                                       ; substitution ocurred, there's no echo.
  2135.  
  2136.  
  2137.         cmp   byte ptr cs:echo_status,1   ; do we want echo?
  2138.         je    echo_wanted
  2139.         jmp   not_required
  2140.  
  2141. echo_wanted:
  2142.  
  2143.         call  crlf    
  2144.         push_all
  2145.         mov   si,offset cs:left_sq_br ; display a '[' in current colour
  2146.         mov   bl,cs:colour
  2147.         call  disp_str_colour
  2148.         pop_all
  2149.  
  2150.  
  2151.         push_all
  2152.         mov   si,dx                   ; start of string
  2153.         add   si,2
  2154.         mov   bl,cs:colour            ; screen attribute to use
  2155.  
  2156.         mov   bp,dx
  2157.         mov   al,ds:[bp+1]            ; get length of string
  2158.         mov   ah,0
  2159.         add   bp,ax                   ; point to CR at end of string
  2160.         add   bp,2                    ; skip first 2 bytes
  2161.         mov   byte ptr ds:[bp],0      ; change CR to a 0 for use with proc
  2162.  
  2163.         push_all
  2164.         mov   byte ptr cs:echo_flag,1 ; 'cos string is in ds
  2165.         call  disp_str_colour         ; display 0-terminated string
  2166.         mov   byte ptr cs:echo_flag,0 ; back to cs for other procs to use
  2167.         pop_all
  2168.  
  2169.         mov   byte ptr ds:[bp],CR     ; put the CR back
  2170.         pop_all
  2171.  
  2172.         push_all
  2173.         mov   si,offset cs:rght_sq_br ; display a ']' in current colour
  2174.         mov   bl,cs:colour
  2175.         call  disp_str_colour
  2176.         pop_all
  2177.         disp_ch LF                   ; ensure DOS default colour returns to
  2178.                                      ; white.
  2179.  
  2180. not_required:
  2181.         ret
  2182. echo    endp
  2183. ;
  2184. ab_none proc                          ; ALIAS N turns off aliases
  2185.         mov   byte ptr cs:ab_status,0
  2186.         call  crlf
  2187.         ret
  2188. ab_none endp
  2189. ; 
  2190. ab_info proc                          ; ALIAS I displays info
  2191.         push_m <dx,ds,ax>             ; Display version number
  2192.         mov   ax,cs
  2193.         mov   ds,ax
  2194.         push_m <bx,si>
  2195.         mov   si,offset cs:version
  2196.         mov   bl,cs:colour 
  2197.         call  disp_str_colour
  2198.         pop_m <si,bx>
  2199.         pop_m <ax,ds,dx>
  2200.         ; 
  2201.         push_all
  2202.         cmp   byte ptr cs:ab_status,0 ; don't display show/hide if off
  2203.         je    info2
  2204.         cmp   byte ptr cs:echo_status,0 ; display show or hide
  2205.         je    info1
  2206.         mov   si,offset cs:msg_show
  2207.         mov   bl,byte ptr cs:colour
  2208.         call  disp_str_colour
  2209.         jmp   info2
  2210.  
  2211. info1:
  2212.  
  2213.         mov   si,offset cs:msg_hide
  2214.         mov   bl,byte ptr cs:colour
  2215.         call  disp_str_colour
  2216.  
  2217. info2:                                ; display on/off/global
  2218.  
  2219.         cmp   byte ptr cs:ab_status,0
  2220.         je    info3
  2221.         cmp   byte ptr cs:expand_from,0
  2222.         je    info4
  2223.         mov   si,offset cs:msg_global
  2224.         mov   bl,byte ptr cs:colour
  2225.         call  disp_str_colour
  2226.         jmp   info6
  2227.  
  2228. info4:
  2229.  
  2230.         mov   si,offset cs:msg_prompt
  2231.         mov   bl,byte ptr cs:colour
  2232.         call  disp_str_colour
  2233.         jmp   info6
  2234.  
  2235. info3:
  2236.  
  2237.         mov   si,offset cs:msg_off
  2238.         mov   bl,byte ptr cs:colour
  2239.         call  disp_str_colour
  2240.  
  2241. info6:
  2242.  
  2243.         pop_all
  2244.         call  disp_def_fn               ; display full path of default file
  2245.         call  alias_count               ; display no of aliases, + table size
  2246.  
  2247.         push_m  <si,di,cx,bx,ax>             ; Display a white space.
  2248.         mov     ah,9
  2249.         mov     al,SPACE
  2250.         mov     bl,WHITE               ; attrib
  2251.         call    get_vpage              ; video page into bh
  2252.         mov     cx,1
  2253.         bios_video
  2254.         pop_m   <ax,bx,cx,di,si>
  2255.  
  2256.         ret  
  2257. ab_info endp
  2258. ; 
  2259. disp_def_fn   proc                      ; Display the default file name that
  2260.                                         ; will be used in ALIAS W commands.
  2261.                                         ; If the def_dir string is empty,
  2262.                                         ; display default_fn.  If def_dir is
  2263.                                         ; not empty, it is the path and file
  2264.                                         ; that was loaded at install time, so
  2265.                                         ; it's the one to display.
  2266.  
  2267.         push_all
  2268.         mov   si,offset cs:def_fn_msg
  2269.         mov   bl,byte ptr cs:colour
  2270.         call  disp_str_colour
  2271.  
  2272.         mov   si,offset cs:default_fn   ; use the non-pathed file?
  2273.         mov   al,byte ptr cs:[def_dir]  ; get 1st byte of pathed string
  2274.         cmp   al,0                      ; is it empty?
  2275.         je    use_non                   ; yes, so stay as we are
  2276.         mov   si,offset cs:defdir_hdr   ; pathed string exists so use instead.
  2277.  
  2278. use_non:
  2279.  
  2280.         mov   bl,byte ptr cs:colour
  2281.         call  disp_str_colour
  2282.         pop_all
  2283.         ret
  2284. disp_def_fn   endp
  2285. ;
  2286. alias_count   proc                      ; Called by ALIAS I command to display
  2287.                                         ; the number of defined/undefined
  2288.                                         ; aliases.
  2289.  
  2290.         call  count_aliases             ; count entries in table and plug the
  2291.                                         ; numbers into the string about to be
  2292.                                         ; displayed.
  2293.         push_all
  2294.         mov   si,offset cs:count_msg    ; display the message
  2295.         mov   bl, byte ptr cs:colour
  2296.         call  disp_str_colour
  2297.         pop_all
  2298.         ret
  2299. alias_count   endp
  2300. ;
  2301. count_aliases  proc
  2302.  
  2303.         push_m <ax,bx,cx,dx,bp>
  2304.         mov    ax,0                     ; count full entries in ax
  2305.         mov    bx,0                     ; count total table entries in bx
  2306.         mov    bp,offset cs:ab_table    ; start of the table
  2307.  
  2308. count_top:
  2309.  
  2310.         mov    dh,byte ptr cs:[bp]      ; get 1st char from table entry
  2311.         cmp    dh,0F0h
  2312.         je     count_done
  2313.         cmp    dh,0                     ; is entry full?
  2314.         je     count_empty              ; no, then it's empty!
  2315.         inc    ax                       ; full entries
  2316.  
  2317. count_empty:
  2318.  
  2319.         inc    bx                       ; total entries
  2320.         add    bp,RHS_LEN + LHS_LEN + 1 ; point to next entry
  2321.         jmp    short count_top
  2322.  
  2323. count_done:
  2324.  
  2325.                                         ; ax and bx contain totals. Now plug
  2326.                                         ; them in.
  2327.         aam                             ; put digits of ax into ah and al
  2328.         add    ax,3030h                 ; convert to ascii
  2329.         mov    bp,offset cs:count_msg1
  2330.         mov    byte ptr cs:[bp],ah
  2331.         mov    byte ptr cs:[bp+1],al
  2332.  
  2333.         mov    ax,bx                    ; Now do the second number
  2334.         aam
  2335.         add    ax,3030h
  2336.         mov    bp,offset cs:count_msg2
  2337.         mov    byte ptr cs:[bp],ah
  2338.         mov    byte ptr cs:[bp+1],al
  2339.  
  2340.         pop_m  <bp,dx,cx,bx,ax>
  2341.         ret
  2342. count_aliases  endp
  2343. ;
  2344. ab_prompt     proc
  2345.         mov   byte ptr cs:expand_from,0 ; expand from dos prompt
  2346.         mov   byte ptr cs:ab_status,1   ; turn on
  2347.         call  crlf
  2348.         ret
  2349. ab_prompt     endp
  2350. ;
  2351. ab_global     proc
  2352.         mov   byte ptr cs:expand_from,1 ; expand globally
  2353.         mov   byte ptr cs:ab_status,1   ; turn on
  2354.         call  crlf
  2355.         ret
  2356. ab_global     endp
  2357. ;
  2358. ab_help proc                          ; ALIAS ? gives help
  2359.         push_m <bx,si,dx,ds,ax>
  2360.         mov   bl,cs:colour 
  2361.         mov   si,offset cs:help_text
  2362.         call  disp_str_colour
  2363.         pop_m <ax,ds,dx,si,bx>
  2364.         ret
  2365. ab_help endp
  2366. ; 
  2367. ab_add  proc                          ; ALIAS A <arg> <string>
  2368.  
  2369.                                       ; Before doing anything else,check that
  2370.                                       ; user left a space between ALIAS A and
  2371.                                       ; the arg, or prog will hang.  ie, 
  2372.                                       ; abort if [dx+9] is not a space.
  2373.  
  2374.         push_m <ax,bp>
  2375.         mov   bp,dx
  2376.         mov   ah,byte ptr ds:[bp+9]   ; get the char between ALIAS L and arg
  2377.         cmp   ah,' '                  ; is it a space
  2378.         pop_m <bp,ax>
  2379.         je    ok_space3               ; continue if ok. Can't write jne 'cos
  2380.                                       ; out of range.
  2381.         call  syntax_error            ; error - no action taken
  2382.         jmp   add_err                 ; if not a space, abort A command
  2383.  
  2384. ok_space3:
  2385.  
  2386.         call  to_lower                ; Make the LHS part of the alias lower
  2387.                                       ; case.  Leave the RHS part as it is,
  2388.                                       ; because user may want to specify
  2389.                                       ; a case-specific alias, for example
  2390.                                       ; as command-line options on MS C.
  2391.  
  2392.         push_m <ax,bx,cx,dx,bp,si>
  2393.         mov   si,0                    ; count length of arg
  2394.         mov   bp,dx
  2395.         add   bp,10                   ; point to arg
  2396.  
  2397. add2:
  2398.  
  2399.         mov   ah,ds:[bp+si]           ; get arg character
  2400.                                       ; is it c/r?  If so, no string was
  2401.                                       ; typed so abort
  2402.         cmp   ah,CR 
  2403.         jne   not_cr
  2404.         pop_m <si,bp,dx,cx,bx,ax>
  2405.         call  syntax_error
  2406.         jmp   add_err                 ; abort
  2407.      
  2408. not_cr:
  2409.  
  2410.         cmp   ah,' '                  ; is it a space?
  2411.         je    add1
  2412.         cmp   si,LHS_LEN              ; or have we done 6 chars?
  2413.         je    add1    
  2414.         inc   si                      ; no. point to next char
  2415.         jmp   add2
  2416.  
  2417. add1:
  2418.  
  2419.         mov   bx,si
  2420.         mov   cs:arg_end,bl           ; arg_end is length of arg
  2421.         ; 
  2422.         mov   si,0
  2423.         mov   bp,dx
  2424.  
  2425.         add   bp,10                   ; point to 1st char of lhs
  2426.         mov   al,cs:arg_end
  2427.         mov   ah,0
  2428.         add   bp,ax
  2429.                                       ; bp should now point to a space, and
  2430.                                       ; incrementing it will point to the
  2431.                                       ; start of the rhs.  But this will not
  2432.                                       ; be so if the lhs was > 6 chars, so
  2433.                                       ; so we may need to add more to bp.
  2434.  
  2435. add11:
  2436.  
  2437.         cmp   byte ptr ds:[bp],SPACE  ; are we ok?
  2438.         je    add10                   ; yes, so point to rhs and we're ok
  2439.         inc   bp
  2440.         jmp   short add11
  2441.  
  2442. add10:
  2443.  
  2444.         inc   bp
  2445.  
  2446. add3:    
  2447.  
  2448.         mov   ah,ds:[bp+si]            
  2449.         cmp   ah,CR                   ; end of string
  2450.         je    add4
  2451.         cmp   si,RHS_LEN              ; truncate if necessary
  2452.         je    add4
  2453.         inc   si
  2454.         jmp   add3
  2455.  
  2456. add4:
  2457.  
  2458.         mov   bx,si
  2459.         mov   cs:str_end,bl
  2460.                                       ; Arg starts at dx+10, length arg_end. 
  2461.                                       ; Str starts at dx+11+arg_end, 
  2462.                                       ; with length str_end
  2463.         pop_m <si,bp,dx,cx,bx,ax>
  2464.         ; 
  2465.         cmp   byte ptr cs:arg_end,LHS_LEN
  2466.         jbe   add6                    ; must be < 6 chars
  2467.         jmp   add_err                 ; else give error and exit.
  2468.                                       ; Actually, string has been truncated
  2469.                                       ; above, so it should never fail here.
  2470.  
  2471. add6:
  2472.  
  2473.         cmp   byte ptr cs:str_end,RHS_LEN ; Ensure length of rhs string is OK.
  2474.                                           ; It should be, cos it was truncated
  2475.                                           ; by the routines above.
  2476.         jbe   add7
  2477.         jmp   add_err
  2478.  
  2479. add7:
  2480.  
  2481.         push_m <es,di,cx,ax>          ; fill 6-char buffer with 0's
  2482.         cld
  2483.         mov   ax,cs
  2484.         mov   es,ax
  2485.         mov   al,0
  2486.         mov   di,offset cs:buffer2
  2487.         mov   cx,LHS_LEN
  2488.         rep   stosb
  2489.         pop_m <ax,cx,di,es>
  2490.  
  2491.                                       ; Put arg into buffer.
  2492.  
  2493.         push_m <ax,cx,dx,es,ds,di,si>
  2494.         cld
  2495.         mov   ax,cs
  2496.         mov   si,dx
  2497.         add   si,10                   ; copy from ds:dx+10
  2498.         mov   es,ax
  2499.         mov   di,offset cs:buffer2    ; copy to buffer
  2500.         mov   cl,cs:arg_end           ; no of bytes to copy
  2501.         mov   ch,0
  2502.         rep   movsb
  2503.         pop_m <si,di,ds,es,dx,cx,ax>
  2504.         ; 
  2505.                                       ; Now scan buffer vs table,
  2506.                                       ; to ensure that
  2507.                                       ; arg doesn't already exist
  2508.         push_m <ax,bx,cx,ds,es,di,si>
  2509.         mov   bh,1                    ; count for up to 30 comparisons
  2510.         mov   di,offset cs:ab_table
  2511.  
  2512. scan:
  2513.  
  2514.         mov   ax,cs
  2515.         mov   es,ax
  2516.         mov   ds,ax
  2517.         mov   si,offset cs:buffer2
  2518.         mov   cx,LHS_LEN
  2519.         cld
  2520.         repe  cmpsb
  2521.         jne   scan2
  2522.         jmp   already_in_table
  2523.  
  2524. scan2:                                ; no match, so loop again
  2525.  
  2526.         inc   bh
  2527.         cmp   bh,TBL_LEN + 1
  2528.         je    not_in_table
  2529.         add   di,RHS_LEN + 1
  2530.         add   di,cx
  2531.         jmp   scan
  2532.  
  2533. already_in_table:                     ; can't add, cos it already exists
  2534.  
  2535.         pop_m <si,di,es,ds,cx,bx,ax>
  2536.         call  exist_err                 ; display error msg
  2537.         ret
  2538.  
  2539. not_in_table:
  2540.  
  2541.         pop_m <si,di,es,ds,cx,bx,ax>
  2542.                                       ; we have a string that does not
  2543.                                       ; already exist. Now find an empty
  2544.                                       ; table entry
  2545.         push_m <ax,bx,bp>
  2546.         mov   bh,1                    ; do up to 30 comparisons
  2547.         mov   bp,offset cs:ab_table   ; start of table
  2548.  
  2549. keep_looking:
  2550.  
  2551.         mov   ah,cs:[bp]              ; get 1st char of arg
  2552.         cmp   ah,0                    ; if char is 0 then space is free
  2553.         je    entry_spare          
  2554.         add   bh,1                    ; inc counter
  2555.         add   bp,LHS_LEN+RHS_LEN+1
  2556.         cmp   bh,TBL_LEN + 1          ; all done?
  2557.         jne   keep_looking            ; no , so round again
  2558.         pop_m <bp,bx,ax>              ; no space, so quit
  2559.         call  table_full              ; and display error message
  2560.         ret
  2561.  
  2562. entry_spare:
  2563.  
  2564.         mov   cs:spare,bp             ; 1st byte of table entry
  2565.         pop_m <bp,bx,ax>
  2566.         ; 
  2567.                                       ; fill table from spare for 77
  2568.                                       ; bytes, with 0
  2569.         push_m <di,es,cx,ax>
  2570.         cld
  2571.         mov   ax,cs
  2572.         mov   es,ax             
  2573.         mov   di,cs:spare
  2574.         mov   cx,LHS_LEN + RHS_LEN + 1
  2575.         mov   al,0
  2576.         rep   stosb
  2577.         pop_m <ax,cx,es,di>
  2578.         ; 
  2579.         push_m <ax,cx,di,si,es>
  2580.  
  2581.         mov   ax,dx
  2582.         add   ax,10
  2583.         mov   si,ax                   ; copy arg from ds:di
  2584.         mov   ax,cs
  2585.         mov   es,ax                   ; to es:di
  2586.         mov   di,cs:spare
  2587.         mov   ch,0
  2588.         mov   cl,cs:arg_end
  2589.         rep   movsb
  2590.         ; 
  2591.         mov   ax,dx
  2592.         add   ax,10
  2593.         mov   bh,0
  2594.         mov   bl,cs:arg_end
  2595.         add   ax,bx
  2596.         mov   si,ax                   ; copy string from ds:si.
  2597.                                       ; SI currently points to the space
  2598.                                       ; before the rhs in the user's string.
  2599.                                       ; However, if the user entered an lhs
  2600.                                       ; that was too long we need to skip over
  2601.                                       ; those extra chars that are here.
  2602.  
  2603. add14:
  2604.  
  2605.         cmp   byte ptr ds:[si],SPACE  ; are we in the right place
  2606.         je    add12                   ; yes, then carry on
  2607.         inc   si                      ; else point to next char and try again
  2608.         jmp   short add14
  2609.  
  2610. add12:
  2611.  
  2612.         inc   si
  2613.         mov   ax,cs
  2614.         mov   es,ax                   ; to es:di
  2615.         mov   di,cs:spare
  2616.         add   di,LHS_LEN              ; copy to string, not arg
  2617.         mov   ch,0
  2618.         mov   cl,cs:str_end           ; no of chars to copy
  2619.         rep   movsb
  2620.         ; 
  2621.         pop_m <es,si,di,cx,ax>
  2622.  
  2623. add5:
  2624.  
  2625.         call  crlf
  2626.  
  2627. add_err:
  2628.  
  2629.         ret
  2630. ab_add  endp
  2631.         ; 
  2632. table_full    proc                    ; display 'table full' msg
  2633.         push_all
  2634.         mov   bl,cs:colour
  2635.         mov   si,offset cs:table_full_msg
  2636.         call  disp_str_colour
  2637.         pop_all
  2638.         ret
  2639. table_full    endp
  2640. ;
  2641. ab_colour proc
  2642.         call  crlf
  2643.         push_all
  2644.  
  2645.         mov   bl,cs:colour
  2646.         mov   byte ptr cs:old_col,bl  ; save current colour in case of ESC
  2647.  
  2648. colour_top:
  2649.  
  2650.         mov   bl,cs:colour            ; get current colour
  2651.         mov   si,offset cs:colour_msg
  2652.         call  disp_str_colour
  2653.  
  2654. get_colour_key:
  2655.  
  2656.         mov   ah,8                    ; get key. no echo
  2657.         int   21h
  2658.         cmp   al,0                    ; 2-byte code?
  2659.         je    get_colour_key          ; loop again if yes
  2660.         ;
  2661.         cmp   al,32                   ; space character?
  2662.         jne   colour1
  2663.         cmp   byte ptr cs:colour,15   ; if colour = 15, reset to 1
  2664.         jne   colour2
  2665.         mov   byte ptr cs:colour,1
  2666.         jmp   colour_top
  2667.  
  2668. colour2:
  2669.  
  2670.         inc   byte ptr cs:colour
  2671.         jmp   colour_top
  2672.  
  2673. colour1:                              ; not a space. try for cr
  2674.  
  2675.         cmp   al,13
  2676.         je    colour3                 ; jmp if cr.
  2677.         cmp   al,27                   ; ESC?
  2678.         jne   get_colour_key          ; get char again if not.
  2679.        
  2680.         mov   bl,cs:old_col           ; ESC, so get old colour
  2681.         mov   byte ptr cs:colour,bl   ; and make it the current colour
  2682.  
  2683. colour3:
  2684.  
  2685.         pop_all 
  2686.         disp_ch CR                    ; all done. move crsr to start of line
  2687.         push_all
  2688.         mov   al,32                   ; display a line of spaces over line
  2689.         mov   bl,WHITE
  2690.         mov   bh,0
  2691.         mov   cx,75
  2692.         mov   ah,9
  2693.         bios_video
  2694.         pop_all 
  2695.         disp_ch CR                    ; put crsr at start of line again
  2696.         ret
  2697. ab_colour     endp
  2698. ;
  2699. ab_show proc
  2700.         mov   byte ptr cs:echo_status,1
  2701.         call  crlf
  2702.         ret
  2703. ab_show endp
  2704. ;
  2705. ab_hide proc
  2706.         mov   byte ptr cs:echo_status,0
  2707.         call  crlf
  2708.         ret
  2709. ab_hide endp
  2710. ;
  2711. ab_delete     proc                    ; ALIAS D <arg> deletes an entry
  2712.         push_m <ax,bx,cx,dx,es,ds,si,di,bp>
  2713.         mov   bp,dx
  2714.         mov   ah,byte ptr ds:[bp+1]   ; get length of string
  2715.  
  2716.         cmp   ah,7                    ; if just ALIAS D typed...
  2717.         je    not_there               ; ...then do nothing
  2718.  
  2719.                                       ; Before doing anything else,check that
  2720.                                       ; user left a space between ALIAS D and
  2721.                                       ; the arg, or prog will hang.  ie, 
  2722.                                       ; abort if [dx+9] is not a space.
  2723.  
  2724.         push_m <ax,bp>
  2725.         mov   bp,dx
  2726.         mov   ah,byte ptr ds:[bp+9]   ; get the char between ALIAS D and arg
  2727.         cmp   ah,' '                  ; is it a space
  2728.         pop_m <bp,ax>
  2729.         je    ok_space2               ; continue if ok. Can't write jne 'cos
  2730.                                       ; out of range.
  2731.         jmp   not_there               ; if not a space, abort D command
  2732.  
  2733. ok_space2:
  2734.  
  2735.         sub   ah,8                    ; arg is at dx+10 with len arg_end
  2736.         mov   cs:arg_end,ah                                       
  2737.                                       ; fill buffer with 0's
  2738.         mov   ax,cs
  2739.         mov   es,ax
  2740.         mov   al,0
  2741.         mov   di,offset cs:buffer2
  2742.         mov   cx,LHS_LEN
  2743.         cld
  2744.         rep   stosb
  2745.   
  2746.         call  copy_to_buffer2         ; copy arg into buffer
  2747.  
  2748.                                       ; now look through table. If arg
  2749.                                       ; exists, delete it.
  2750.  
  2751.         mov   bh,1                    ; do up to 30 comparisons
  2752.         mov   di,offset cs:ab_table
  2753.            
  2754. not_there_yet:
  2755.  
  2756.         mov   ax,cs
  2757.         mov   es,ax
  2758.         mov   ds,ax
  2759.         mov   si,offset cs:buffer2
  2760.         mov   cx,LHS_LEN
  2761.         cld
  2762.         repe  cmpsb
  2763.         jne   still_not_there
  2764.         jmp   got_it
  2765.  
  2766. still_not_there:
  2767.  
  2768.         inc   bh
  2769.         cmp   bh,TBL_LEN + 1
  2770.         je    not_there
  2771.         add   di,RHS_LEN + 1
  2772.         add   di,cx
  2773.         jmp   not_there_yet
  2774.  
  2775. got_it:                               ; di holds start of table
  2776.                                       ; entry so delete it
  2777.         sub   di,LHS_LEN
  2778.         mov   byte ptr es:[di],0      ; set 1st char to 0, = deleted
  2779.         pop_m <bp,di,si,ds,es,dx,cx,bx,ax>
  2780.         call  crlf
  2781.         ret
  2782.  
  2783. not_there:
  2784.  
  2785.         pop_m <bp,di,si,ds,es,dx,cx,bx,ax>
  2786.         call  not_found               ; show error cos entry doesn't exist
  2787.         ret
  2788. ; 
  2789. ab_delete     endp
  2790. ; 
  2791. ab_flush      proc                    ; ALIAS F wipes entire table.
  2792.         call  are_you_sure            ; ask user to confirm
  2793.         cmp   byte ptr cs:confirm,1   ; is user sure?
  2794.         jne   flush_done              ; jump if no
  2795.         push_m <di,es,cx,ax>
  2796.         mov   ax,cs
  2797.         mov   es,ax
  2798.         mov   di,offset cs:ab_table
  2799.         mov   al,0
  2800.         mov   cx,(RHS_LEN + LHS_LEN + 1) * TBL_LEN
  2801.         rep   stosb                   ; Fill entire table with 0's.  Don't
  2802.         pop_m <ax,cx,es,di>           ; erase the bytes before the actual
  2803.                                       ; data, as these hold other bits of
  2804.                                       ; info that get saved with the table.
  2805. flush_done:
  2806.         ret
  2807. ab_flush      endp
  2808. ; 
  2809. ab_list proc                          ; ALIAS L lists the whole table.
  2810.                                       ; ALIAS L <arg> lists specified entry
  2811.                                       ; Note: the search routines used here
  2812.                                       ; are direct copies of the ones from
  2813.                                       ; the D command.  Should really be put
  2814.                                       ; into a proc to save space.
  2815.  
  2816. call get_lines                        ; Set byte at cs:page_len to no. of
  2817.                                       ; lines that screen can display.
  2818.  
  2819.         push_m <bp,ax>
  2820.         mov   bp,dx
  2821.         mov   ah,byte ptr ds:[bp+1]   ; get length of string into ah
  2822.         cmp   ah,7                    ; just ALIAS L typed?
  2823.         pop_m  <ax,bp>
  2824.         jne   list_single             ; if not, list a single entry
  2825.         jmp list_all                  ; If just ALIAS L, goto list_all
  2826.  
  2827. list_single:
  2828.                                       ; search table for specified entry..
  2829.                                       ; and list it if it exists.
  2830.  
  2831.                                       ; Before doing anything else,check that
  2832.                                       ; user left a space between ALIAS L and
  2833.                                       ; the arg, or prog will hang.  ie, 
  2834.                                       ; abort if [dx+9] is not a space.
  2835.  
  2836.         push_m <ax,bp>
  2837.         mov   bp,dx
  2838.         mov   ah,byte ptr ds:[bp+9]   ; get the char between ALIAS L and arg
  2839.         cmp   ah,' '                  ; is it a space
  2840.         pop_m <bp,ax>
  2841.         je    ok_space                ; continue if ok. Can't write jne 'cos
  2842.                                       ; out of range.
  2843.         call  syntax_error
  2844.         jmp   list4                   ; if not a space, abort L command
  2845.  
  2846. ok_space:
  2847.  
  2848.         push_m <ax,bx,cx,dx,es,ds,si,di,bp>
  2849.         mov   bp,dx
  2850.         mov   ah,byte ptr ds:[bp+1]   ; get length of string into ah
  2851.         sub   ah,8
  2852.         mov   cs:arg_end,ah           ; the arg specified in cmd line is 
  2853.                                       ; at dx+10, with length arg_end
  2854.  
  2855.                                       ; fill buffer with 0's
  2856.         mov   ax,cs
  2857.         mov   es,ax
  2858.         mov   al,0
  2859.         mov   di,offset cs:buffer2
  2860.         mov   cx,LHS_LEN
  2861.         cld
  2862.         rep   stosb
  2863.  
  2864.         call  copy_to_buffer2         ; copy string to buffer
  2865.  
  2866.                                       ; now look through table. If arg
  2867.                                       ; exists, list it.
  2868.  
  2869.         mov   bh,1                    ; do up to 30 comparisons
  2870.         mov   di,offset cs:ab_table 
  2871.            
  2872. list_not_there_yet:
  2873.  
  2874.         mov   ax,cs
  2875.         mov   es,ax
  2876.         mov   ds,ax
  2877.         mov   si,offset cs:buffer2
  2878.         mov   cx,LHS_LEN
  2879.         cld
  2880.         repe  cmpsb
  2881.         jne   list_still_not_there
  2882.         jmp   list_got_it
  2883.  
  2884. list_still_not_there:
  2885.  
  2886.         inc   bh
  2887.         cmp   bh,TBL_LEN + 1
  2888.         je    list_not_there
  2889.         add   di,RHS_LEN + 1
  2890.         add   di,cx
  2891.         jmp   list_not_there_yet
  2892.  
  2893. list_got_it:                          ; di holds start of table entry.
  2894.  
  2895.         sub   di,LHS_LEN              ; move to start of entry
  2896.         call  crlf                    ; move crsr below DOS prompt line
  2897.         call  crlf                    ; and go down a line
  2898.         call  list_an_entry           ; list it in current colour
  2899.         pop_m <bp,di,si,ds,es,dx,cx,bx,ax>
  2900.         jmp   list4
  2901.  
  2902. list_not_there:
  2903.  
  2904.         pop_m <bp,di,si,ds,es,dx,cx,bx,ax>
  2905.         call  not_found               ; display error message
  2906.         jmp   list4                   ; end of selective list routine
  2907.  
  2908. list_all:                             ; list whole table
  2909.  
  2910.         mov   byte ptr cs:list_count,0 ; line counter
  2911.         push_m <di,ds,dx,cx,bx,ax>
  2912.         call  crlf
  2913.         call  crlf
  2914.         mov   bh,1                    ; count 30 loops through table
  2915.         mov   di,offset cs:ab_table   ; point to start of table
  2916.  
  2917. list1:
  2918.  
  2919.         mov   ah,cs:[di]              ; get 1st char of arg
  2920.         cmp   ah,0                    ; is entry empty?
  2921.         jne   not_empty
  2922.         jmp   list2                   ; jump if so
  2923.  
  2924. not_empty:
  2925.  
  2926.         inc    byte ptr cs:list_count
  2927.         push   ax
  2928.         mov    ah,byte ptr cs:page_len
  2929.         cmp    byte ptr cs:list_count,ah
  2930.         pop    ax
  2931.         jne    page_not_full
  2932.         call   list_pause             ; Press Any Key to Continue
  2933.  
  2934. page_not_full:
  2935.  
  2936.         call   list_an_entry          ; list current entry in current colour
  2937. list2:                                ; ..unless current table entry is empty
  2938.         inc   bh                      ; counter for no of entries
  2939.         cmp   bh,TBL_LEN + 1          ; have we seen all the table
  2940.         je    list3                   ; all done if yes
  2941.         add   di,LHS_LEN + RHS_LEN + 1 ; else point to next entry
  2942.         jmp   list1                   ; and do it all again
  2943.  
  2944. list3:     
  2945.  
  2946.         pop_m <ax,bx,cx,dx,ds,di>
  2947. list4:
  2948.  
  2949.                                       ; Write a white space, for BIOS func 0Eh
  2950.                                       ; to use as reference for new attrib.
  2951.         call    crlf
  2952.         push_m  <cx,bx,ax,di,si>
  2953.         mov     ah,9
  2954.         mov     al,SPACE
  2955.         mov     bl,WHITE               ; attrib
  2956.         call    get_vpage              ; video page into bh
  2957.         mov     cx,1
  2958.         bios_video
  2959.         pop_m   <si,di,ax,bx,cx>
  2960.  
  2961.         ret
  2962. ab_list endp
  2963. ;
  2964. not_found proc                        ; Display error message if the subject
  2965.                                       ; of an ALIAS L <arg> is not found.
  2966.         push_all
  2967.         mov    bl,byte ptr cs:colour
  2968.         mov    si,offset cs:err_nfound
  2969.         call   disp_str_colour
  2970.         pop_all
  2971.         ret
  2972. not_found endp
  2973. ;
  2974. exist_err proc                        ; Display error message if the subject
  2975.                                     ; of an ALIAS A already exists.
  2976.         push_all
  2977.         mov    bl,byte ptr cs:colour
  2978.         mov    si,offset cs:exist_msg
  2979.         call   disp_str_colour
  2980.         pop_all
  2981.         ret
  2982. exist_err endp
  2983. ;
  2984. get_lines proc
  2985.  
  2986.         push  ax                      ; Set page_len to no. of lines on scrn,
  2987.         push  ds                      ; so listings can pause when necessary.
  2988.         mov   ax,40h
  2989.         mov   ds,ax
  2990.         mov   ah,byte ptr ds:[84h]    ; get DOS's screen length (in lines)
  2991.         pop   ds
  2992.         cmp   ah,0
  2993.         je    not_really_0
  2994.         jmp   short length_set
  2995.  
  2996. not_really_0:
  2997.  
  2998.         mov   byte ptr cs:page_len,25  ; If byte is 0, length is 25.  That's
  2999.         jmp   short length_set_2       ; the rule, according to DOS books.
  3000.  
  3001. length_set:
  3002.  
  3003.         mov   byte ptr cs:page_len,ah
  3004.  
  3005. length_set_2:
  3006.  
  3007.         pop   ax                      ; page_length is now set.
  3008.         ret
  3009. get_lines endp
  3010. ;
  3011. list_pause    proc
  3012.                                       ; Display a Press Any Key to Cont msg
  3013.         push_all
  3014.         mov   byte ptr cs:list_count,0 ; clear the line counter
  3015.         mov   bl,byte ptr cs:colour 
  3016.         mov   si,offset cs:press_msg
  3017.         call  disp_str_colour         ; display message in current colour
  3018.  
  3019. pause1:
  3020.  
  3021.         mov   ah,8                    ; get key (without echo) into al.
  3022.         int   21h
  3023.         cmp   al,0                    ; if it's a 2-byte code,
  3024.         je    pause1                  ; then go round again.
  3025.  
  3026.                                       ; Cover the message with some spaces
  3027.  
  3028.         disp_ch  CR
  3029.         push_all
  3030.         mov      al,SPACE
  3031.         mov      ah,09
  3032.         mov      bl,WHITE
  3033.         mov      cx,35
  3034.         BIOS_VIDEO
  3035.         pop_all
  3036.  
  3037.         disp_ch CR
  3038.  
  3039.         push_m  <di,si,cx,bx,ax>       ; avoid colour inheritance bug
  3040.         mov     ah,9
  3041.         mov     al,SPACE
  3042.         mov     bl,WHITE               ; attrib
  3043.         call    get_vpage              ; video page into bh
  3044.         mov     cx,1
  3045.         bios_video
  3046.         pop_m   <ax,bx,cx,si,di>
  3047.  
  3048.         pop_all
  3049.         ret
  3050. list_pause    endp
  3051. ;
  3052. copy_to_buffer2   proc
  3053.                                      ; copy arg into buffer. used by L and D
  3054.         mov   ax,cs
  3055.         mov   si,dx
  3056.         add   si,10
  3057.         mov   es,ax
  3058.         mov   di,offset cs:buffer2
  3059.         mov   cl,cs:arg_end
  3060.         mov   ch,0
  3061.  
  3062. cx_not_zero:
  3063.  
  3064.         cld
  3065.         movsb                        ; copy ds:si to es:di
  3066.                                      ; don't use rep prefix cos we need
  3067.                                      ; to force chars to lower case when
  3068.                                      ; copied.
  3069.  
  3070.         push  ax
  3071.         dec   di                     ; put it where it was before the movsb
  3072.         mov   al,byte ptr es:[di]    ; get the byte just copied
  3073.         or    al,00100000b           ; make character lower case
  3074.         mov   byte ptr es:[di],al    ; and put it back
  3075.         inc   di                     ; and put di back too
  3076.         pop   ax
  3077.  
  3078.         dec   cx                     ; dec counter
  3079.         cmp   cx,0
  3080.         jne   cx_not_zero
  3081.         ret
  3082. copy_to_buffer2   endp
  3083. ; 
  3084. ab_order proc                        ; Sort the abbreviation table (in RAM)
  3085.                                      ; so that LHS entries are in ascending
  3086.                                      ; alphabetical order.
  3087.                                      ; Method used is a bubble sort.
  3088.                                      ; This proc is not called explicitly by
  3089.                                      ; the user.  It is called automatically
  3090.                                      ; before a LIST or WRITE, and after a
  3091.                                      ; DELETE or ADD command is processed.
  3092.         push_all
  3093.  
  3094. sort1:
  3095.  
  3096.         mov   byte ptr cs:sort_counter,0                  ; count no. of swaps
  3097.         mov   word ptr cs:sort_pointer,offset cs:ab_table ; pointer into data
  3098.         mov   byte ptr cs:sort_entries,TBL_LEN            ; no of entries
  3099.  
  3100. sort2:
  3101.  
  3102.         cmp   byte ptr cs:sort_entries,1 ; are we pointing at the last entry?
  3103.         ja    sort3                      ; no
  3104.         cmp   byte ptr cs:sort_counter,0 ; We've finished a pass through the
  3105.                                          ; data.  If there were no swaps, we
  3106.                                          ; are sorted.
  3107.         je    sorted
  3108.         jmp   sort1
  3109.  
  3110. sort3:
  3111.  
  3112.         call  sort_compare               ; compare string at pointer with the
  3113.                                          ; following one and set swap_flag = 1
  3114.                                          ; if swap needed, else 0
  3115.  
  3116.         cmp   byte ptr cs:swap_flag,1    ; swap needed?
  3117.         jne   sort4                      ; no
  3118.         call  sort_swap                  ; swap
  3119.         inc   byte ptr cs:sort_counter   ; count swaps needed during the pass
  3120.  
  3121. sort4:
  3122.  
  3123.         add   word ptr cs:sort_pointer,LHS_LEN + RHS_LEN +1 ;point to next str
  3124.         dec   byte ptr cs:sort_entries   ; see how far we've got to go
  3125.         jmp   sort2
  3126.  
  3127. sorted:
  3128.  
  3129.         pop_all
  3130.         ret
  3131. ab_order endp
  3132. ;
  3133. sort_compare proc                       ; compare alphabetically the string
  3134.                                         ; at sort_pointer with the string at
  3135.                                         ; (sort_pointer + lhs_len + rhs_len +1)
  3136.                                         ; If they are in the wrong order, set
  3137.                                         ; swap_flag to 1, else set it to 0.
  3138.                                         ; The strings' length is each lhs_len
  3139.                                         ; characters, as we are only looking at
  3140.                                         ; the left hand sides of table entries.
  3141.  
  3142.         push_all
  3143.         mov   byte ptr cs:swap_flag,0   ; clear flag
  3144.         mov   bp,1                      ; count length of strings
  3145.         mov   si,cs:sort_pointer        ; pointer to 1st string
  3146.         mov   di,si                     ; pointer to second string
  3147.         add   di,lhs_len+ rhs_len + 1
  3148.  
  3149. comp1:
  3150.  
  3151.         mov   ah,byte ptr cs:[si]       ; get byte from 1st string
  3152.         mov   al,byte ptr cs:[di]       ; and a byte from the second
  3153.         cmp   ah,al                     ; compare them
  3154.         jb    compared                  ; they're in the right order
  3155.         je    comp2                     ; or they are the same
  3156.  
  3157.         mov   byte ptr cs:swap_flag,1   ; else set the flag to say 'swap'
  3158.         jmp   compared                  ; and our job is done
  3159.  
  3160. comp2:
  3161.  
  3162.         inc   si                        ; bump up pointers
  3163.         inc   di
  3164.         inc   bp                        ; and change "how many left to compare"
  3165.         cmp   bp,lhs_len + 1            ; whole lhs compared?
  3166.         jne   comp1                     ; no, so compare another
  3167.  
  3168. compared:
  3169.  
  3170.         pop_all                         ; all compared.
  3171.         ret
  3172. sort_compare endp
  3173. ;
  3174. sort_swap proc     ; swap the string at sort_pointer with the one at
  3175.                    ; (sort_pointer + lhs_len + rhs_len + 1).  The string
  3176.                    ; has length (lhs_len + rhs_len + 1).  This routine
  3177.                    ; swaps each byte in turn which, although slower than
  3178.                    ; a rep movsb instruction, avoids having to have a
  3179.                    ; large buffer to use while the swap takes place.
  3180.  
  3181.  
  3182.         push_all
  3183.         mov   bp,LHS_LEN + RHS_LEN + 1  ; length of strings
  3184.         mov   si,cs:sort_pointer        ; pointer to 1st string
  3185.         mov   di,si                     ; pointer to second string
  3186.         add   di,bp
  3187.  
  3188. swap1:
  3189.  
  3190.         mov   ah,byte ptr cs:[si]       ; get byte from 1st string
  3191.         mov   al,byte ptr cs:[di]       ; and a byte from the second
  3192.         mov   byte ptr cs:[si],al       ; and write them back...
  3193.         mov   byte ptr cs:[di],ah       ; in reverse order
  3194.         inc   si                        ; bump up pointers
  3195.         inc   di
  3196.         dec   bp                        ; and update counter
  3197.         cmp   bp,0                      ; all swapped?
  3198.         jne   swap1                     ; no, so swap another
  3199.         pop_all                         ; all swapped, so we're done
  3200.         ret
  3201. sort_swap endp
  3202. ;
  3203. to_lower       proc
  3204.  
  3205.                                         ; Force the LHS part of an alias
  3206.                                         ; in an ALIAS A command to lower case.
  3207.  
  3208.         push_m <si,ax>
  3209.         mov    si,dx                    ; pointer into string
  3210.         add    si,10                    ; point to start of LHS in ALIAS A
  3211.                                         ; command string.
  3212.  
  3213. lower1:
  3214.  
  3215.         mov    ah,byte ptr ds:[si]      ; get char from string
  3216.         cmp    ah,CR                    ; are we done?
  3217.         je     lower2
  3218.         cmp    ah,SPACE
  3219.         je     lower2                   ; stop on space. CR is just for safety
  3220.         cmp    ah,41h
  3221.         jb     dont_lower               ; don't convert if character < 'A'
  3222.         cmp    ah,5ah                   ; or > 'Z'
  3223.         ja     dont_lower
  3224.         or     ah, 00100000b            ; else make character lower case
  3225.         mov    byte ptr ds:[si],ah      ; and put it back
  3226.  
  3227. dont_lower:
  3228.  
  3229.         inc    si                       ; point to next char in string
  3230.         jmp    short lower1
  3231.  
  3232. lower2:
  3233.  
  3234.         pop_m  <ax,si>
  3235.         ret
  3236. to_lower       endp
  3237. ;
  3238. list_an_entry  proc                   ; used by ab_list proc. Lists the
  3239.                                       ; table entry which starts at [di].
  3240.  
  3241.                                       ; Display LHS string in current
  3242.                                       ; colour.  Terminates on ascii 0.
  3243.                                       ; However, if the LHS string is of
  3244.                                       ; the maximum permitted length,
  3245.                                       ; there won't be a zero and we run
  3246.                                       ; into the RHS str. So save 1st byte
  3247.                                       ; of RHS string in cs:list_temp 
  3248.                                       ; and put a zero there instead.
  3249.                                       ; Replace saved byte when done.
  3250.                                       ; Do this whatever the length of
  3251.                                       ; the LHS string, as it's not worth
  3252.                                       ; checking! The RHS string always ends
  3253.                                       ; with a 0, so there's no need to
  3254.                                       ; worry about that one.
  3255.  
  3256.         push  bp
  3257.         push  ax
  3258.         mov   bp,di                   ; start of LHS string in cs
  3259.         add   bp,LHS_LEN              ; point to 1st char of RHS string
  3260.         mov   al,byte ptr cs:[bp]     ; get character to save
  3261.         mov   byte ptr cs:list_temp,al; save it
  3262.         mov   byte ptr cs:[bp],0      ; put zero at end of LHS string
  3263.         mov   word ptr cs:list_temp2,bp ; save the address that was altered
  3264.         pop   ax
  3265.         pop   bp
  3266.  
  3267.         push_all
  3268.         mov   si,di                   ; start of string
  3269.         mov   bl,cs:colour            ; set colour
  3270.         call  disp_str_colour         ; display the string
  3271.         pop_all
  3272.  
  3273.         push_m <ax,bp>
  3274.         mov   al,byte ptr cs:list_temp; get original byte
  3275.         mov   bp,word ptr cs:list_temp2 ; get its address
  3276.         mov   byte ptr cs:[bp],al     ; and put the byte back
  3277.         pop_m <bp,ax>
  3278.                                       ; Now put cursor 2 places after LHS so
  3279.                                       ; the RHS strings line up neatly.
  3280.  
  3281.         push_all
  3282.         mov   ah,3                    ; read crsr position
  3283.         call  get_vpage               ; get page into bh
  3284.         bios_video                    ; get crsr row into dh, to preserve
  3285.  
  3286.         mov   ah,2                    ; set crsr position
  3287.         call   get_vpage              ; video page --> bh
  3288.         mov   dl,(LHS_LEN + 2)        ; set column. Leave row as is.
  3289.         bios_video                    ; do it
  3290.         pop_all
  3291.  
  3292.  
  3293.         push_all                      ; display string until 0 byte. 
  3294.         mov   bl,cs:colour            ; current colour
  3295.  
  3296.         add   di,LHS_LEN              ; skip arg
  3297.         mov   si,di                   ; address of string
  3298.         call  disp_str_colour         ; call proc
  3299.         pop_all
  3300.         call  crlf                    ; start a new line
  3301.         ret
  3302. list_an_entry  endp
  3303. ;
  3304. ab_write      proc                    ; ALIAS W <pathname>  saves table
  3305.         call  are_you_sure            ; is user sure?
  3306.         cmp   byte ptr cs:confirm,1   ; did user say yes?
  3307.         jne   write_not_sure          ; abandon if not
  3308.  
  3309.         push_m <ax,bx,cx,dx,bp,si,ds>
  3310.         push ds
  3311.         mov   bp,dx
  3312.         mov   al, byte ptr ds:[bp+1]  ; get length of string
  3313.         cmp   al,7                    ; just ALIAS W typed?
  3314.         jne   write1
  3315.         mov   dx,offset cs:default_fn ; use default file if so.
  3316.  
  3317.         push  ax
  3318.         mov   al,byte ptr cs:[def_dir] ; if this string is full of zeroes,
  3319.                                        ; the default file was not loaded
  3320.         cmp   al,0
  3321.         pop   ax
  3322.         je    not_loaded               ; so use the file name we just set up.
  3323.         mov   dx,offset cs:defdir_hdr  ; If default file WAS loaded at install
  3324.                                        ; time, recover its path.
  3325.  
  3326. not_loaded:
  3327.  
  3328.         push  cs
  3329.         pop   ds
  3330.         jmp   short write2
  3331.  
  3332. write1:
  3333.  
  3334.         mov   ah,0
  3335.         mov   si,ax
  3336.         add   si,2                    ; point to CR terminator
  3337.         add   si,bp
  3338.         mov   byte ptr ds:[si],0      ; change CR to 0 to make asciiz
  3339.         ; 
  3340.         add   dx,10                   ; point to start of filename
  3341.  
  3342. write2:
  3343.  
  3344.         mov   cl,0                    ; no attributes
  3345.         mov   ah,3ch                  ; create file
  3346.         int   21h                     ; do it. Handle -->ax
  3347.         ; 
  3348.         jnc   ab_save_ok              ; continue if no error 
  3349.         call  disk_error_msg
  3350.         jmp   short ab_save_quit      ; else display error msg
  3351.  
  3352. ab_save_ok:
  3353.  
  3354.         mov   bx,ax                   ; write to file. Handle in bx
  3355.         mov   cx,((RHS_LEN + LHS_LEN + 1) * TBL_LEN) + 5 ; table plus signat
  3356.         mov   ax,cs  
  3357.         mov   ds,ax
  3358.         mov   dx,offset cs:table_top  ; point to data area to be saved
  3359.         mov   ah,40h
  3360.         int   21h
  3361.         ; 
  3362.         mov   ah,3eh                  ; close file whose handle is in bx
  3363.         int   21h
  3364.  
  3365. ab_save_quit:
  3366.  
  3367.         pop   ds
  3368.         ; 
  3369.         pop_m <ds,si,bp,dx,cx,bx,ax>
  3370.  
  3371. write_not_sure:
  3372.  
  3373.         ret
  3374. ab_write      endp
  3375. ;
  3376. ab_read       proc                    ; ALIAS R <pathname>  loads a table
  3377.         call  are_you_sure            ; Ask user to confirm
  3378.         cmp   byte ptr cs:confirm,1   ; is user sure?
  3379.         jne   read_not_sure           ; abandon if not
  3380.  
  3381.         push_m <ax,bx,cx,dx,bp,si,ds>
  3382.         push  ds
  3383.         ; 
  3384.         mov   bp,dx
  3385.         mov   al,byte ptr ds:[bp+1]   ; get length of string
  3386.         cmp   al,7                    ; just ALIAS R typed?
  3387.         jne   read1
  3388.         mov   dx,offset cs:default_fn ; assume default filename if so.
  3389.                                       ; However, if a pathed version of the
  3390.                                       ; default file exists, use it instead.
  3391.  
  3392.         push  ax
  3393.         mov   al,byte ptr cs:[def_dir] ; if this string is full of zeroes,
  3394.                                        ; the default file was not loaded
  3395.         cmp   al,0
  3396.         pop   ax
  3397.         je    not_loaded2              ; so use the file name we just set up.
  3398.         mov   dx,offset cs:defdir_hdr  ; If default file WAS loaded at install
  3399.                                        ; time, recover its path.
  3400. not_loaded2:
  3401.  
  3402.         push  cs
  3403.         pop   ds
  3404.         jmp   short read2
  3405.  
  3406. read1:
  3407.  
  3408.         mov   ah,0
  3409.         mov   si,ax
  3410.         add   si,2
  3411.         add   si,bp
  3412.         mov   byte ptr ds:[si],0      ; replace CR with 0
  3413.         ; 
  3414.         add   dx,10                    ; point to start of filename
  3415.  
  3416. read2:
  3417.         mov   ah,3dh
  3418.         mov   al,0                    ; read mode only
  3419.         int   21h                     ; open file for reading
  3420.         ; 
  3421.         jnc   ab_load_ok              ; continue if no error
  3422.         call  disk_error_msg
  3423.         jmp   short ab_l_quit
  3424.  
  3425. ab_load_ok:
  3426.  
  3427.         mov   bx,ax                   ; put handle in correct place
  3428.         mov   cx,((RHS_LEN + LHS_LEN + 1) * TBL_LEN) + 5 ; table plus signat
  3429.         mov   ax,cs
  3430.         mov   ds,ax
  3431.         mov   dx,offset cs:table_top  ; point to destination of loaded bytes
  3432.         mov   ah,3fh                  ; read file
  3433.         int   21h
  3434.         ; 
  3435.         mov   ah,3eh
  3436.         int   21h                     ; close file
  3437.  
  3438. ab_l_quit:
  3439.  
  3440.         pop   ds
  3441.         ; 
  3442.         pop_m <ds,si,bp,dx,cx,bx,ax>
  3443.         call  crlf
  3444. read_not_sure:                        ; come here if user says "No"
  3445.         ret
  3446. ab_read       endp
  3447. ; 
  3448. get_string_from_kbd proc              ; The DOSEDIT get-string routine
  3449.  
  3450.         call  update_csize            ;make cursor echo insert mode
  3451.         cli                           ;turn interrupts off
  3452.         mov   word ptr cs:oldsp,sp    ;save the old stack pointer
  3453.         mov   word ptr cs:oldsp+2,ss
  3454.         mov   ss,cs:codeseg           ;make a local stack
  3455.         mov   sp,offset stcktop       ;set stack pointer to top of stack
  3456.         sti                           ;turn interrupts back on
  3457.         push  ax                      ;save registers
  3458.         call  bufkey                  ;do buffer keyboard input
  3459.         pop   ax                      ;restore registers
  3460. ;
  3461.         cli                           ;turn interrupts off
  3462.         mov   ss,word ptr cs:oldsp+2  ;restore the old stack
  3463.         mov   sp,word ptr cs:oldsp
  3464.         sti                           ;turn interrupts back on
  3465.         call  small_cursor            ; restore cursor size.
  3466.         ret
  3467. ;
  3468. get_string_from_kbd endp
  3469.  
  3470.                                       ;function to emulate the dos buffered
  3471.                                       ;keyboard input routine int 21 ah=0Ah.
  3472.  
  3473.                                       ;Call to get buffered input from the
  3474.                                       ;keyboard using the tiny editor.
  3475.                                       ;Entry:
  3476.                                       ;ds:dx -> input buffer for the string
  3477.                                       ;ds:dx+0 = number of chars in buffer
  3478.                                       ;Exit:
  3479.                                       ;ds:dx+1 = number of chars entered.
  3480.                                       ;ds:dx+2 -> string terminated by CR.
  3481. bufkey:
  3482.  
  3483.         push_all
  3484. ;
  3485.         mov   ax,ds                   ;es:di -> string storage
  3486.         mov   es,ax
  3487.         mov   di,dx
  3488. ;
  3489.         mov   cl,[di]                 ;cl = max number of char to accept
  3490.         mov   ch,0                    ;cx = max number of char to accept
  3491.         dec   cx                      ;sub 1 to make space for the cr
  3492.         call  tinyedt                 ;get the string
  3493. ;
  3494.         mov   al,CR                   ;echo the return
  3495.         call  putc
  3496. ;
  3497.         call  strlen                  ;compute the string length     
  3498.         inc   di                      ;es:di -> string length storage
  3499.         mov   es:[di],cl              ;save the string length
  3500.         inc   di                      ;es:di -> storage for the string
  3501. ;
  3502.         call  cpystr                  ;copy the string into buffer
  3503.         mov   byte ptr es:[di],cr     ;terminate the string with cr
  3504. ;
  3505.         pop_all
  3506.         ret
  3507.  
  3508.                                       ;call to move output string
  3509.                                       ;Entry:
  3510.                                       ;cs:si -> input string terminated by 0
  3511.                                       ;es:di -> destination for string
  3512.                                       ;Exit:
  3513.                                       ;cs:si -> 0 in source string
  3514.                                       ;es:di -> 0 in destination string
  3515.                                       ;ax = undefined
  3516. cpystr:
  3517.  
  3518.         mov   al,cs:[si]              ;get char from source string
  3519.         mov   es:[di],al              ;write the destination string
  3520.         cmp   al,0                    ;is this the termiation char?
  3521.         jz    cpystr1                 ;yes, string moved
  3522.         inc   si                      ;inc the from pointer
  3523.         inc   di                      ;inc the two pointer
  3524.         jmp   cpystr                  ;loop till done
  3525.  
  3526. cpystr1:
  3527.  
  3528.         ret
  3529. ;
  3530.                                       ;Little line editor
  3531.                                       ;Call to get a single line of text from
  3532.                                       ;the keyboard with editing.
  3533.                                       ;Entry:
  3534.                                       ;cx = max chars to accept, excl null.
  3535.                                       ;Exit:
  3536.                                       ;cs:si -> string terminated with 0
  3537.  
  3538.  
  3539. tinyedt:
  3540.  
  3541.         push   ax                      ;save registers
  3542.         push   bx
  3543.         push   cx
  3544.         push   dx
  3545.         push   bp
  3546.         push   di
  3547.         push   ds
  3548.         push   es
  3549.  
  3550.         mov    ax,cs                   ;data segment = code segment
  3551.         mov    ds,ax
  3552.         mov    maxchar,cx              ;save the max number of characters
  3553.         call   initlin                 ;begin editing a new line
  3554.  
  3555.         call   dcinitlin               ; Do special init functions for DOS
  3556.                                        ; compatibility.
  3557.  
  3558. tinyed1:
  3559.  
  3560.         call   getc                    ;get a character
  3561.         cmp    ax,prf_trigger          ; is char the prf key?
  3562.         je     tiny22
  3563.         mov    byte ptr cs:prf_multi,0 ; clear flag used to detect multiple
  3564.                                        ; presses of the prf key.
  3565. tiny22:
  3566.  
  3567.         cmp    ax,it_key
  3568.         je     tiny2
  3569.         mov    byte ptr cs:it_multi,0
  3570.  
  3571. tiny2:
  3572.  
  3573.         cmp    ax,F6Key               ; Translate F6 to Ctrl-Z
  3574.         jne    tiny9
  3575.         mov    ax,01Ah
  3576.  
  3577. tiny9:
  3578.  
  3579.         cmp    ax,CR                   ;is the key a return?
  3580.         je     tinyed2                 ;yes, done editing the line
  3581.         mov    bx,offset cmndtbl       ;bx -> table of keys and commands
  3582.         call   gotocmd                 ;lookup the command and execute
  3583.         call   update                  ;update the display
  3584.         jmp    tinyed1
  3585.  
  3586. tinyed2:
  3587.  
  3588.         call   begline                 ;move the cursor to the beginning
  3589.         call   update                  ;redraw the display
  3590.         call   endline                 ;remove the bubble in text
  3591.         mov    si,cursorb              ;si -> beginning of the cursor
  3592.         mov    byte ptr [si],0         ;terminate the string
  3593.         mov    si,offset bublbeg       ;cs:si -> beginning of the string
  3594.         call   strlen                  ;compute the string length
  3595.         cmp    cx,shrtstr              ;is the string too short to save?
  3596.         jbe    tinyed3                 ;yes, don't save it
  3597.         call   cmdput                  ;no, long enough, record the line
  3598.  
  3599. tinyed3:
  3600.  
  3601.         pop    es
  3602.         pop    ds
  3603.         pop    di
  3604.         pop    bp
  3605.         pop    dx
  3606.         pop    cx
  3607.         pop    bx
  3608.         pop    ax
  3609.         ret
  3610.  
  3611.  
  3612.                                       ;This routine branches to a command
  3613.                                       ;based on table lookup.
  3614.                                       ;Entry:
  3615.                                       ;ax = command number to lookup in table
  3616.                                       ;bx -> beginning of lookup table
  3617.                                       ;Exit:
  3618.                                       ;ax = command number
  3619.                                       ;pc = command subroutine address
  3620.                                       ;Table Format:     
  3621.                                       ;match word,branch word
  3622.                                       ;last match word must be 0,
  3623.                                       ;the addr is the no match routine.
  3624.  
  3625. gotocmd:
  3626.  
  3627.         cmp   ax,0                    ;is it a null command?
  3628.         jz    gotocd3                 ;yes, skip it
  3629.  
  3630. gotocd1:
  3631.  
  3632.         cmp   [bx],ax                 ;does table entry match command number?
  3633.         je    gotocd2                 ;yes, go do that command
  3634.         cmp   byte ptr [bx],0         ;is this the end of the table?
  3635.         je    gotocd2                 ;yes, execute the no match command
  3636.         add   bx,4                    ;bx -> next table entry
  3637.         jmp   gotocd1                 ;go test next table entry
  3638.  
  3639. gotocd2:
  3640.  
  3641.         add   bx,2                    ;bx -> branch word
  3642.         jmp   word ptr [bx]           ;execute the routine
  3643.  
  3644. gotocd3:
  3645.  
  3646.         ret
  3647. ;
  3648.                                       ;call to begin editing a new line
  3649. initlin:
  3650.  
  3651.         call   vidstat                ;get screen width and display page
  3652.         mov    al,ah                  ;al = screen width
  3653.         mov    ah,0                   ;ax = screen width
  3654.         mov    scrnwdt,ax             ;save screen width
  3655.         mov    disppag,bh             ;save the display page
  3656. ;
  3657.         call   getcpos                ;get the cursor position
  3658.         mov    cursory,dh             ;save cursor position in y
  3659.         mov    al,dl                  ;al = cursor position in x
  3660.         mov    ah,0                   ;ax = cursor position in x
  3661.         mov    cursorx,ax             ;save cursor position in x
  3662.         mov    leftx,ax               ;save x position of the left most spot
  3663. ;
  3664.         mov    ax,scrnwdt             ;ax = width of the screen
  3665.         sub    ax,leftx               ;ax = length of editor line
  3666.         mov    linelen,ax             ;save editor line length
  3667. ;
  3668.         call   delline                ;delete everything in the buffer
  3669. ;
  3670.         mov    si,offset scrnimg      ;fill image buffer with zeros
  3671.         mov    cx,maxswdt             ;cx = buffer size
  3672.  
  3673. initln1:
  3674.  
  3675.         mov    byte ptr [si],0        ;put in a zero
  3676.         inc    si                     ;si -> next spot in the buffer
  3677.         loop   initln1                ;loop till done
  3678.         ret
  3679. ;
  3680.  
  3681. dcinitlin:                            ; Initialize for DOS compatibility.
  3682.                                       ; As we enter the line editor, cmdpnt
  3683.                                       ; points to where, in the history
  3684.                                       ; buffer, the command about to be
  3685.                                       ; entered will start.  Get the text of
  3686.                                       ; the PREVIOUS command and store it in
  3687.                                       ; dcbuffer.  This is the command that
  3688.                                       ; will be recalled if user presses the
  3689.                                       ; invisible DOS-like editing keys.
  3690.  
  3691.         push_m  <bx,si,di,ax>
  3692.         call    cmdprev               ; get start of previous command into si
  3693.  
  3694.                                       ; Now copy the command into dcbuffer.
  3695.  
  3696.         mov     di,offset cs:dcbuffer     ; destination
  3697.         mov     word ptr cs:dcpointer,di  ; initialise dcpointer
  3698.         push    si
  3699.         call    cmdnext
  3700.         pop     si
  3701.  
  3702. dcinit2:
  3703.  
  3704.         mov     ah,byte ptr cs:[si]   ; get byte from command buffer
  3705.         mov     byte ptr cs:[di],ah   ; put in destination
  3706.         cmp     ah,0                  ; are we done?
  3707.         je      dcinit1
  3708.         call    cmdinc                ; get next byte from buffer
  3709.         inc     di
  3710.         jmp     short dcinit2
  3711.  
  3712. dcinit1:
  3713.  
  3714.         pop_m   <ax,di,si,bx>
  3715.         ret
  3716.  
  3717.                                       ;call to initialize the tiny editor
  3718. inittny:
  3719.  
  3720.         call   vidstat                ;get the display page
  3721.         mov    disppag,bh             ;save the display page
  3722.         mov    cursorb,offset bublbeg    ;set pointer to cursor beginning
  3723.         mov    cursore,offset bublend    ;set pointer to cursor end
  3724.         call   noundel                ;mark nothing to undelete
  3725.         call   cmdinit                ;initialize the old command recorder
  3726.         ret
  3727.  
  3728.                                         ;Editor commands
  3729.  
  3730.  
  3731. F3proc:                                 ; Call to implement the F3 key, and
  3732.                                         ; make it work like it does with DOS.
  3733.  
  3734.  
  3735.         mov     si,cs:dcpointer
  3736.         push    ax
  3737.         push    bx
  3738.         mov     ax,word ptr cs:cursorb
  3739.         mov     bx,offset cs:bublbeg
  3740.         sub     ax,bx                   ; AX = number of chars left of cursor
  3741.         push    ax
  3742.         call    delline                 ; delete whats in the buffer now. Can't
  3743.                                         ; do this before calculating ax, cos
  3744.                                         ; it destroys cursorb.
  3745.         pop     ax
  3746.         add     word ptr cs:cursorb,ax  ; Move destination for the incoming
  3747.                                         ; characters past the ones already
  3748.                                         ; typed.
  3749.         pop     bx
  3750.         pop     ax
  3751. ;
  3752.                                         ;Now carry on like a normal cursup.
  3753. f3proc1:
  3754.  
  3755.         call    cmdotrg                 ;get a character from the last command
  3756.         cmp     al,0                    ;is it the termination char?
  3757.         jz      f3proc2                 ;yes
  3758.         cmp     al,0FFh
  3759.         je      f3proc1
  3760.         call    putin                   ;no, place the char in the bubble
  3761.         jmp     f3proc1
  3762. ;
  3763. f3proc2:
  3764.  
  3765.         call    noundel                 ;mark nothing undeletable
  3766.         call    setcol                  ;update start display column number
  3767.         call    cmdnext
  3768.         ret
  3769.  
  3770.  
  3771.                                       ;Call to move the cursor up one line,
  3772.                                       ;show previous command in buffer.
  3773. cursup:
  3774.  
  3775.         call   delline                ;delete what's in the buffer now
  3776.         call   cmdprev                ;si -> previous command
  3777.  
  3778. cursup1:
  3779.  
  3780.         call   cmdotrg                ;get a character from the last command
  3781.         cmp    al,0                   ;is it the termination char?
  3782.         jz     cursup2                ;yes
  3783.         call   putin                  ;no, place the char in the bubble
  3784.         jmp    cursup1
  3785.  
  3786. cursup2:
  3787.  
  3788.         call   noundel                ;mark nothing undeletable
  3789.         call   setcol                 ;update start display column number
  3790.         ret
  3791.  
  3792.                                       ;call to move the cursor down one line,
  3793.                                       ;show next command in buffer.
  3794.  
  3795. cursdn:
  3796.  
  3797.         call   delline                ;delete whats in the buffer now
  3798.         call   cmdnext                ;si -> next command
  3799.  
  3800. cursdn1:
  3801.  
  3802.         call   cmdotrg                ;get a character from the next command
  3803.         cmp    al,0                   ;is it the termination char?
  3804.         jz     cursdn2                ;yes
  3805.         call   putin                  ;no, place the char in the bubble
  3806.         jmp    cursdn1
  3807.  
  3808. cursdn2:
  3809.  
  3810.         call   noundel                ;mark nothing undeletable
  3811.         call   setcol                 ;update start display column number
  3812.         ret
  3813.  
  3814.                                       ;Call to move the cursor to beginning
  3815.                                       ;of the line.
  3816. begline:
  3817.  
  3818.         cmp    cursorb,offset bublbeg ;is the cursor at the beginning?
  3819.         je     beglin1                ;yes, all done
  3820.         call   curslf                 ;move the cursor over 1
  3821.         jmp    begline
  3822.  
  3823. beglin1:
  3824.  
  3825.         ret
  3826.  
  3827.                                       ;Call to move the cursor to the end of
  3828.                                       ;the line.
  3829.  
  3830. endline:
  3831.  
  3832.         cmp    cursore,offset bublend ;is the cursor at the end?
  3833.         je     endlin1                ;yes, all done
  3834.         call   cursrt                 ;move the cursor over 1
  3835.         jmp    endline
  3836.  
  3837. endlin1:
  3838.  
  3839.         ret
  3840.  
  3841.                                       ;call to move the cursor left one word
  3842. wordl:
  3843.  
  3844.         call   curslf                 ;move cursor 1 to the left
  3845.         mov    si,cursorb             ;si -> character on the left of cursor
  3846.         cmp    si,offset bublbeg      ;is it at the beginning of the bubble?
  3847.         je     wordl1                 ;yes, all done moving
  3848.         mov    al,[si-1]              ;al = character on the left
  3849.         call   wordchr                ;is it a legal word character?
  3850.         jnc    wordl                  ;yes, go eat the char
  3851.         call   curslf                 ;move one more across the white char
  3852.  
  3853. wordl1:
  3854.  
  3855.         ret
  3856.  
  3857.                                       ;Call to move the cursor left one word
  3858. wordr:
  3859.  
  3860.         call   cursrt                 ;move one character to the right
  3861.         mov    si,cursore             ;si -> character on the right of cursor
  3862.         cmp    si,offset bublend      ;is it at the end of the bubble?
  3863.         je     wordr1                 ;yes, all done moving
  3864.         mov    al,[si+1]              ;al = character on the right
  3865.         call   wordchr                ;is it a legal word character?
  3866.         jnc    wordr                  ;yes, go eat the char
  3867.         call   cursrt                 ;move one more across the white char
  3868.  
  3869. wordr1:
  3870.  
  3871.         ret
  3872.                                       ;Call to move the cursor left one char
  3873. curslf:
  3874.  
  3875.         cmp    cursorb,offset bublbeg ;is the cursor at the beginning?
  3876.         je     curslf1                ;yes, don't move it
  3877.         dec    cursorb                ;cursorb -> character left of cursor
  3878.         mov    si,cursorb             ;si -> cursor beginning
  3879.         mov    di,cursore             ;di -> cursor end
  3880.         mov    al,[si]                ;al = character left of the cursor
  3881.         mov    [di],al                ;move character right of the cursor
  3882.         dec    cursore                ;cursore -> end of the new cursor
  3883.         call   noundel                ;mark nothing undeletable
  3884.         call   setcol                 ;update start display column number
  3885.  
  3886. curslf1:
  3887.  
  3888.         ret
  3889.  
  3890.                                       ;Call to move the cursor right one char
  3891. cursrt:
  3892.  
  3893.         cmp    cursore,offset bublend ;is the cursor at the end?
  3894.         je     cursrt1                ;yes, don't move it
  3895.         inc    cursore                ;cursore -> character right of cursor
  3896.         mov    si,cursorb             ;si -> cursor beginning
  3897.         mov    di,cursore             ;di -> cursor end
  3898.         mov    al,[di]                ;al = character right of the cursor
  3899.         mov    [si],al                ;move character left of the cursor
  3900.         inc    cursorb                ;cursorb -> new beginning of the cursor
  3901.         call   noundel                ;mark nothing undeletable
  3902.         call   setcol                 ;update start display column number
  3903.  
  3904. cursrt1:
  3905.  
  3906.         ret
  3907.  
  3908.                                       ;call to delete the line the cursor's on
  3909. delline:
  3910.  
  3911.         call   dellinl                  ;delete everything to the left
  3912.         call   dellinr                  ;delete everything to the right
  3913.  
  3914.         ret
  3915.  
  3916. escproc:
  3917.  
  3918.         call   delline                  ; When user hits ESC, delete the
  3919.                                         ; current line, and reset dcpointer
  3920.         push   si
  3921.         mov    si,offset cs:dcbuffer
  3922.         mov    word ptr cs:dcpointer,si
  3923.         pop    si
  3924.         ret
  3925. ;
  3926.                                       ;call to delete all char to beginning
  3927.                                       ;of line.
  3928. dellinl:
  3929.  
  3930.         cmp    cursorb,offset bublbeg ;is the cursor at the beginning?
  3931.         je     dellnl1                ;yes, all deleted
  3932.         call   delchrl                ;no, delete char on the left
  3933.         jmp    dellinl                ;loop till all gone
  3934.  
  3935. dellnl1:
  3936.  
  3937.         ret
  3938.  
  3939.                                       ;call to delete to end of line
  3940. dellinr:
  3941.  
  3942.         cmp    cursore,offset bublend ;is the cursor at the end?
  3943.         je     dellnr1                ;yes, all deleted
  3944.         call   delchrr                ;no, delete char on the right
  3945.         jmp    dellinr                ;loop till all gone
  3946.  
  3947. dellnr1:
  3948.  
  3949.         ret
  3950.  
  3951.                                       ;call to delete word left of the cursor
  3952. delwrdl:
  3953.  
  3954.         call   delchrl                ;delete the character to the left
  3955.         mov    si,cursorb             ;si -> character on the left of cursor
  3956.         cmp    si,offset bublbeg      ;is it at the beginning of the bubble?
  3957.         je     delwrl1                ;yes, all done deleting
  3958.         mov    al,[si-1]              ;al = character on the left
  3959.         call   wordchr                ;is it a legal word character?
  3960.         jnc    delwrdl                ;yes, go eat the char
  3961.  
  3962. delwrl1:
  3963.  
  3964.         ret
  3965.  
  3966.                                       ;call to delete a word right
  3967.                                       ;of the cursor.
  3968. delwrdr:
  3969.  
  3970.         call   delchrr                ;delete the character to the right
  3971.         mov    si,cursore             ;si -> character on the right of cursor
  3972.         cmp    si,offset bublend      ;is it at the end of the bubble?
  3973.         je     delwrr1                ;yes, all done deleting
  3974.         mov    al,[si+1]              ;al = character on the right
  3975.         call   wordchr                ;is it a legal word character?
  3976.         jnc    delwrdr                ;yes, go eat the char
  3977.  
  3978. delwrr1:
  3979.  
  3980.         ret
  3981.  
  3982.                                       ;call to delete char left of cursor
  3983. delchrl:
  3984.  
  3985.         cmp    cursorb,offset bublbeg ;is the cursor at the beginning?
  3986.         je     delchl1                ;yes, don't delete
  3987.         dec    cursorb                ;delete the character
  3988.         inc    unleft                 ;make the character undeletable
  3989.         call   setcol                 ;update start display column number
  3990.  
  3991. delchl1:
  3992.  
  3993.         ret
  3994.  
  3995.  
  3996. delchrr:
  3997.  
  3998.                                       ; Call to delete char right of cursor
  3999.                                       ; However, if user hasn't typed any
  4000.                                       ; chars yet, delete a character from the
  4001.                                       ; dcbuffer.
  4002.  
  4003.  
  4004.         push    bx
  4005.         call    bublcnt               ; bx <-- no of chars typed
  4006.         cmp     bx,0
  4007.         pop     bx
  4008.         jne     del_right
  4009.  
  4010.                                       ; No chars have been typed, so
  4011.                                       ; effectively delete a char from the
  4012.                                       ; dcbuffer by incrementing dcpointer.
  4013.  
  4014.         inc     word ptr cs:dcpointer
  4015.         ret
  4016.  
  4017.  
  4018. del_right:
  4019.  
  4020.         cmp    cursore,offset bublend ;is the cursor at the end?
  4021.         je     del_dcbuff             ;yes, so delete from dcbuffer instead
  4022.         inc    cursore                ;delete the character
  4023.         inc    unright                ;make the character undeletable
  4024.         call   setcol                 ;update start display column number
  4025.  
  4026. delchr1:
  4027.  
  4028.         ret
  4029.  
  4030. del_dcbuff:
  4031.  
  4032.         inc  byte ptr cs:dcpointer
  4033.         ret
  4034.  
  4035.                                       ;call to undelete text from the buffer
  4036. undelet:
  4037.  
  4038.         mov    ax,unleft              ;al = # of char to undelete on left
  4039.         add    cursorb,ax             ;undelete on the left
  4040.         mov    ax,unright             ;al = # of char to undelete on right
  4041.         sub    cursore,ax             ;undelete on the right
  4042.         call   noundel                ;mark nothing undeletable
  4043.         call   setcol                 ;update start display column number
  4044.         ret
  4045.  
  4046.                                       ;call to place a character in the edit
  4047.                                       ;buffer, filter out trash first
  4048. nomatch:
  4049.  
  4050.         call   filter                 ;filter out trash
  4051.         jc     nomtch1                ;branch on trash
  4052.         call   putin                  ;else insert character in edit buffer
  4053.         call   noundel                ;mark nothing undeletable
  4054.         call   setcol                 ;update start display column number
  4055.  
  4056. nomtch1:
  4057.  
  4058.         ret
  4059.  
  4060.                                       ;Editor Display Functions
  4061.  
  4062.                                       ;call to update the display line
  4063. update:
  4064.  
  4065.         push   ax                     ;save registers
  4066.         push   bx
  4067.         push   dx
  4068.         push   si
  4069.         push   di
  4070.         mov    si,offset bublbeg      ;si -> first char in bubble
  4071.         mov    bx,startx              ;bx = start column # of display line
  4072.         call   findcol                ;si -> first character to display
  4073.         mov    di,offset scrnimg      ;di -> screen image buffer
  4074.         mov    updatex,0              ;x pos on display line to update
  4075.  
  4076. update1:
  4077.  
  4078.         cmp    si,cursorb             ;does si -> the cursor in the bubble?
  4079.         jne    update2                ;no
  4080.         mov    ax,updatex             ;yes, save the editor cursor position
  4081.         add    ax,leftx               ;add the starting left column number
  4082.         mov    edcursx,ax
  4083.         mov    si,cursore             ;si -> end of cursor marker
  4084.         inc    si                     ;si -> first char right of the cursor
  4085.  
  4086. update2:
  4087.  
  4088.         cmp    si,offset bublend+1    ;does si -> end of the buffer
  4089.         je     update5                ;yes, go blank end of line
  4090.         mov    al,[si]                ;al = next char to display
  4091.         inc    si                     ;si -> next char in the bubble
  4092.         cmp    al,tab                 ;is the character a tab?
  4093.         jne    update4                ;no, go display the character
  4094.  
  4095. update3:
  4096.  
  4097.         mov    al,' '                 ;yes, expand the tab, display a blank
  4098.         call   updatec                ;display the blank
  4099.         jz     update6                ;branch if update complete
  4100.         mov    ax,updatex             ;ax = current update column
  4101.         add    ax,startx              ;ax = x pos from start of edit line
  4102.         and    ax,111b                ;ax = column mod 8
  4103.         jnz    update3                ;loop till tab expanded
  4104.         jmp    update1                ;go display the next character
  4105.  
  4106. update4:
  4107.  
  4108.         call   updatec                ;display a normal character
  4109.         jz     update6                ;branch if update complete
  4110.         jmp    update1                ;go display the next character
  4111.  
  4112. update5:
  4113.  
  4114.         mov    ax,linelen             ;blank end of line
  4115.         dec    ax                     ;ax = right most column number
  4116.         cmp    ax,updatex             ;has the full screen been displayed?
  4117.         jz     update6                ;yes, all done
  4118.         cmp    byte ptr [di],0        ;has this character never been changed?
  4119.         jz     update6                ;yes, don't change it
  4120.         mov    al,' '                 ;end of line, display blanks
  4121.         call   updatec                ;display the character
  4122.         jnz    update1                ;go display next char if not done
  4123.  
  4124. update6:
  4125.  
  4126.         mov    dx,edcursx             ;position the hardware editor cursor
  4127.         call   setcurx
  4128.         mov    cursorx,dx             ;save the cursor x value
  4129.         pop    di                     ;restore registers and return
  4130.         pop    si
  4131.         pop    dx
  4132.         pop    bx
  4133.         pop    ax
  4134.         ret
  4135.  
  4136.                                       ;call to update a single char on display
  4137.                                       ;Entry:
  4138.                                       ;al = character to write
  4139.                                       ;di -> char in same pos on screen
  4140.                                       ;cursorx = pos of hardware cursor in x
  4141.                                       ;updatex = next x loc to update on scrn
  4142.                                       ;Exit:
  4143.                                       ;cursorx = loc of the hw cursor in x
  4144.                                       ;updatex = new x loc to update on scr
  4145.                                       ;          next time
  4146.                                       ;di -> next character in screen image
  4147.                                       ;z flag set if line fully displayed
  4148.  
  4149. updatec:
  4150.  
  4151.         cmp    al,[di]                ;is the char already shown?
  4152.         je     updatc2                ;yes, don't change it
  4153.         mov    dx,updatex             ;no, must display the character
  4154.         add    dx,leftx               ;dl = desired x location to update
  4155.         cmp    cursorx,dx             ;is the cursor in the correct spot?
  4156.         je     updatc1                ;yes, don't need to move it
  4157.         call   setcurx                ;no, set the cursor column
  4158.         mov    cursorx,dx             ;save the cursor x value
  4159.  
  4160. updatc1:
  4161.  
  4162.         call   putc                   ;display the character
  4163.         inc    cursorx                ;increment the hardware cursor column
  4164.         mov    [di],al                ;put the character in the image buffer
  4165.  
  4166. updatc2:
  4167.  
  4168.         inc    updatex                ;increment the next update column no.
  4169.         inc    di                     ;di -> next char in image buffer
  4170.         mov    ax,linelen             ;ax = line length
  4171.         dec    ax                     ;ax = left most column, line relative
  4172.         cmp    ax,updatex             ;set z flag if display line is full
  4173.         ret
  4174.  
  4175.  
  4176.                                       ;Primitive Editor Functions
  4177.  
  4178.                                       ;call to filter out unwanted characters
  4179.                                       ;Entry:
  4180.                                       ;ax = keyboard character
  4181.                                       ;Exit:
  4182.                                       ;ax = keyboard character
  4183.                                       ;carry set if key filter out
  4184.                                       ;all other registers unchanged
  4185.  
  4186. filter:
  4187.  
  4188.         cmp    al,LF                  ;is it a line feed?
  4189.         je     filter2                ;yes, filter it out
  4190.  
  4191. filter1:
  4192.  
  4193.         clc                           ;don't filter
  4194.         ret                           ;return with no carry
  4195.  
  4196. filter2:
  4197.  
  4198.         stc                           ;do filter the character
  4199.         ret                           ;return with no carry
  4200.  
  4201.                                       ;insert a char into bubble buffer,
  4202.                                       ;no filtering
  4203.                                       ;Entry:
  4204.                                       ;al = character
  4205.                                       ;Exit:
  4206.                                       ;all registers unchanged
  4207.  
  4208. putin:
  4209.  
  4210.         push   ax                     ;save registers
  4211.         push   si
  4212.         call   bublcnt                ;bx = number of characters in bubble
  4213.         cmp    bx,maxchar             ;are more characters allowed?
  4214.         jae    putin1                 ;no, trash the character
  4215.         mov    si,cursorb             ;si -> beginning of the cursor
  4216.         mov    [si],al                ;put the character in the bubble
  4217.         inc    si                     ;si -> next spot in the bubble
  4218.         cmp    si,cursore             ;is the bubble full?
  4219.         je     putin1                 ;yes, don't update the cursor position
  4220.         mov    cursorb,si             ;update the beginning of the cursor
  4221.  
  4222. putin1:
  4223.  
  4224.         pop    si                     ;restore registers
  4225.         pop    ax
  4226.  
  4227.                                       ; If insert mode is off, make a call
  4228.                                       ; to dellchrr, to delete the character
  4229.                                       ; to the right of the cursor.  This
  4230.                                       ; is how we achieve overwrite mode.
  4231.  
  4232.         cmp    byte ptr cs:ins_mode,1 ; insert mode on?
  4233.         je     putin2                 ; yes, so we're ok
  4234.         call   delchrr                ; overwrite mode required
  4235.  
  4236. putin2:
  4237.  
  4238.         ret
  4239.  
  4240.                                       ;call to compute the number of
  4241.                                       ;characters in the bubble buffer
  4242.                                       ;Exit:
  4243.                                       ;bx = number of characters in the buffer
  4244.                                       ;all other registers unchanged
  4245.  
  4246. bublcnt:
  4247.  
  4248.         mov    bx,offset bublend      ;add char count before & after bubble
  4249.         sub    bx,cursore
  4250.         add    bx,cursorb
  4251.         sub    bx,offset bublbeg
  4252.         ret
  4253.  
  4254.                                       ;call to mark nothing undeletable
  4255. noundel:
  4256.  
  4257.         mov    unleft,0
  4258.         mov    unright,0
  4259.         ret
  4260.  
  4261.                                       ;find address of char at column n
  4262.                                       ;Enter:
  4263.                                       ;si -> beginning of string
  4264.                                       ;bx = desired column number
  4265.                                       ;Exit:
  4266.                                       ;si -> character at column n
  4267.                                       ;all other registers unchanged
  4268.  
  4269. findcol:
  4270.  
  4271.         push   ax                     ;save registers
  4272.         push   bx
  4273.         push   cx
  4274.         mov    cx,0                   ;cx = column counter
  4275.         cmp    cx,bx                  ;is this the correct column number?
  4276.         je     findcl3                ;yes, all done
  4277.         inc    bx                     ;incrememt the desired column number
  4278.  
  4279. findcl1:
  4280.  
  4281.         mov    al,[si]                ;al = character from string
  4282.         cmp    al,tab                 ;is it a tab?
  4283.         jne    findcl2                ;no, normal character
  4284.         add    cx,8                   ;yes, expand tab, add tab width
  4285.         and    cx,0fff8h              ;cx = column at next tab stop
  4286.         cmp    cx,bx                  ;is this the correct column?
  4287.         jae    findcl3                ;yes, stop looking
  4288.         inc    si                     ;no, si -> next char in string
  4289.         jmp    findcl1                ;branch if this not desired column
  4290.  
  4291. findcl2:
  4292.  
  4293.         inc    cx                     ;no, add 1 column for displayable char
  4294.         cmp    cx,bx                  ;is this the correct column?
  4295.         je     findcl3                ;yes, stop looking
  4296.         inc    si                     ;si -> next char in string
  4297.         jmp    findcl1                ;keep looking
  4298.  
  4299. findcl3:
  4300.  
  4301.         pop    cx                     ;restore registers and return
  4302.         pop    bx
  4303.         pop    ax
  4304.         ret
  4305.  
  4306.                                       ;call to compute the column
  4307.                                       ;number to begin displaying
  4308.  
  4309.                                       ;Entry:
  4310.                                       ;startx = current start col
  4311.                                       ;of display line
  4312.                                       ;Exit:
  4313.                                       ;startx = new starting column
  4314.                                       ;of the display line
  4315.                                       ;all registers unchanged
  4316.  
  4317. setcol:
  4318.  
  4319.         push   ax                     ;save registers
  4320.         push   bx
  4321.         call   colcurs                ;compute cursor column number
  4322.         cmp    bx,startx              ;is the cursor left of the screen?
  4323.         jae    setcol1                ;no
  4324.         mov    startx,bx              ;yes, set the start spot same as crsr
  4325.         jmp    setcol2                ;all done
  4326.  
  4327. setcol1:
  4328.  
  4329.         mov    ax,linelen             ;ax = width of the display line
  4330.         dec    ax                     ;ax = right most display column
  4331.         add    ax,startx              ;ax = x pos of last displayed char
  4332.         cmp    bx,ax
  4333.         jb     setcol2                ;branch if cursor is on the screen
  4334.  
  4335.         sub    bx,linelen             ;cursor right of display line
  4336.         add    bx,2                   ;compute new starting column
  4337.         mov    startx,bx
  4338.  
  4339. setcol2:
  4340.  
  4341.         pop    bx                     ;restore registers and return
  4342.         pop    ax
  4343.         ret
  4344.  
  4345.                                       ;call to compute the column number the
  4346.                                       ;cursor is on, from beginning of line
  4347.                                       ;Exit:
  4348.                                       ;bx = cursor column number
  4349.                                       ;all other registers unchanged
  4350.  
  4351. colcurs:
  4352.  
  4353.         push   ax                     ;save registers
  4354.         push   si
  4355.         mov    si,offset bublbeg      ;si -> first char on line
  4356.         mov    bx,0                   ;zero column counter
  4357.  
  4358. colcur1:
  4359.  
  4360.         cmp    si,cursorb             ;does si -> the cursor?
  4361.         je     colcur3                ;yes, found the cursor column
  4362.         mov    al,[si]                ;get char from line
  4363.         inc    si                     ;si -> next char on line
  4364.         cmp    al,tab                 ;is it a tab?
  4365.         jne    colcur2                ;no, normal character
  4366.         add    bx,8                   ;add distance between tab stops
  4367.         and    bx,0fff8h              ;bx = column of next tab stop
  4368.         jmp    colcur1                ;go check next character
  4369.  
  4370. colcur2:
  4371.  
  4372.         inc    bx                     ;add 1 column for displayable char
  4373.         jmp    colcur1                ;go check next char
  4374.  
  4375. colcur3:
  4376.  
  4377.         pop    si                     ;restore registers and return
  4378.         pop    ax
  4379.         ret
  4380.  
  4381.                                       ;Functions to record and retrieve
  4382.                                       ;past lines edited
  4383.  
  4384.                                       ;call to find the previous command
  4385.                                       ;Exit:
  4386.                                       ;si -> beginning of the previous cmd
  4387.                                       ;all other registers unchanged
  4388.  
  4389. cmdprev:
  4390.  
  4391.         mov    si,cmdpnt              ;si -> current command
  4392.         cmp    si,cmdold              ;is this the oldest command?
  4393.         je     cmdprv1                ;yes, return pointer to this one
  4394.         call   cmdbefr                ;si -> the previous command
  4395.         mov    cmdpnt,si              ;si -> new current command
  4396.  
  4397. cmdprv1:
  4398.  
  4399.         ret
  4400.  
  4401.                                       ;call to find the next command
  4402.                                       ;Exit:
  4403.                                       ;si -> beginning of the next command
  4404.                                       ;all other registers unchanged
  4405.  
  4406. cmdnext:
  4407.  
  4408.         mov    si,cmdpnt              ;si -> current command
  4409.         cmp    si,cmdnew              ;is this the newest command?
  4410.         je     cmdnxt1                ;yes, return pointer to this one
  4411.         call   cmdaftr                ;si -> the next command
  4412.         mov    cmdpnt,si              ;si -> new current command
  4413.  
  4414. cmdnxt1:
  4415.  
  4416.         ret
  4417.  
  4418.                                       ;call to enter cmd into the ring
  4419.                                       ;Entry:
  4420.                                       ;si -> command terminated by zero
  4421.                                       ;to insert into the ring
  4422.  
  4423. cmdput:
  4424.  
  4425.         push   ax                     ;save registers
  4426.         push   si
  4427.         cmp    byte ptr [si],0        ;is it a null command?
  4428.         jz     cmdput2                ;yes, don't put it in
  4429.  
  4430. cmdput1:
  4431.  
  4432.         mov    al,[si]                ;get a character to insert
  4433.         inc    si                     ;si -> next char to insert
  4434.         call   cmdinrg                ;put it in the ring
  4435.         cmp    al,0                   ;is it the termination zero?
  4436.         jnz    cmdput1                ;no, go insert the next one
  4437.  
  4438. cmdput2:
  4439.  
  4440.         mov    si,cmdnew              ;si -> spot for the next new command
  4441.         mov    cmdpnt,si              ;put the command pointer here
  4442.         mov    byte ptr [si],0        ;make new command a null string
  4443.         pop    si                     ;restore registers and return
  4444.         pop    ax
  4445.         ret
  4446.  
  4447.                                       ;call to get a char from the ring
  4448.                                       ;Entry:
  4449.                                       ;si -> character in the ring
  4450.                                       ;Exit:
  4451.                                       ;al = character from the ring
  4452.                                       ;si -> next character in the ring
  4453.  
  4454. cmdotrg:
  4455.  
  4456.         mov    al,[si]                ;get char from the ring
  4457.         call   cmdinc                 ;si -> next char in the ring
  4458.         ret
  4459.  
  4460.                                       ;call to enter a char into the ring
  4461.                                       ;Entry:
  4462.                                       ;al = character to insert
  4463.                                       ;cmdnew -> storage for new cmd char
  4464.                                       ;Exit:
  4465.                                       ;all registers unchanged
  4466.  
  4467. cmdinrg:
  4468.  
  4469.         push   si                     ;save registers
  4470.         mov    si,cmdnew              ;si -> storage for new commands
  4471.         mov    [si],al                ;save the new command character
  4472.         call   cmdinc                 ;increment the pointer
  4473.         mov    cmdnew,si              ;update pointer for new commands
  4474.         cmp    si,cmdold              ;is an old command in the way?
  4475.         jne    cmdinr1                ;no
  4476.         mov    si,cmdold              ;yes, remove the oldest command
  4477.         call   cmdaftr                ;si -> next to oldest command
  4478.         mov    cmdold,si              ;save pointer to new oldest command
  4479.  
  4480. cmdinr1:
  4481.  
  4482.         pop    si
  4483.         ret
  4484.  
  4485.                                       ;call to search for previous command
  4486.                                       ;Entry:
  4487.                                       ;si -> beginning of current command
  4488.                                       ;Exit:
  4489.                                       ;si -> beginning of previous command
  4490.                                       ;all other registers unchanged
  4491.  
  4492. cmdbefr:
  4493.  
  4494.         call   cmddec                 ;si -> termination of previous command
  4495. cmdbfr1:
  4496.  
  4497.         call   cmddec                 ;si -> previous character
  4498.         cmp    byte ptr [si],0        ;does si -> termination char?
  4499.         jnz    cmdbfr1                ;no, keep looping
  4500.         call   cmdinc                 ;si -> first char of command
  4501.         ret
  4502.  
  4503.                                       ;call to search for the next command
  4504.                                       ;Entry:
  4505.                                       ;si -> beginning of current command
  4506.                                       ;Exit:
  4507.                                       ;si -> beginning of next command
  4508.                                       ;all other registers unchanged
  4509.  
  4510. cmdaftr:
  4511.  
  4512.         call   cmdinc                 ;si -> next character
  4513.         cmp    byte ptr [si],0        ;does si -> termination char?
  4514.         jnz    cmdaftr                ;no, keep looping
  4515.         call   cmdinc                 ;si -> first char of command
  4516.         ret
  4517.  
  4518.                                       ;call to increment a pointer into
  4519.                                       ;the commands buffer.
  4520.  
  4521.                                       ;Exit:
  4522.                                       ;si = increment pointer
  4523.                                       ;all other registers unchanged
  4524. cmdinc:
  4525.  
  4526.         inc    si                     ;inc the pointer
  4527.         cmp    si,offset cmdbot       ;is the pointer outside the ring?
  4528.         jbe    cmdinc1                ;no
  4529.         mov    si,offset cmdtop       ;yes, set pointer to the top
  4530.  
  4531. cmdinc1:
  4532.  
  4533.         ret
  4534.  
  4535.                                       ;call to decrement a pointer into the
  4536.                                       ;commands buffer.
  4537.                                       ;Exit:
  4538.                                       ;si = decremented pointer
  4539.                                       ;all other registers unchanged
  4540.  
  4541. cmddec:
  4542.  
  4543.         dec    si                     ;dec the pointer
  4544.         cmp    si,offset cmdtop       ;is the pointer outside the ring?
  4545.         jae    cmddec1                ;no
  4546.         mov    si,offset cmdbot       ;yes, set pointer to the bottom
  4547.  
  4548. cmddec1:
  4549.  
  4550.         ret
  4551.  
  4552.                                       ;call to initialize the command
  4553.                                       ;recording functions.
  4554.  
  4555. cmdinit:
  4556.  
  4557.         mov    si,offset cmdtop       ;si -> beginning of command ring
  4558.         mov    cmdold,si              ;initialize all pointer to top of ring
  4559.         mov    cmdnew,si
  4560.         mov    cmdpnt,si
  4561.         mov    si,offset cmdtop       ;fill command buffer with null strings
  4562.         mov    cx,cmdlen              ;cx = buffer size
  4563.  
  4564. cmdint1:
  4565.  
  4566.         mov    byte ptr [si],0        ;put in a zero
  4567.         inc    si                     ;si -> next spot in the buffer
  4568.         loop   cmdint1                ;loop till done
  4569.         ret
  4570.  
  4571.                                       ;DOS and ROM Interface Functions
  4572.  
  4573.                                       ;call to get the state of the video
  4574.                                       ;Exit:
  4575.                                       ;al = display mode
  4576.                                       ;ah = number of char columns on screen
  4577.                                       ;bh = current active display page
  4578.                                       ;bl = undefined
  4579.                                       ;all other registers unchanged
  4580.  
  4581. vidstat:
  4582.  
  4583.         push   si                     ;save registers
  4584.         push   di
  4585.         mov    ah,15                  ;get the video state
  4586.         bios_video
  4587.         pop    di                     ;restore registers and return
  4588.         pop    si
  4589.         ret
  4590.  
  4591.                                       ;call to get the cursor position
  4592.                                       ;Exit:
  4593.                                       ;dl = cursor position in x
  4594.                                       ;dh = cursor position in y
  4595.                                       ;all other registers unchanged
  4596.  
  4597. getcpos:
  4598.  
  4599.         push   ax                     ;save registers
  4600.         push   bx
  4601.         push   si
  4602.         push   di
  4603.         mov    bh,disppag             ;bh = display page
  4604.         mov    ah,3                   ;read the cursor position
  4605.         bios_video
  4606.         pop    di                     ;restore registers and return
  4607.         pop    si
  4608.         pop    bx
  4609.         pop    ax
  4610.         ret
  4611.  
  4612.                                       ;call to set the cursor x position
  4613.                                       ;Entry:
  4614.                                       ;dl = cursor position in x
  4615.                                       ;Exit:
  4616.                                       ;all registers unchanged
  4617.  
  4618. setcurx:
  4619.  
  4620.         push   ax                     ;save registers
  4621.         push   bx
  4622.         push   si
  4623.         push   di
  4624.         mov    dh,cursory             ;dh = cursor line number
  4625.         mov    bh,disppag             ;bh = display page
  4626.         mov    ah,2                   ;set the cursor position
  4627.         bios_video
  4628.         pop    di                     ;restore registers and return
  4629.         pop    si
  4630.         pop    bx
  4631.         pop    ax
  4632.         ret
  4633.  
  4634.                                       ;call to display a string
  4635.                                       ;Entry:
  4636.                                       ;si -> string terminated by zero
  4637.                                       ;Exit:
  4638.                                       ;all registers unchanged
  4639.  
  4640. puts:
  4641.  
  4642.         push   ax                     ;save registers
  4643.         push   si
  4644.  
  4645. puts1:
  4646.  
  4647.         mov    al,[si]                ;get char from the string
  4648.         inc    si                     ;si -> next char in string
  4649.         cmp    al,0                   ;is it the termination zero?
  4650.         jz     puts2                  ;yes, all done
  4651.         call   putc                   ;display the character
  4652.         jmp    puts1                  ;go display the next character
  4653.  
  4654. puts2:
  4655.  
  4656.         pop    si                     ;restore registers and return
  4657.         pop    ax
  4658.         ret
  4659.  
  4660. putc:                                 ;display char in al
  4661.  
  4662.         disp_ch al
  4663.         ret
  4664.  
  4665.                                       ;call to get a char from the console
  4666.                                       ;keyboard without echo
  4667.                                       ;Exit:
  4668.                                       ;ax = char from keyboard
  4669.                                       ;ah = 1 if extended keycode else 0
  4670.                                       ;all other registers unchanged
  4671.  
  4672. getc:
  4673.  
  4674.         mov    ah,8                   ;read keyboard without echo
  4675.         int    21h
  4676.         cmp    al,0                   ;is it an extended key?
  4677.         jz     getc1                  ;yes, go get the keycode
  4678.         mov    ah,0                   ;no, ax = keyboard code
  4679.         ret
  4680.  
  4681. getc1:
  4682.  
  4683.         mov    ah,8                   ;read keyboard without echo
  4684.         int    21h
  4685.         mov    ah,1                   ;ax = extended keycode
  4686.         ret
  4687.  
  4688.                                       ;Misc Functions
  4689.  
  4690.                                       ;call to compute the length of a string
  4691.                                       ;Entry:
  4692.                                       ;cs:si -> string terminated by zero
  4693.                                       ;Exit:
  4694.                                       ;cx = string length
  4695.                                       ;all other registers unchanges
  4696.  
  4697. strlen:
  4698.  
  4699.         push   si                     ;save registers
  4700.         mov    cx,0                   ;zero the counter
  4701.  
  4702. strlen1:
  4703.  
  4704.         cmp    byte ptr cs:[si],0     ;is this the termination character?
  4705.         jz     strlen2                ;yes, all done
  4706.         inc    si                     ;si -> next char in string
  4707.         inc    cx                     ;inc the char counter
  4708.         jmp    strlen1                ;loop till done
  4709.  
  4710. strlen2:
  4711.  
  4712.         pop    si                     ;restore registers and return
  4713.         ret
  4714.  
  4715.                                       ;call to check for legal word character
  4716.                                       ;Entry:
  4717.                                       ;al = char to test
  4718.                                       ;Exit:
  4719.                                       ;cf set if invalid char
  4720.                                       ;all other registers unchanged
  4721.  
  4722. wordchr:
  4723.  
  4724.         push   bx                     ;save bx
  4725.         mov    bx,'az'                ;is the char a lower case letter?
  4726.         call   chrrang
  4727.         jnc    wordch1                ;yes, return with no carry
  4728.         mov    bx,'AZ'                ;is the char an upper case letter?
  4729.         call   chrrang
  4730.         jnc    wordch1                ;yes, return with no carry
  4731.         mov    bx,'09'                ;is the char a number?
  4732.         call   chrrang                ;return with status in carry
  4733.  
  4734. wordch1:
  4735.  
  4736.         pop    bx                     ;restore bx and return
  4737.         ret
  4738.  
  4739.                                       ;call to test if a character is
  4740.                                       ;between or included by two characters
  4741.                                       ;Entry:
  4742.                                       ;al = char to check
  4743.                                       ;bl = upper match char
  4744.                                       ;bh = low match char
  4745.                                       ;Exit:
  4746.                                       ;cf clear if valid match
  4747.                                       ;bl = undefined
  4748.                                       ;all other registers unchanged
  4749.  
  4750. chrrang:
  4751.  
  4752.         cmp    al,bh                  ;is the char < bh
  4753.         jc     chrrng1                ;yes, no match, return with carry
  4754.         inc    bl                     ;is the char > bl
  4755.         cmp    al,bl                  ;compare with upper limit
  4756.         cmc                           ;invert the carry flag
  4757.  
  4758. chrrng1:
  4759.  
  4760.         ret
  4761. ;
  4762. inskey         proc                    ; Toggle insert mode, cos user has
  4763.                                        ; pressed insert key.
  4764.  
  4765.                                        ; However, if bublcnt = 0, obey the
  4766.                                        ; rules of DOS compatibility and insert
  4767.                                        ; an 0FFh byte into dcbuffer.
  4768.  
  4769.         push   bx
  4770.         call   bublcnt
  4771.         cmp    bx,0                    ; Has user typed anything yet?
  4772.         pop    bx
  4773.         jne    ins_normal              ; If yes, continue normally
  4774.  
  4775.                                        ; Insert a 0FFh byte into dcbuffer,
  4776.                                        ; starting at cs:[dcpointer].
  4777.  
  4778.         push    si
  4779.         mov     si,offset cs:dcbufend  ; start at end of dcbuffer
  4780.         sub     si,2                   ; point to last byte of dcbuffer
  4781.                                        ; before end marker
  4782.         cmp     byte ptr cs:[si],0     ; is there room for a char to be
  4783.                                        ; inserted?
  4784.         je      ins_is_room            ; continue if there's room, ie last
  4785.                                        ; char is zero
  4786.         cmp     byte ptr cs:[si],0FFh
  4787.         je      ins_is_room            ; also continue if last char is 0FFh
  4788.         pop     si                     ; else, tidy up the stack...
  4789.         ret                            ; ...and return.
  4790.  
  4791. ins_is_room:
  4792.  
  4793.         push    bx
  4794.         push    ax
  4795.         mov     bx,word ptr cs:dcpointer
  4796.  
  4797. shift_cont:
  4798.  
  4799.         mov     ah,byte ptr cs:[si]    ; get character from dcbuffer
  4800.         mov     byte ptr cs:[si+1],ah  ; shift it right by one char
  4801.         cmp     si,bx                  ; are we done shifting?
  4802.         je      dun_shifting
  4803.         dec     si
  4804.         jmp     short shift_cont
  4805.  
  4806. dun_shifting:
  4807.  
  4808.         mov     byte ptr cs:[si],0FFh  ; put blank in newly-created space
  4809.         pop     ax
  4810.         pop     bx
  4811.         pop     si
  4812.         ret                            ; End of dcbuffer insert routine
  4813.  
  4814. ins_normal:
  4815.  
  4816.         cmp    byte ptr cs:ins_mode,0  ; is mode currently overwrite?
  4817.         jne    ins01                   ; no, so change to overwrite
  4818.         mov    byte ptr cs:ins_mode,1  ; change to insert mode
  4819.         jmp    short ins02
  4820.  
  4821. ins01:
  4822.  
  4823.         mov    byte ptr cs:ins_mode,0  ; set mode to overwrite
  4824. ins02:
  4825.  
  4826.         call  update_csize             ; update cursor size to reflect mode
  4827.         ret
  4828. inskey        endp
  4829. ;
  4830. update_csize   proc
  4831.  
  4832.         cmp    byte ptr cs:ins_mode,0   ; is mode set to overwrite?
  4833.         jne    ins_csize                ; no, so set csize to insert size
  4834.         call   small_cursor             ; yes, so make small cursor
  4835.         jmp    short ins2
  4836.  
  4837. ins_csize:
  4838.  
  4839.         call   big_cursor
  4840.  
  4841. ins2:
  4842.  
  4843.         ret
  4844. update_csize   endp
  4845. ;
  4846. big_cursor     proc                    ; Add 2 scan lines to crsr height
  4847.  
  4848.         cmp    byte ptr cs:[csize],2   ; is cursor already big?
  4849.         je     is_big                  ; yes, so do nothing
  4850.         push_m <ax,bx,cx,dx,di,si>
  4851.         mov    ah,3
  4852.         call   get_vpage
  4853.         bios_video                         ; returns height of cursor in cl
  4854.         dec    ch
  4855.         dec    ch                          ; increase the height of the cursor
  4856.                                            ; by 2 scan lines.
  4857.         mov    ah,1
  4858.         call   get_vpage
  4859.         bios_video                         ; and set new cursor height
  4860.         mov    byte ptr cs:[csize],2       ; set status to say crsr is big
  4861.         pop_m  <si,di,dx,cx,bx,ax>
  4862.  
  4863. is_big:
  4864.  
  4865.         ret
  4866.  
  4867. big_cursor     endp
  4868. ;
  4869. small_cursor     proc                  ; Shrink crsr height by 2 scan lines
  4870.  
  4871.         cmp    byte ptr cs:[csize],1   ; is cursor already small?
  4872.         je     is_small                ; yes, then do nothing
  4873.         push_m <si,di,ax,bx,cx,dx>
  4874.         mov    ah,3
  4875.         call   get_vpage
  4876.         bios_video                         ; returns start line in ch
  4877.         inc    ch
  4878.         inc    ch                          ; shrink the height of the cursor
  4879.                                            ; by 2 scan lines.
  4880.         mov    ah,1
  4881.         call   get_vpage
  4882.         bios_video                         ; and set new cursor height
  4883.         mov    byte ptr cs:[csize],1       ; set status to say crsr is small
  4884.         pop_m  <dx,cx,bx,ax,di,si>
  4885.  
  4886. is_small:
  4887.  
  4888.         ret
  4889.  
  4890. small_cursor     endp
  4891. ;
  4892. do_prf proc                            ; User pressed prf trigger key for the
  4893.                                        ; first time, while entering a command.
  4894.                                        ; Search the
  4895.                                        ; stored commands for matches with
  4896.                                        ; however many characters the user
  4897.                                        ; has typed so far.
  4898.  
  4899.                                        ; If a match is found, update display.
  4900.  
  4901.                                        ; The order of search is to start at
  4902.                                        ; cmdpnt, which is where the next cmd
  4903.                                        ; to be entered would be stored. We
  4904.                                        ; then work backwards,towards cmdtop,
  4905.                                        ; getting the most recent commands.  We
  4906.                                        ; wrap from cmdtop to cmdbot once, and
  4907.                                        ; searching stops when cmdpnt is
  4908.                                        ; reached for the second time.
  4909.  
  4910.         push   bx
  4911.         call   bublcnt                 ; bx <-- no of chars typed by user
  4912.         cmp    bx,0                    ; has user typed anything yet?
  4913.         pop    bx
  4914.         je     no_prf                  ; no, so do nothing
  4915.  
  4916.         cmp    byte ptr cs:prf_multi,0 ; is this another press of the prf key
  4917.                                        ; straight after the last one?
  4918.         je     no_multi                ; no, so carry on
  4919.  
  4920.         push_all                       ; prepare for a multiple prf
  4921.         mov    si,word ptr cs:prf_pos  ; restore si from last prf proc
  4922.         mov    bp,0                    ; go round the whole stack again
  4923.                                        ; Actually, there's no reason to go
  4924.                                        ; all the way round again.  We SHOULD
  4925.                                        ; save bp the first time round, and
  4926.                                        ; restore it for multiple prf presses.
  4927.         jmp    short prf2
  4928.  
  4929. no_multi:
  4930.  
  4931.         push_all
  4932.         mov    si,word ptr cs:cmdpnt   ; posn where next cmd will be stored
  4933.         mov    bp,0
  4934.  
  4935. prf2:
  4936.  
  4937.         call   cmdbefr                 ; SI now points to the first char of
  4938.                                        ; the latest command.
  4939.         cmp    bp,0                    ; After calling cmdbefr for
  4940.                                        ; the FIRST TIME, save SI in BP.
  4941.         jne    prf1
  4942.         mov    bp,si
  4943.         jmp    short prf3
  4944.  
  4945. prf1:
  4946.  
  4947.         cmp    bp,si                   ; On all but first time round, check
  4948.         jne    prf3                    ; if bp=si.  If so, we've come full
  4949.                                        ; circle and have checked all commands.
  4950.         jmp    prf_done
  4951.  
  4952. prf3:
  4953.  
  4954.         mov    di,offset cs:bublbeg    ; point to first word of user's command
  4955.         call   prf_compare             ; compare word at [si] with one at [di]
  4956.         cmp    byte ptr cs:prf_cflag,1 ; was a match found?
  4957.         je     prf_match               ; yes, so update display
  4958.         jmp    short prf2              ; No match.  Get next cmd from stack
  4959.                                        ; and try again.
  4960. prf_match:
  4961.  
  4962.         mov    word ptr cs:prf_pos,si  ; Match found. Save address of start of
  4963.                                        ; matching command...
  4964.         call   prf_disp                ; ...and put it on screen
  4965.  
  4966. prf_done:
  4967.  
  4968.         mov    byte ptr cs:prf_multi,1 ; set flag.  When any key apart from
  4969.                                        ; the prf trigger is pressed, this flag
  4970.                                        ; gets cleared, so if it is still set
  4971.                                        ; on entry to do_prf next time, then
  4972.                                        ; we have a multiple prf request and
  4973.                                        ; look for the next match, rather than
  4974.                                        ; starting from cmdpnt again.
  4975.  
  4976.  
  4977.         pop_all
  4978.  
  4979. no_prf:
  4980.  
  4981.         ret
  4982. do_prf  endp
  4983. ;
  4984. prf_compare proc
  4985.  
  4986.                                        ; This proc compares the characters
  4987.                                        ; in the user's partly-typed command
  4988.                                        ; with the same number of characters
  4989.                                        ; in the command at [si], which is one
  4990.                                        ; in the dosedit buffer. Sets prf_cflag
  4991.                                        ; if match found.
  4992.  
  4993.                                        ; The chars at [si] is in the dosedit
  4994.                                        ; command buffer, and may wrap around.
  4995.                                        ; Therefore, we can't use a repe cmpsb
  4996.                                        ; for the comparison.  Instead, we keep
  4997.                                        ; calling cmdinc, which increments si
  4998.                                        ; and will wrap from bottom to top of
  4999.                                        ; the command stack if necessary.
  5000.  
  5001.         mov    byte ptr cs:prf_cflag,0      ; clear flag
  5002.         push_m <ax,si,di,bx>
  5003.  
  5004.         call   bublcnt                 ; bx <-- no of chars typed by user.
  5005.                                        ; Used by this proc to count how many
  5006.                                        ; comparisons we need to make.
  5007.  
  5008.         cmp    byte ptr cs:prf_multi,1 ; Is this a multiple prf press?
  5009.         jne    prf_c2                  ; No, so carry on
  5010.         mov    bx,word ptr cs:prf_bx   ; It is a multiple press, so use the
  5011.         jmp    prf_c4                  ; value of bublcnt from last time.
  5012.                                        ; This way, we only look for matches
  5013.                                        ; in the part of the string that the
  5014.                                        ; user actually typed, and not in the
  5015.                                        ; part that prf added last time.
  5016. prf_c2:
  5017.  
  5018.         mov    word ptr cs:prf_bx,bx   ; First time round, save bublcnt value.
  5019.  
  5020. prf_c4:
  5021.  
  5022.         mov    ah,byte ptr cs:[di]     ; get a byte from user's string
  5023.         mov    al,byte ptr cs:[si]     ; and one from command stack
  5024.         or     ax,0010000000100000b    ; force chars to lower case
  5025.         cmp    bx,0                    ; have we compared enough characters?
  5026.         je     prf_c1                  ; yes, then match was found
  5027.         cmp    ah,al                   ; are they equal?
  5028.         jne    prf_c3                  ; no match. Exit and leave flag clear.
  5029.         inc    di                      ; chars are equal, so go get next ones
  5030.         call   cmdinc                  ; inc si, but watch for wrap
  5031.         dec    bx                      ; count no of comparisons made
  5032.         jmp    short prf_c4            ; and off we go again
  5033.  
  5034. prf_c1:
  5035.  
  5036.         mov    byte ptr cs:prf_cflag,1 ; indicate that match was found
  5037.  
  5038. prf_c3:
  5039.  
  5040.         pop_m  <bx,di,si,ax>
  5041.         ret
  5042. prf_compare endp
  5043. ;
  5044. prf_disp proc                         ; If do_prf finds a match, then this
  5045.                                       ; proc is called.  It is almost
  5046.                                       ; identical to cursup, which is called
  5047.                                       ; by the dosedit routine when the user
  5048.                                       ; presses up-arrow to retrieve the
  5049.                                       ; previous command.  However, address
  5050.                                       ; of the cmd to be retrieved is taken
  5051.                                       ; from prf_pos rather than from a call
  5052.                                       ; to cmdprev.
  5053.  
  5054.         push_all
  5055.         call   delline                ;delete what's in the buffer now
  5056.         mov    si,word ptr cs:prf_pos ; get address of matching command that
  5057.                                       ; do_prf found.
  5058.  
  5059. prf_disp1:
  5060.  
  5061.         call   cmdotrg                ;get a character from the last command
  5062.         cmp    al,0                   ;is it the termination char?
  5063.         jz     prf_disp2              ;yes
  5064.         call   putin                  ;no, place the char in the bubble
  5065.         jmp    prf_disp1
  5066.  
  5067. prf_disp2:
  5068.  
  5069.         call   noundel                ;mark nothing undeletable
  5070.         call   setcol                 ;update start display column number
  5071.  
  5072.         pop_all
  5073.         ret                           ; Pointers all set.  The actual update
  5074.                                       ; to the display will happen when the
  5075.                                       ; update proc is called.
  5076.  
  5077. prf_disp endp
  5078. ;
  5079. it_proc proc                           ; Called when user presses the 'it'
  5080.                                        ; key, which is currently F8.
  5081.                                        ; Retrieves all but the first word of
  5082.                                        ; the previous command, and sticks it
  5083.                                        ; on the end of the part-typed command.
  5084.                                        ; Unlike prf, this proc doesn't check
  5085.                                        ; that the first words match.
  5086.  
  5087.  
  5088.         call    cmdprev                 ;SI -> previous command
  5089.         push    si
  5090.  
  5091. it2:
  5092.  
  5093.         cmp     byte ptr cs:[si],SPACE
  5094.         je      it1
  5095.         inc     si
  5096.         jmp     short it2
  5097.  
  5098. it1:
  5099.  
  5100.         inc     si                      ; SI now points to the first char
  5101.                                         ; after the space in the previous
  5102.                                         ; command.  This is where characters
  5103.                                         ; will be retrieved from.
  5104.         push    ax
  5105.         push    bx
  5106.         mov     ax,word ptr cs:cursorb
  5107.         mov     bx,offset cs:bublbeg
  5108.         sub     ax,bx                   ; AX = number of chars left of cursor
  5109.         push    ax
  5110.         call    delline                 ; delete whats in the buffer now. Can't
  5111.                                         ; do this before calculating ax, cos
  5112.                                         ; it destroys cursorb.
  5113.         pop     ax
  5114.  
  5115.         cmp     byte ptr cs:it_multi,1  ; if multiple F8 in operation,
  5116.         jne     it6                     ; then use old cursorb
  5117.         push    bx
  5118.         mov     bx,word ptr cs:it_save
  5119.         mov     word ptr cs:cursorb,bx
  5120.         pop     bx
  5121.         jmp     short it5
  5122.  
  5123. it6:
  5124.  
  5125.         add     word ptr cs:cursorb,ax  ; Move destination for the incoming
  5126.                                         ; characters past the ones already
  5127.                                         ; typed.
  5128.         mov     bx,word ptr cs:cursorb
  5129.         mov     word ptr cs:it_save,bx  ; save cursorb, to use if multiple
  5130.                                         ; presses of F8 detected.
  5131. it5:
  5132.         pop     bx
  5133.         pop     ax
  5134. ;
  5135.         push    si
  5136.         mov     si,word ptr cs:cursorb
  5137.         cmp     byte ptr cs:[si-1],SPACE ; Did user leave a space
  5138.                                          ; before pressing the IT key?
  5139.         pop     si
  5140.         je      it3                      ; Yes, then we're ok
  5141.  
  5142.         push    si
  5143.         mov     si,word ptr cs:cursorb
  5144.         mov     byte ptr cs:[si],SPACE   ; Else force a space into string
  5145.         inc     si
  5146.         mov     word ptr cs:cursorb,si
  5147.         pop     si
  5148.  
  5149.                                         ;Now carry on like a normal cursup.
  5150. it3:
  5151.  
  5152.         call    cmdotrg                 ;get a character from the last command
  5153.         cmp     al,0                    ;is it the termination char?
  5154.         jz      it4                     ;yes
  5155.         call    putin                   ;no, place the char in the bubble
  5156.         jmp     it3
  5157.  
  5158. it4:
  5159.         call    noundel                 ;mark nothing undeletable
  5160.         call    setcol                  ;update start display column number
  5161.         pop     si
  5162.         mov     byte ptr cs:it_multi,1  ; set flag, which is cleared after
  5163.                                         ; getc is called.  If it's still set
  5164.                                         ; on entry to it_proc, then multiple
  5165.                                         ; presses of F8 are occurring.
  5166.         ret
  5167. it_proc endp
  5168. ;
  5169. f1proc  proc                            ; Do nothing if F1 pressed
  5170.         ret
  5171.  
  5172. f1proc  endp
  5173. ;
  5174. pg_up_proc     proc                     ;PgUp moves pointers to start of
  5175.                                         ;command buffer.
  5176.  
  5177.         push   si
  5178.         push   bp
  5179.  
  5180. pgup_top:
  5181.  
  5182.         call   cmdprev                  ; get previous command into si
  5183.         mov    bp,si                    ; and save it in bp
  5184.         call   cmdprev                  ; get previous command again
  5185.         cmp    si,bp                    ; has value changed?
  5186.         je     pgup_done                ; no, so we're at the top
  5187.         jmp    short pgup_top           ; not there yet
  5188.  
  5189. pgup_done:
  5190.  
  5191.         pop    bp
  5192.         pop    si
  5193.         ret
  5194.  
  5195.  
  5196.         ret
  5197. pg_up_proc     endp
  5198. ;
  5199. pg_dn_proc     proc                     ;PgDn moves pointers to end of
  5200.                                         ;command buffer.
  5201.  
  5202.         push   si
  5203.         push   bp
  5204.  
  5205. pgdn_top:
  5206.  
  5207.         call   cmdnext                  ; get next command into si
  5208.         mov    bp,si                    ; and save it in bp
  5209.         call   cmdnext                  ; get next command again
  5210.         cmp    si,bp                    ; has value changed?
  5211.         je     pgdn_done                ; no, so we're at the end
  5212.         jmp    short pgdn_top           ; not there yet
  5213.  
  5214. pgdn_done:
  5215.  
  5216.         pop    bp
  5217.         pop    si
  5218.         ret
  5219. pg_dn_proc     endp
  5220. ;
  5221. also_proc      proc                     ; The F10 key is the 'also' key.
  5222.                                         ; Brings back the first word of the
  5223.                                         ; previous command, up to & including
  5224.                                         ; the first space character.
  5225.  
  5226.  
  5227.         call   delline                ;delete what's in the buffer now
  5228.         call   cmdprev                ;si -> previous command
  5229.         mov    al,0                   ; don't let al be 20h on entry
  5230.  
  5231. also1:
  5232.  
  5233.         cmp    al,SPACE               ; Was last char a space?
  5234.         jz     also2                  ; yes, then we have enough characters
  5235.         call   cmdotrg                ;get a character from the last command
  5236.         cmp    al,0                   ;is it the termination char?
  5237.         jz     also2                  ;yes
  5238.         call   putin                  ;no, place the char in the bubble
  5239.         jmp    also1
  5240.  
  5241. also2:
  5242.  
  5243.         call   noundel                ;mark nothing undeletable
  5244.         call   setcol                 ;update start display column number
  5245.         ret
  5246. also_proc      endp
  5247. ;
  5248.                                       ; Now, a procedure to display a 
  5249.                                       ; string, using a screen 
  5250.                                       ; attribute that can be specified 
  5251.                                       ; by the caller.  On entry, SI 
  5252.                                       ; must point to the offset of the 
  5253.                                       ; string, which must be in the 
  5254.                                       ; CODE SEGMENT. BL should be set 
  5255.                                       ; to the attribute required.  
  5256.                                       ; Strings of longer than 80 
  5257.                                       ; chars should have a crlf at 
  5258.                                       ; the end of each line. 
  5259.                                       ;
  5260.                                       ; Strings should end in a cr,lf so
  5261.                                       ; that the end of this routine can
  5262.                                       ; display a space in white after
  5263.                                       ; displaying the string. If this
  5264.                                       ; is not done, the default colour
  5265.                                       ; is not always re-set properly.
  5266.                                       ;
  5267.                                       ; Always terminates on ascii 0.
  5268.                                       ; Won't terminate on $.
  5269.  
  5270. disp_str_colour        proc
  5271.  
  5272.  
  5273.         call   get_vpage              ; get vpage into bh
  5274.  
  5275.         mov   cx,1                    ; write each char once
  5276.         mov   ax,cs                   ; the string must be in cs, but...
  5277.         cmp   byte ptr cs:echo_flag,1 ; if flag is set, string is in ds
  5278.         jne   all_ok
  5279.         mov   ax,ds
  5280.  
  5281. all_ok:
  5282.  
  5283.         mov   ds,ax
  5284.         cld
  5285.  
  5286. again:
  5287.  
  5288.         lodsb                         ; get char into al
  5289.         cmp   al,0
  5290.         je    done
  5291.         cmp   al,CR 
  5292.         jne   try1
  5293.         disp_ch CR 
  5294.         jmp   short again
  5295.  
  5296. try1:
  5297.  
  5298.         cmp   al,LF
  5299.         jne   try2
  5300.         disp_ch LF
  5301.         jmp   short again
  5302.  
  5303. try2:
  5304.  
  5305.         mov   ah,09h
  5306.         bios_video                    ; disp char
  5307.         push_all
  5308.         mov   ah,3
  5309.         bios_video                    ; get crsr pos
  5310.         inc   dl
  5311.         ;
  5312.         mov   ah,2                    ; set new crsr pos
  5313.         bios_video
  5314.         pop_all
  5315.         ;
  5316.         jmp   again
  5317.  
  5318. done:
  5319.  
  5320.                                       ; display a space in white, to reset
  5321.                                       ; default colour. Should really check
  5322.                                       ; what default colour was, and save it.
  5323.  
  5324.         mov al,SPACE
  5325.         mov bl,WHITE
  5326.         mov ah,9
  5327.         mov cx,1
  5328.         bios_video
  5329.         ret
  5330. disp_str_colour        endp
  5331. ;
  5332.         if     debug                  ; Assemble only if DEBUG equate is true.
  5333. hw_blip proc                          ; Make a bleep.  This proc is hardware
  5334.                                       ; coded to aviod DOS and BIOS calls.
  5335.  
  5336.         push   ax
  5337.         push   bx
  5338.         push   cx
  5339.         push   dx
  5340.         push   di
  5341.         mov    di,2500                ; frequency in Hz
  5342.         mov    bx,15                  ; duration in 1/100 secs
  5343.         mov    al,0b6h
  5344.         out    43h,al
  5345.         mov    dx,14h
  5346.         mov    ax,4f38h
  5347.         div    di
  5348.         out    42h,al
  5349.         mov    al,ah
  5350.         out    42h,al
  5351.         in     al,61h
  5352.         mov    ah,al
  5353.         or     al,3
  5354.         out    61h,al
  5355.  
  5356. blip1:
  5357.  
  5358.         mov    cx,2801
  5359.  
  5360. spkr_on:
  5361.  
  5362.         loop   spkr_on
  5363.         dec    bx
  5364.         jnz    blip1
  5365.         mov    al,ah
  5366.         out    61h,al
  5367.         pop    di
  5368.         pop    dx
  5369.         pop    cx
  5370.         pop    bx
  5371.         pop    ax
  5372.         ret
  5373. hw_blip endp
  5374.         endif
  5375. ;
  5376.         if     debug
  5377. printregs      proc                     ; Dump the registers to LPT1.
  5378.  
  5379.         push_all
  5380.         push    ax
  5381.         push    si
  5382.         push    bp
  5383.  
  5384.         mov     si,offset axreg
  5385.         call    binasc
  5386.  
  5387.         mov     ax,bx
  5388.         mov     si,offset bxreg
  5389.         call    binasc
  5390.  
  5391.         mov     ax,cx
  5392.         mov     si,offset cxreg
  5393.         call    binasc
  5394.  
  5395.         mov     ax,dx
  5396.         mov     si,offset dxreg
  5397.         call    binasc
  5398.  
  5399.         mov     ax,ds
  5400.         mov     si,offset dsreg
  5401.         call    binasc
  5402.  
  5403.         mov     ax,es
  5404.         mov     si,offset esreg
  5405.         call    binasc
  5406.  
  5407.         mov     ax,bp
  5408.         mov     si,offset bpreg
  5409.         call    binasc
  5410.  
  5411.         mov     ax,di
  5412.         mov     si,offset direg
  5413.         call    binasc
  5414.  
  5415.         pop     bp
  5416.         pop     si
  5417.         push    si
  5418.         push    bp
  5419.         mov     ax,si
  5420.         mov     si,offset sireg
  5421.         call    binasc
  5422.  
  5423.         mov     si,offset prtstr        ;String to output
  5424.         pop     bp
  5425.         push    dx                      ;Save DX
  5426.         xor     dx,dx                   ;Printer LPT1:
  5427.  
  5428. prloop:
  5429.  
  5430.         mov     ah,0                    ;Print string
  5431.         mov     al,cs:[si]
  5432.         cmp     al,0
  5433.         je      prdone
  5434.         int     17h
  5435.         inc     si
  5436.         jmp     prloop
  5437.  
  5438. prdone:
  5439.  
  5440.         pop     dx
  5441.         pop     si
  5442.         pop     ax
  5443.         pop_all
  5444.         ret
  5445. printregs       endp
  5446.         endif
  5447. ;
  5448.         if      debug
  5449. binasc  proc    near                    ;Convert AX to ASCII and put at CS:SI
  5450.         push    ax
  5451.         mov     al,ah
  5452.         call    conval
  5453.         pop     ax
  5454.  
  5455. conval:
  5456.  
  5457.         push    ax
  5458.         push    cx
  5459.         mov     cl,4
  5460.         ror     al,cl
  5461.         pop     cx
  5462.         and     al,0Fh
  5463.         add     al,30h
  5464.         cmp     al,39h
  5465.         jbe     bin1
  5466.         add     al,7
  5467.  
  5468. bin1:
  5469.  
  5470.         mov     cs:[si],al
  5471.         inc     si
  5472.         pop     ax
  5473.         and     al,0Fh
  5474.         add     al,30h
  5475.         cmp     al,39h
  5476.         jbe     bin2
  5477.         add     al,7
  5478. bin2:
  5479.  
  5480.         mov     cs:[si],al
  5481.         inc     si
  5482.         ret
  5483. binasc  endp
  5484.         endif
  5485. ;
  5486. disk_error_msg      proc              ; display an error msg if I/O fails
  5487.         push_all
  5488.  
  5489.         mov   si,offset cs:disk_msg   ; display error message
  5490.         mov   bl,byte ptr cs:colour
  5491.         call  disp_str_colour
  5492.  
  5493.         pop_all
  5494.         ret
  5495. disk_error_msg      endp
  5496. ;
  5497. invalid_letter      proc           ; error message in reply to bad ALIAS cmd
  5498.         push_all
  5499.         mov   si,offset cs:inv_letter
  5500.         mov   bl,byte ptr cs:colour
  5501.         call  disp_str_colour
  5502.         pop_all
  5503.         ret
  5504. invalid_letter      endp
  5505. ;
  5506. syntax_error        proc 
  5507.         push_all
  5508.         mov   si,offset cs:syn_error
  5509.         mov   bl,byte ptr cs:colour
  5510.         call  disp_str_colour
  5511.         pop_all
  5512.         ret
  5513. syntax_error        endp
  5514. ;
  5515. ab_zap:                               ; de-install program
  5516.  
  5517.         call  are_you_sure            ; do we really want to zap?
  5518.         cmp   byte ptr cs:confirm,1
  5519.         je    zap_sure                ; carry on if user is sure
  5520.         jmp   bye                     ; else abandon
  5521.  
  5522. zap_sure:
  5523.  
  5524.         push_m <ax,ds,dx>
  5525.         mov   ah,25h                  ; replace old int 21h vector that was
  5526.         mov   al,21h                  ; overwritten by Alias
  5527.         mov   dx,cs:old_vec_seg
  5528.         mov   ds,dx
  5529.         mov   dx,cs:old_vec_off
  5530.         int   21h
  5531.         pop_m <dx,ds,ax>
  5532.  
  5533.         push  bp
  5534.         mov   bp,dx
  5535.         mov   byte ptr ds:[bp+1],0    ; set length to 0 to stop ALIAS Z cmd
  5536.                                       ; being executed by DOS
  5537.         mov   byte ptr ds:[bp+2],CR   ; put c/r terminator in buffer too
  5538.         pop   bp                      ; The ALIAS Z cmd can't be recalled 
  5539.                                       ; with F3, as the routine that restores
  5540.                                       ; the char bufer doesn't get called now
  5541.                                       ; that alias is no longer resident.
  5542.         ;
  5543.         push_m <es,ax,bx,cx,dx>
  5544.         mov   ah,35h                  ; int 2eh vector holds start of MCB's
  5545.         mov   al,2eh 
  5546.         int   21h                     ; int 2eh vector --> es:bx
  5547.         mov   bx,es
  5548.         dec   bx                      ; 1st MCB now at bx:0
  5549.         mov   es,bx
  5550.  
  5551. zap2:
  5552.  
  5553.         mov   es,bx
  5554.         mov   ax,word ptr es:3        ; size of block controlled by this MCB
  5555.         mov   cl,es:0                 ; marker at start of MCB
  5556.         mov   dx,word ptr es:1        ; segment that controls this block
  5557.         cmp   dx,cs:new_vec_seg       ; is block owned by alias.com?
  5558.         jne   zap1
  5559.         mov   word ptr es:1,0         ; free the block if owned by alias.com
  5560.  
  5561. zap1:
  5562.  
  5563.         cmp   cl,5ah                  ; if marker = 'Z' then no more MCB's
  5564.         je    zap3
  5565.         add   bx,ax                   ; else point to next MCB
  5566.         inc   bx
  5567.         jmp   short zap2              ; and do it all again
  5568.  
  5569. zap3:
  5570.  
  5571.         pop_m <dx,cx,bx,ax,es>
  5572.  
  5573.         push_all
  5574.         mov   bl,cs:colour            ; display de-installation message
  5575.         mov   si,offset cs:zap_msg
  5576.         call  disp_str_colour
  5577.         pop_all
  5578.  
  5579.         call  restore_flags
  5580.         iret                          ; finish. Alias now de-installed.
  5581. ;
  5582. ; -----------------------------------------------------------------------
  5583. ;                          D A T A    A R E A
  5584. ; -----------------------------------------------------------------------
  5585. ;
  5586. exec:   db 0eah                ; far jmp instruction
  5587.     old_vec_off dw 0           ; existing int 21h vector before installation
  5588.     old_vec_seg dw 0
  5589.     new_vec_off dw 0           ; new int 21h vector installed by this prog
  5590.     new_vec_seg dw 0
  5591.     command_cs  dw 0           ; the address within command.com that ...
  5592.     command_ip  dw 0           ; ... called this program
  5593.         prf_pos dw 0           ; record pos where command match starts
  5594.       prf_cflag db 0           ; used by prf_compare proc
  5595.       prf_multi db 0           ; detects multiple presses of prf_trigger key
  5596.        it_multi db 0           ; detects multiple it_key presses
  5597.         it_save dw 0           ; save cursorb for multiple F8 operations.
  5598.          prf_bx dw 0           ; used by multi prf
  5599.           csize db 1           ; 1 = small, 2 = big cursor size
  5600.     def_fn_msg  db 'Default data file is ',EOM
  5601.     defdir_hdr  db 'Z:\'       ; Def_dir header.Drive letter to be filled in.
  5602.     def_dir     db 66 dup(0)   ; Note the dir where ALIAS.DAT was loaded from.
  5603.     default_fn  db 'ALIAS.DAT',0  ; default filename
  5604.     match       db 'alias '           ; command looked for
  5605.    match_u_case db 'ALIAS '           ; check upper case too
  5606.       count_msg db CR,LF,'Aliases defined: '  ; used by ALIAS I.
  5607.      count_msg1 db '00/'                      ; 00's filled by count_aliases
  5608.      count_msg2 db '00',CR,LF,EOM
  5609.     buffer      db LHS_LEN dup(0)   ; temporary store for user's string
  5610.     buffer2     db LHS_LEN dup(0)   ; used by D and L commands for searching
  5611.     param_buff  db 129 dup(0)       ; save chars to be re-added after aliasing
  5612.     nest_flag   db 0                ; gets set if an expansion takes place
  5613.     match_pos   dw 0                ; offset into ab_table where match starts
  5614.     match_len   db 0                ; length of match string
  5615.     arg_end     db 0
  5616.     str_end     db 0
  5617.     spare       dw 0           ; position of spare entry in table
  5618.     temp1       dw 0           ; temporary storage to avoid using stack
  5619.     temp2       dw 0
  5620.     temp3       dw 0
  5621.    sort_counter db 0           ; used by sorting routine
  5622.    sort_pointer dw 0           ; ditto
  5623.     swap_flag   db 0           ; ditto
  5624.    sort_entries db 0           ; ditto
  5625.     confirm     db 0           ; set/cleared by are_you_sure proc
  5626.     sure_msg    db CR,LF,'Are you sure? (Y/N) ',EOM
  5627.     press_msg   db '>> Press any key to continue <<',EOM
  5628.     kb_str_len  db 0           ; save length of string got by func 0Ah
  5629.     kb_str_ch1  db 0           ; save 1st char of str before setting to cr
  5630.     do_kb_str   db 0           ; do we want to put back str? 0 = no
  5631.     echo_temp   db 0           ; used by echo proc
  5632.     echo_flag   db 0           ; used by echo and disp_str_colour procs
  5633.     list_temp   db 0           ; used by list proc
  5634.     list_temp2  dw 0           ; used by list proc
  5635.     list_count  db 0           ; counter so LIST can pause when screen full
  5636.       page_len  db 0           ; used in LIST proc
  5637.     old_col     db 0           ; save current colour during ALIAS C command
  5638.     zap_msg     db CR,LF,'ALIAS de-installed.',CR,LF,EOM
  5639.     multi_line_outstanding db 0  ; is part of multi-line remaining?  0 = no
  5640.     multi_start dw 0
  5641.     multi_len   db 0
  5642.     save_flags  dw 0             ; save the flags register here
  5643.     error_msg   db CR,LF,'Error - type ALIAS ? for help.',CR,LF,EOM
  5644.     err_nfound  db CR,LF,'No such alias.',EOM
  5645.     exist_msg   db CR,LF,'Specified alias already exists.',CR,LF,EOM
  5646.     inv_letter  db CR,LF,'Invalid command.  Type ALIAS ? for help.',CR,LF,EOM
  5647.     syn_error   db CR,LF,'Syntax error.  Type ALIAS ? for help.',EOM
  5648.     disk_msg    db CR,LF,'Disk error. Possibly File Not Found,'
  5649.                 db ' or Disk Full.',CR,LF,EOM
  5650.      no_fit_msg db CR,LF,'Error - string too long.',CR,LF,EOM
  5651.       star_flag db 0
  5652.     table_full_msg db CR,LF,'No more space in Alias table.',CR,LF,EOM
  5653.     left_sq_br  db '[',0         ; for use if show mode is on
  5654.     rght_sq_br  db ']',0
  5655.     command_letter db 0          ; single-char ALIAS command store
  5656.     version     db CR,LF
  5657.                 db 'ALIAS v',VERS,CR,LF
  5658. ife online_help
  5659.                 db '(Short version)',CR,LF
  5660. endif
  5661.                 db EOM
  5662.     colour_msg  db CR,'Press SPACE to see colours, RETURN to select'
  5663.                 db ' or ESC to quit.',EOM
  5664.     msg_show    db 'Expanded aliases will echo on screen.',CR,LF,EOM
  5665.     msg_hide    db 'Expanded aliases will not echo.',CR,LF,EOM
  5666.     msg_off     db 'Aliases are turned off.',CR,LF,EOM
  5667.     msg_prompt  db 'Aliases from DOS prompt only.',CR,LF,EOM
  5668.     msg_global  db 'Global expansion set.',CR,LF,EOM
  5669.  
  5670. if debug            ; This data used by printregs proc
  5671.  
  5672.         prtstr  db 'AX-'
  5673.          axreg  db '----'
  5674.                 db ' BX-'
  5675.          bxreg  db '----'
  5676.                 db ' CX-'
  5677.          cxreg  db '----'
  5678.                 db ' DX-'
  5679.          dxreg  db '----'
  5680.                 db ' DS-'
  5681.          dsreg  db '----'
  5682.                 db ' ES-'
  5683.          esreg  db '----'
  5684.                 db ' BP-'
  5685.          bpreg  db '----'
  5686.                 db ' DI-'
  5687.          direg  db '----' 
  5688.                 db ' SI-'
  5689.          sireg  db '----'
  5690.                 db CR,LF,0
  5691. endif
  5692.  
  5693. if online_help                          ; Only assemble online help if EQUate
  5694.                                         ; set.  Omitting help saves memory.
  5695.  
  5696. help_text db LF,CR
  5697. db '╔═══════╤═════════════════════════════════════════════════════════╤════════════╗',CR,LF
  5698. db '║ v',VERS,' │   ALIAS Help Screen (Read ALIAS.HLP for more details)   │  (c)RJS ''89║',CR,LF
  5699. db '╟───────┴─────────────────────────────────────────────────────────┴────────────╢',CR,LF
  5700. db '║ Make DA an alias for DIR A:                ALIAS A DA DIR A:                 ║',CR,LF
  5701. db '║ Delete alias DA                            ALIAS D DA                        ║',CR,LF
  5702. db '║ List aliases                               ALIAS L aliasname                 ║',CR,LF
  5703. db '║ Read aliases from file (default ALIAS.DAT) ALIAS R filename                  ║',CR,LF
  5704. db '║ Write aliases to file  (default ALIAS.DAT) ALIAS W filename                  ║',CR,LF
  5705. db '╟────────────────────────────────────────────────────┬─────────────────────────╢',CR,LF
  5706. db '║ Flush all aliases from memory              ALIAS F │Recall commands        ',24,' ║',CR,LF
  5707. db '║ Aliases valid from prompt only (default)   ALIAS P │Separator              & ║',CR,LF
  5708. db '║ Aliases valid globally                     ALIAS G │Override alias         ~ ║',CR,LF
  5709. db '║ Aliases not valid (turn them off)          ALIAS N │Beg/End of cmnds  PgUp/Dn║',CR,LF
  5710. db '║ Show aliases on screen before expanding    ALIAS S │Quit circular alias   ESC║',CR,LF
  5711. db '║ Hide aliases (don''t show them)             ALIAS H ├─────────────────────────╢',CR,LF
  5712. db '║ Display status and setup info              ALIAS I │WordRt/Lt   Ctrl ',26,'/Ctrl ',27,'║',CR,LF
  5713. db '║ Change colour used by ALIAS program        ALIAS C │BegLn/EndLn      Home/End║',CR,LF
  5714. db '║ De-install ALIAS                           ALIAS Z │DelWrdL/R    Ctrl-W/Alt-W║',CR,LF
  5715. db '║ Display this help screen                   ALIAS ? │DBOL/DEOL    Ctrl-L/Alt-L║',CR,LF
  5716. db '║ List contents of command recall buffer     ALIAS B │Undelete           Ctrl-U║',CR,LF
  5717. db '╟1─────┬2──────┬3───────┬4──────┬5──────┬6──────┬7───┴──┬8───────┬9─────┬10────╢',CR,LF
  5718. db '║      │       │        │       │       │       │       │Complete│  It  │ Also ║',CR,LF
  5719. db '╚══════╧═══════╧════════╧═══════╧═══════╧═══════╧═══════╧════════╧══════╧══════╝',CR,LF
  5720. db EOM
  5721.  
  5722. else                                ; If no online help required, inform user.
  5723.  
  5724. help_text db LF,CR,' No online help available in short',CR,LF
  5725.           db ' version. Read ALIAS.HLP file for help.',CR,LF,EOM
  5726. endif
  5727.  
  5728.                                  ; These 5 bytes get saved at the top of the
  5729.                                  ; data file.
  5730. table_top:
  5731.  
  5732.        ins_mode db 0             ; 0 = overwrite mode, 1 = insert mode
  5733.  
  5734.     ab_status   db 1             ; alias status. 1 = on, 0  = off. This too 
  5735.                                  ; is saved with table.
  5736.     expand_from db 0             ; 0 = dos prompt (default), 1 = global. This
  5737.                                  ; gets saved with table-don't move this db.
  5738.     colour      db 7             ; default colour. changed with C command,
  5739.                                  ; and gets saved with table. 7 = white.
  5740.     echo_status db 0             ; 0 = hide (default), 1 = show. also gets
  5741.                                  ; saved with table.
  5742.  
  5743.      ab_table db ((RHS_LEN+LHS_LEN+1)*TBL_LEN) dup(0)  ; the alias table
  5744.    table_end  db 0F0h                                  ; used by count_aliases
  5745.  
  5746.                                   ;Data Area for Dos Editor
  5747.  
  5748.                                   ;Table of keys and their commands' address
  5749.  
  5750. cmndtbl:
  5751.  
  5752.    dw   ltarrw,   curslf          ;move cursor left one column
  5753.    dw   rtarrw,   cursrt          ;move cursor right one column
  5754.    dw   cntlf,    wordl           ;move cursor left word
  5755.    dw   cntrt,    wordr           ;move cursor right word
  5756.    dw   homekey,  begline         ;move cursor to beginning of line
  5757.    dw   endkey,   endline         ;move cursor to end of line
  5758.    dw   uparrw,   cursup          ;move cursor up one line
  5759.    dw   dnarrw,   cursdn          ;move cursor down one line
  5760.    dw   f3key,    f3proc          ;non-destructive f3
  5761.    dw   bs,       delchrl         ;delete char left of cursor
  5762.    dw   delkey,   delchrr         ;delete char right of cursor
  5763.    dw   'W'-cntl, delwrdl         ;delete word left of cursor
  5764.    dw   altw,     delwrdr         ;delete word right of cursor
  5765.    dw   'L'-cntl, dellinl         ;delete to beginning of line
  5766.    dw   altl,     dellinr         ;delete to end of line
  5767.    dw   altk,     delline         ;delete all characters on line
  5768.    dw   escape,   escproc         ;delete all characters on line
  5769.    dw   'U'-cntl, undelet         ;undelete text from buffer
  5770.    dw   altu,     undelet         ;undelete text from buffer
  5771.    dw   insert,   inskey          ;toggle insert/overwrite mode
  5772.    dw prf_trigger,do_prf          ;enter prf routine if trigger key pressed
  5773.    dw     it_key ,it_proc         ;F8 key
  5774.    dw    also_key,also_proc       ;F10 key
  5775.    dw     pgdnkey,pg_dn_proc      ;PgDn key
  5776.    dw     pgupkey,pg_up_proc      ;PgUp Key
  5777.    dw       f1key,f1proc          ; F1 key does nothing
  5778.    dw   0000h,    nomatch         ;no match, place the char in buffer
  5779.  
  5780. bublbeg     db    maxlin dup (?)  ;beginning of bubble buffer
  5781. Bublend     db    ?               ;end of bubble buffer
  5782. Cursorb     dw    ?               ;pointer to beginning of cursor
  5783. Cursore     dw    ?               ;pointer to end cursor in text buffer
  5784. Unleft      dw    ?               ;undelete data counter on the left
  5785. Unright     dw    ?               ;undelete data counter on the right
  5786. Scrnwdt     dw    ?               ;screen width in columns
  5787. Disppag     db    ?               ;display page
  5788. Maxchar     dw    ?               ;max number of char in line
  5789. dcbuffer    db    maxlin+2 dup(?) ; Buffer for DOS compatibility
  5790. dcbufend    db    ?               ; Mark end of dcbuffer
  5791. dcpointer   dw    ?               ; pointer into dcbuffer
  5792.  
  5793.                                   ;Screen relative variables
  5794.  
  5795. Leftx       dw    ?               ;X position of the left most character
  5796. edcursx     dw    ?               ;X position of the editor cursor
  5797. cursorx     dw    ?               ;X position of the cursor
  5798. cursory     db    ?               ;Y position of the cursor
  5799.  
  5800.                                   ;Display line relative variables
  5801.  
  5802. linelen     dw    ?               ;length of display line
  5803. Updatex     dw    ?               ;X position for character update
  5804.  
  5805.                                   ;Text line relative variables
  5806.  
  5807. startx      dw    ?               ;column # of start of the display line
  5808. scrnimg     db    maxswdt dup (?) ;image of screen display line
  5809.  
  5810. dosvect     dd    ?               ;contains pointer to Dos vector
  5811. oldsp       dd    ?               ;contains old stack pointer
  5812. codeseg     dw    ?               ;code segment for this program
  5813.  
  5814.                                   ;Storage for the command recording functions
  5815.  
  5816. cmdtop     db     cmdlen-1 dup (?);ring buffer for line entries
  5817. cmdbot     db     ?               ;end of ring buffer
  5818. cmdold     dw     ?               ;pointer to oldest command
  5819. cmdnew     dw     ?               ;pointer to newest command
  5820. cmdpnt     dw     ?               ;pointer to current command
  5821.  
  5822.  
  5823. stckbot    db     200 dup (?)     ;storage for the stack
  5824. stcktop    db     ?               ;top of the stack
  5825.                                   ;End of editor data
  5826.  
  5827. ; -----------------------------------------------------------------------
  5828. ;                   NOTHING BELOW HERE GETS MADE RESIDENT
  5829. ; -----------------------------------------------------------------------
  5830.  
  5831. init:   push  cs                      ; set ds = cs
  5832.         pop   ds
  5833.         jmp   install
  5834.  
  5835.     greet db 'ALIAS v',VERS,' now installed.'
  5836.  
  5837. ife online_help
  5838.           db CR,LF,'(Short version.  No online help).'
  5839. endif
  5840.  
  5841.    db CR,LF,'(c)Robert Schifreen 1989.'
  5842.    db CR,LF
  5843.    db CR,LF,'ALIAS gives you:'
  5844.    db CR,LF,' - Aliasing for MS-DOS commands'
  5845.    db CR,LF,' - Recall of previous commands'
  5846.    db CR,LF,' - Full editing of recalled commands'
  5847.    db CR,LF,' - Automatic command completion.'
  5848.    db CR,LF,'For help, use the ALIAS ? command.',CR,LF
  5849.  
  5850.    db CR,LF,'IMPORTANT:  ALIAS is not "free software" and it is not "public domain".'
  5851.    db CR,LF,'You may use the software for one month, and you are welcome to give'
  5852.    db CR,LF,'copies to anyone you wish.  If, after the one month trial period, you'
  5853.    db CR,LF,'intend to continue using the program, you or your company must register it'
  5854.    db CR,LF,'by sending a contribution of up to £25 or 30 US dollars to the author at'
  5855.    db CR,LF,'65 Latchingdon Court, 26 Forest Road, London, E17 6JT, England.',CR,LF
  5856.  
  5857.    db CR,LF,'Registered users receive: extra documentation; news of major upgrades;'
  5858.    db CR,LF,'a special memory-saving version; dial-up technical support in the UK'
  5859.    db CR,LF,'and the US on the Cix and Bix networks; full MASM source code (¼MB) for'
  5860.    db CR,LF,'the latest version of ALIAS (please state disk size when registering).'
  5861.    db CR,LF,'$'
  5862.  
  5863. wrong_dos db 'ALIAS runs only under DOS version 2, 3 or 4.',CR,LF,DOS_EOM
  5864. alrdy_in  db 'There seems to be a copy of ALIAS already in memory.',CR,LF
  5865.           db 'Type ALIAS ? for help.',CR,LF,EOM
  5866. default   db 'Loading ALIAS.DAT...',CR,LF,DOS_EOM
  5867.  
  5868. install:
  5869.  
  5870.                                       ; With ALIAS installed, calling DOS
  5871.                                       ; function 35h increments 0040:00F4h
  5872.                                       ; to show that ALIAS is resident. Use
  5873.                                       ; this check to see if prog is
  5874.                                       ; already installed.
  5875.  
  5876.  
  5877.         push_m <ax,bx,cx,ds,dx,es>
  5878.         mov   ax,40h
  5879.         mov   ds,ax                   ; segment for ICA
  5880.         mov   ch,byte ptr ds:0f4h     ; get current value of ICA byte
  5881.         mov   ah,35h                  ; now call function 35h
  5882.         mov   al,5                    ; get value of int 5, though exact value
  5883.                                       ; doesn't really matter.
  5884.         int   21h                     ; gets int 5 vector into es:bx
  5885.         mov   ax,40h                  ; point to ica again
  5886.         mov   ds,ax
  5887.         mov   cl,byte ptr ds:0f4h     ; get ICA byte again.
  5888.         inc   ch
  5889.         cmp   ch,cl                   ; Is cl = ch + 1?     
  5890.         pop_m <es,dx,ds,cx,bx,ax>
  5891.         jne carry_on_installing       ; If cl becomes ch+1, then increment
  5892.                                       ; took place so ALIAS is resident.
  5893.  
  5894.                                        ; ALIAS is already loaded so don't
  5895.                                        ; load it again.
  5896.         push_all
  5897.         mov   si,offset cs:alrdy_in
  5898.         mov   bl,cs:colour
  5899.         call  disp_str_colour          ; display message
  5900.         pop_all
  5901.         int   20h                     ; terminate execution of ALIAS.COM
  5902.  
  5903. carry_on_installing:
  5904.  
  5905.         push_m <ax,dx,ds>
  5906.         mov   ah,30h                  ; get DOS version number
  5907.         int   21h
  5908.         cmp   al,2
  5909.         pop_m <ds,dx,ax>
  5910.         je    dos_ok                  ; continue if 2
  5911.  
  5912.         push_m <ax,dx,ds>
  5913.         mov   ah,30h                  ; get it again
  5914.         int   21h
  5915.         cmp   al,3
  5916.         pop_m <ds,dx,ax>
  5917.         je    dos_ok                  ; continue if it's a 3
  5918.  
  5919.  
  5920.         push_m <ax,dx,ds>
  5921.         mov   ah,30h                  ; get it again
  5922.         int   21h
  5923.         cmp   al,4
  5924.         pop_m <ds,dx,ax>
  5925.         je    dos_ok                  ; continue if it's a 4
  5926.  
  5927.  
  5928.         push_m <ax,dx,ds>
  5929.         mov   ah,30h                  ; get it again
  5930.         int   21h
  5931.         cmp   al,0Ah
  5932.         pop_m <ds,dx,ax>
  5933.         je    dos_ok                  ; continue if 10, ie DOS box of OS/2
  5934.  
  5935.         mov   ah,9                    ; display error msg if DOS is not 2 or 3
  5936.         mov   dx,offset wrong_dos
  5937.         push  ds
  5938.         push  cs
  5939.         pop   ds
  5940.         int   21h
  5941.         pop   ds
  5942.         ret                           ; and terminate
  5943.  
  5944. dos_ok:
  5945.  
  5946.         mov   ah,35h                  ; get interrupt vector
  5947.         mov   al,21h                  ; number 21h - dos function call
  5948.         int   021h
  5949.         mov   ax,es
  5950.         mov   cs:old_vec_seg,ax
  5951.         mov   cs:old_vec_off,bx
  5952. ;
  5953.         mov   ah,25h                  ; set interrupt vector
  5954.         mov   al,21h                  ; specify vector to be set
  5955.         mov   dx,offset intent
  5956.         int   21h
  5957. ; 
  5958.         mov   ah,35h                  ; find out new interrupt vector
  5959.         mov   al,21h                  ; for int 21h 
  5960.         int   21h
  5961.         mov   ax,es
  5962.         mov   cs:new_vec_seg,ax
  5963.         mov   cs:new_vec_off,bx
  5964. ;
  5965.                                       ; If alias.dat exists, load it
  5966.         push_m <ax,bx,cx,dx,ds>
  5967.         push  cs                      ; point to filename
  5968.         pop   ds
  5969.         mov   dx,offset cs:default_fn
  5970.         mov   ah,3dh                  ; open file
  5971.         mov   al,0                    ; for reading
  5972.         int   21h
  5973.         jc    no_default_file         ; quit if file not found 
  5974. ;
  5975.                                       ; print msg to say we're loading file
  5976.         push_all
  5977.         mov   ah,9
  5978.         mov   dx,offset cs:default
  5979.         push  cs
  5980.         pop   ds
  5981.         int   21h
  5982.         pop_all
  5983. ;
  5984.         mov   bx,ax                   ; put handle in correct place
  5985.         mov   cx,((RHS_LEN + LHS_LEN + 1) * TBL_LEN) + 5 ; table plus signat
  5986.         push  cs
  5987.         pop   ds
  5988.         mov   dx,offset cs:table_top  ; start of data area
  5989.         mov   ah,3fh
  5990.         int   21h
  5991.         ;
  5992.         mov   ah,3eh                  ; close file
  5993.         int   21h
  5994. ;
  5995.                                       ; Get the name of the current directory,
  5996.                                       ; ie the one that ALIAS.DAT is in.
  5997.                                       ; Use this directory for future writes
  5998.                                       ; if an ALIAS W command is used without
  5999.                                       ; a specified filename.
  6000.         push_m <ax,ds,dx,si>
  6001.         mov   ah,47h
  6002.         mov   dl,0                    ; default drive
  6003.         push  cs
  6004.         pop   ds
  6005.         mov   si,offset cs:def_dir    ; buffer for the directory
  6006.         int   21h
  6007.         pop_m <si,dx,ds,ax>
  6008. ;
  6009.                                       ; Func 47h doesn't return the drive
  6010.                                       ; letter, so get it and plug it in.
  6011.         push  ax
  6012.         mov   ah,19h
  6013.         int   21h                     ; get zero-based drive code into al.
  6014.         add   al,'A'                  ; convert to a letter
  6015.         mov   byte ptr cs:defdir_hdr,al   ; and put it at front of string
  6016.         pop   ax
  6017. ;
  6018.                                       ; Now find the end of the path string,
  6019.                                       ; and put a backslash and filename on,
  6020.                                       ; to create a full path and file name.
  6021.  
  6022.         push_all
  6023.         push  cs
  6024.         pop   es                      ; scasb needs string at es:di
  6025.         cld                           ; clear direction flag
  6026.         mov   al,0                    ; char to search for
  6027.         mov   cx,66                   ; length of string to search
  6028.         mov   di,offset cs:def_dir    ; addr of string to search
  6029.         repne scasb                   ; search till we find a 0.  We will
  6030.                                       ; definitely find one eventually!
  6031.         dec   di                      ; di now has adr of the zero byte
  6032.  
  6033.         cmp   byte ptr cs:[di-1],'\'  ; Are we in root?
  6034.         je    in_root                 ; Yes, then backslash is already there
  6035.  
  6036.         mov   byte ptr cs:[di],'\'    ; else put backslash on end of string
  6037.  
  6038.                                       ; Now copy the default filename from
  6039.                                       ; default_fn to the end of the path.
  6040.  
  6041.         inc   di                      ; point to char after trailing backslash
  6042.  
  6043. in_root:
  6044.  
  6045.         mov   si,offset cs:default_fn ; point to start of default filename
  6046.  
  6047. copy1:
  6048.  
  6049.         lodsb                         ; get a byte from the filename into al
  6050.         cmp   al,0                    ; done?
  6051.         je    copy_done
  6052.         mov   byte ptr cs:[di],al     ; put the byte into place
  6053.         inc   di                      ; SI got incremented by the lodsb.
  6054.         jmp   short copy1             ; and go get the next byte
  6055.  
  6056. copy_done:
  6057.  
  6058.         pop_all
  6059.  
  6060. no_default_file:                      ; default file was not in current dir
  6061.                                       ; so don't load it.
  6062.  
  6063.         pop_m <ds,dx,cx,bx,ax>
  6064.  
  6065.         show   greet                  ; Display welcome message.  Note that
  6066.                                       ; we use the standard DOS call to display
  6067.                                       ; this message, rather than the fancy
  6068.                                       ; colour string printer that is used
  6069.                                       ; everywhere else in ALIAS.  This is so
  6070.                                       ; that the user can redirect the greet
  6071.                                       ; message to NUL if he wishes.
  6072.  
  6073.  
  6074.                                       ; Set up the command line editor
  6075.  
  6076.         mov    sp,offset stcktop      ;set stack pointer to top of stack
  6077.         mov    cs:codeseg,cs          ;save this code segment
  6078.         mov    ds,cs:codeseg          ;DS is same as code segment
  6079.         call   inittny                ;initialize the editor
  6080.  
  6081.  
  6082.                                       ; Free the environment block allocated
  6083.                                       ; to us, as we don't need it.  The adr
  6084.                                       ; of the block is in PSP:2ch.
  6085.  
  6086.                                       ; If the debug flag is set, do not
  6087.                                       ; assemble this routine.  With the
  6088.                                       ; environment intact, one can use SMAP
  6089.                                       ; to find the name of the loaded version
  6090.                                       ; of the program, which helps me to
  6091.                                       ; remember whether ALIAS.COM is loaded,
  6092.                                       ; or whether it's a temporary version of
  6093.                                       ; the file, used for test purposes.
  6094.  
  6095.         ife    debug
  6096.         push_m <ax,es>
  6097.         mov    es,cs:[2ch]            ; get seg adr of our environment block
  6098.         mov    ah,49h                 ; free a block
  6099.         int    21h                    ; free the block
  6100.         pop_m <es,ax>                 ; all done
  6101.         endif
  6102.  
  6103.         mov   ax,3100h                ; terminate and remain resident
  6104.         mov   dx,rsize                ; size of residency in paragraphs
  6105.         int   21h                     ; done
  6106.  
  6107.         code  ends
  6108.         end   start                   ; start execution at routine 'start'
  6109.  
  6110. ; -----------------------------------------------------------------------
  6111. ;                       (c) Robert Schifreen 1985,1989
  6112. ; -----------------------------------------------------------------------
  6113.